hashtable uses?

[iamtheky]

was pointed towards scripting.dictionary as I explored maps, but I got sidetracked in hashtables.   Any pros / cons yall have experienced?    My first hour of playing with trying to feign the behavior yielded this, which may or may not be a good starting point:  

*I am using integer keys because i dont know how to iterate through the collection returned from .keys, not for any legitimate reasons.

 

expandcollapse popup

$MyMap = _MapInit()

_AddKeyValuePair($MyMap , 1, "hello")
_AddKeyValuePair($MyMap , 2, "world")
_AddKeyValuePair($MyMap , 3, "My")
_AddKeyValuePair($MyMap , 4, "Name")
_AddKeyValuePair($MyMap , 5, "Is")
_AddKeyValuePair($MyMap , 6, "Map")

_AddKeyValuePair($MyMap , 1, "world") ;fail with duplicate key

msgbox(0, "Value of Key 3" , _GetValue($MyMap , 3))
msgbox(0, "Value of Key 6" , _GetValue($MyMap , 6))

msgbox(0, 'Whole Map' , _MapToString($MyMap))


Func _MapInit()
  Local $oHashTable = ObjCreate("System.Collections.Hashtable")

    If Not IsObj($oHashTable) Then
        Exit MsgBox(0, "Error", "Object not created")
    EndIf

  return $oHashTable
EndFunc ;_MapInit


Func _AddKeyValuePair($map , $key , $value)
    If $map.ContainsKey($key) Then
        msgbox(0, 'Error' , '"' & $key & '"' & ' already exists with a value of ' & '"' & $map.Item($key) & '"')
    Else
        $map.Add($key, $value)
    EndIf
EndFunc


Func _GetValue($map , $key)
    return $map.Item($key)
EndFunc

Func _MapToString($map)
  local $sHashTable = ""
    For $i = 1 to $map.count
        $sHashTable &= $i & " = " & $map.Item($i) & @LF
    Next
return $sHashTable
EndFunc

 

 

 

[guinness]

Nope couldn't work it out either. HashTables are quite slow in C# compared to the other data structures.

expandcollapse popup

#include <MsgBoxConstants.au3>

; Error constants
Global Enum Step * 2 $MAP_INVALID_LIBRARY, $MAP_INVALID_HANDLE, $MAP_KEY_EXISTS

Local $hMap = _Map_Init()
If @error Then
    MsgBox($MB_SYSTEMMODAL, '', 'It appears System.Collections.Hashtable doesn''t exist on your system.')
    Exit
EndIf

Local $aStrings = ['Hello', 'World', 'My', 'Name', 'Is', 'Map'] ; Starts from zero
For $i = 0 To UBound($aStrings) - 1
    _Map_Add($hMap, $i, $aStrings[$i])
Next

If Not _Map_Add($hMap, 2, 'World') Then ; Duplicate value exists
    MsgBox($MB_SYSTEMMODAL, 'Error', '"2" already exists with a value of ' & '"' & _Map_GetValue($hMap, 2) & '"')
EndIf

MsgBox($MB_SYSTEMMODAL, 'Value of Key 3', _Map_GetValue($hMap, 3))
MsgBox($MB_SYSTEMMODAL, 'Value of Key 6', _Map_GetValue($hMap, 5))

MsgBox($MB_SYSTEMMODAL, 'Map.ToString()', _Map_ToString($hMap))

Func _Map_Init()
    Local $hMap = ObjCreate('System.Collections.Hashtable')
    If Not IsObj($hMap) Then
        Return SetError($MAP_INVALID_LIBRARY, 0, Null)
    EndIf

    Return $hMap
EndFunc   ;==>_Map_Init

Func _Map_Add(ByRef $hMap, $vKey, $vValue)
    ; Check if a valid 'Map' object
    If Not __Map_IsMap($hMap) Then
        Return SetError($MAP_INVALID_HANDLE, 0, False)
    EndIf

    If $hMap.ContainsKey($vKey) Then
        Return SetError($MAP_KEY_EXISTS, 0, False)
    EndIf

    $hMap.Add($vKey, $vValue)

    Return True
EndFunc   ;==>_Map_Add

Func _Map_GetValue(ByRef $hMap, $vKey)
    ; Check if a valid 'Map' object
    If Not __Map_IsMap($hMap) Then
        Return SetError($MAP_INVALID_HANDLE, 0, '')
    EndIf

    Return $hMap.Item($vKey)
EndFunc   ;==>_Map_GetValue

Func _Map_ToString($hMap)
    ; Check if a valid 'Map' object
    If Not __Map_IsMap($hMap) Then
        Return SetError($MAP_INVALID_HANDLE, 0, '')
    EndIf

    ; WARNING: DOESN'T WORK
    Local $sHashTable = ''
    For $vKey In $hMap.Keys()
        $sHashTable &= $vKey & ' = ' & $hMap.Item($vKey) & @CRLF
    Next

    Return $sHashTable
EndFunc   ;==>_Map_ToString

Func __Map_IsMap(ByRef $hMap)
    Return $hMap <> Null
EndFunc   ;==>__Map_IsMap

 

[iamtheky]

is there a most efficient way to play key-value with scripting.dictionary? google would lead me to believe I have as many choices as there are delimiters, but i have a feeling there are better tricks.

nvm any of that until I can state my issue in code, because as soon as i do that I will probably have the answer..

Edited August 15, 2015 by boththose