Child GUI disappears when clicking on a tab twice

[DarkBanana]

Hey there,

I started to work with tabs earlier today but I can't figure out what the problem is.

expandcollapse popup

#include <GuiTab.au3>
#include <WindowsConstants.au3>

Global $Height = @DesktopHeight
Global $Width = @DesktopWidth

$GUI = GUICreate("", $Width, $Height, 0, 0, BitOR($WS_SIZEBOX, $WS_MINIMIZEBOX))
GUICtrlCreateMenu("")
$Tab = GUICtrlCreateTab(20,20,$Width/1.2,$Height/1.2)
GUICtrlCreateTabItem("First")
GUICtrlCreateTabItem("Second")
GUISetState()

$GUI_Child_1 = GUICreate("", $Width / 1.3, $Height / 1.3, 100, 100, BitOR($WS_POPUP, $WS_BORDER))
GUISetBkColor(0xCCFFCC)
DllCall("user32.dll", "int", "SetParent", "hwnd", $GUI_Child_1, "hwnd", $GUI)
GUISetState(@SW_SHOW)

$GUI_Child_2 = GUICreate("", $Width / 1.3, $Height / 1.3, 100, 100, BitOR($WS_POPUP, $WS_BORDER))
GUISetBkColor(0xAAAAAAA)
DllCall("user32.dll", "int", "SetParent", "hwnd", $GUI_Child_1, "hwnd", $GUI)
GUISetState(@SW_HIDE)


While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case -3
            Exit
        Case $Tab
            $SelTab = _GUICtrlTab_GetCurSel($Tab)

            If $SelTab = 0 then
                GUISetState(@SW_HIDE,$GUI_Child_2)
                GUISetState(@SW_SHOW,$GUI_Child_1)
            EndIf

            If $SelTab = 1 then
                GUISetState(@SW_HIDE,$GUI_Child_1)
                GUISetState(@SW_SHOW,$GUI_Child_2)
            EndIf

    EndSwitch
WEnd

If you click twice on the second tab the ChildGUI will disappear and I would like to know why?
 What am I missing? 

Thanks for help.

[BrewManNH]

If you move the GUI you'll see that child 2 isn't connected to the main GUI at all.so when you click the tab again, the gui goes to the back ground.

[jguinch]

You main GUI has the focus so the child Window is behind.

You can use the $WS_EX_MDICHILD exstyle for this :

expandcollapse popup

#include <GuiTab.au3>
#include <WindowsConstants.au3>

Global $Height = @DesktopHeight
Global $Width = @DesktopWidth

$GUI = GUICreate("", $Width, $Height, 0, 0, BitOR($WS_SIZEBOX, $WS_MINIMIZEBOX))
GUICtrlCreateMenu("")
$Tab = GUICtrlCreateTab(20,20,$Width/1.2,$Height/1.2)
GUICtrlCreateTabItem("First")
GUICtrlCreateTabItem("Second")
GUISetState()

$GUI_Child_1 = GUICreate("", $Width / 1.3, $Height / 1.3, 100, 100, BitOR($WS_POPUP, $WS_BORDER), $WS_EX_MDICHILD, $GUI)
GUISetBkColor(0xCCFFCC)
GUISetState(@SW_SHOW)

$GUI_Child_2 = GUICreate("", $Width / 1.3, $Height / 1.3, 100, 100, BitOR($WS_POPUP, $WS_BORDER), $WS_EX_MDICHILD, $GUI)
GUISetBkColor(0xAAAAAAA)
GUISetState(@SW_HIDE)


While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case -3
            Exit
        Case $Tab
            $SelTab = _GUICtrlTab_GetCurSel($Tab)
            Switch $SelTab
                Case 0
                    GUISetState(@SW_HIDE,$GUI_Child_2)
                    GUISetState(@SW_SHOW,$GUI_Child_1)
                Case 1
                    GUISetState(@SW_HIDE,$GUI_Child_1)
                    GUISetState(@SW_SHOW,$GUI_Child_2)
            EndSwitch
    EndSwitch
WEnd

 

[DarkBanana]

There's one wrong number.... I assigned Child 1 twice.

DllCall("user32.dll", "int", "SetParent", "hwnd", $GUI_Child_1, "hwnd", $GUI)

;should be:

DllCall("user32.dll", "int", "SetParent", "hwnd", $GUI_Child_2, "hwnd", $GUI)

Thank you.