FileExists() doesn't see files

[ziuta1411]

Hi,

I have a problem with using FileExists(). I have an array which contains few paths. I try to check if those paths are created by using following code:

For $item in $aPATHS
  If FileExists($item) == 1 Then
      FileWrite($hLogOpen, $item & ' exists' & @CRLF)
   Else
      FileWrite($hLogOpen,$item & ' does not exists' & @CRLF )
   EndIf
Next

Only with first path I get expected outcom, in every other case FileExists returns 0, despite the fact that file actually exists. I'll be grateful for some pointers - what am I doing wrong?

[Melba23]

ziuta1411,

Welcome to the AutoIt forums.

Some suggestions:

• Use a For...To...Next loop to work through the array
• Check the paths are full and not relative

And you should use the "=" operator to do the comparison ("==" forces a case-sensitive string comparison), although in this case it should not make a difference.

M23

 

[computergroove]

messagebox the $item in the loop to see exactly what is being seen by autoit to search for. Is it exactly what is in your array? Are any of these paths in Program Files?

[ziuta1411]

Thank You for your reply I used your advice and came up with:

For $i = 0 To UBound($aPATHS) - 1
  Global $tmp = $aPATHS[$i]
  If FileExists($tmp) = 1 Then
      FileWrite($hLogOpen, $tmp & 'exists' & @CRLF)
   Else
      FileWrite($hLogOpen, $tmp & 'does not exists' & @CRLF)
   EndIf
 Next

$aPATHS array is loaded from a text file, that contains paths like:

d:\AutoIt\TEST

d:\AutoIt\TEST\test1.txt

d:\AutoIt\TEST\test1.bat

and few more, all of these files are in d:\AutoIt\TEST directory, which is the only path that FileExists() sees. None of them are in Program Files. I've displayed $tmp in messagebox and it shows exactly the same string that is in a file.....

And it still doesn't work... Is there any function, that can substitute for FileExists() ?  Maybe it's a newbie question, but I've only been trying autoit for 3 days

[Melba23]

ziuta1411,

I have just run your code (with a few added lines) and it works perfectly for me:

#include <File.au3>
#include <MsgBoxConstants.au3>

; Read path file into an array

Global $aPATHS

_FileReadToArray("Paths.txt", $aPATHS, $FRTA_NOCOUNT)

; Create log file
$sLogfile = "Log.txt"
$hLogOpen = FileOpen($sLogFile, $FO_OVERWRITE)

; Loop through array
For $i = 0 To UBound($aPATHS) - 1
  Global $tmp = $aPATHS[$i]
  If FileExists($tmp) = 1 Then
      ConsoleWrite($tmp & " found" & @CRLF)
      FileWrite($hLogOpen, $tmp & ' exists' & @CRLF)
  Else
      ConsoleWrite($tmp & " NOT found" & @CRLF)
      FileWrite($hLogOpen, $tmp & ' does not exists' & @CRLF)
   EndIf

Next

; Close log file
FileClose($hLogOpen)

; Read the content
$sContent = FileRead($sLogFile)
MsgBox($MB_SYSTEMMODAL, "Result", $sContent)

; Delete log file
FileDelete($sLogFile)

Try running that on your path list.

If it does not work, then please post the file which holds the paths - I am wondering if there s not a problem with its internal structure that prevents you reading more than the first entry.

M23

[ziuta1411]

Thank You, it works I don't really know why, but it solves the problem

[Melba23]

ziuta1411,

Delighted to hear it.

M23