2D Array error

[_sim]

#include <Array.au3>

Local $sB[3]=["A","B","C"]
Local $sA[3]=["X","Y","Z"]
Local $A[2]=[$sB,$sA]

Local $i = 0
While $i < 2
    Local $j=0
    While $j < 3
        MsgBox(1, $A[$i][$j], $A[$i][0])
        $j=$j+1
    WEnd
    $i=$i+1
Wend

I'm sure there's something really simple that I'm missing here but I can't for the life of me work it out. 

When I try to read an element from the second dimension of an array I get this error:

Any ideas?

Edited October 20, 2015 by _sim

[AutoBert]

You defined an1D array $a for 2 Elements and are wondering why an error ocurs when you try to output the 3. element of the the 2. dimesion?

Edited October 20, 2015 by AutoBert

[BrewManNH]

Your $A array contains arrays in an array, adn $A is a 1d array that you're accessing as a 2D array.

[_sim]

Ahh, I knew I was being slow. 

However, now I've redefined $A as 

Local $A[2][3]=[[$sB],[$sA]]

And while the loop iterates fully and 6 message boxes come up, the values are null...

What else have I missed?

[BrewManNH]

You now have a 2D array, but the array $A only holds 1 row, $A[0][0] holds the array $sB, and $A[0][1] holds the array $sA. The other 2 rows of the array are empty.

Arrays-in-arrays are tricky to work with, and usually more work than they're worth trying to work with them.

[Gianni]

?

#include <Array.au3>

Local $sB[3] = ["A", "B", "C"]
Local $sA[3] = ["X", "Y", "Z"]
Local $A[2] = [$sB, $sA]

for $i = 0 to 2
    MsgBox(0, 0, ($A[0])[$i] & @TAB & ($A[1])[$i])
Next

 

edit: reference

Edited October 20, 2015 by Chimp

[kylomas]

Why not keep it simple...

#include <Array.au3>

Local $A[2][3] = [["A", "B", "C"], ["X", "Y", "Z"]]     ; decalre / populate 2D array

For $i = 0 To UBound($A) - 1                            ; for all rows in array
    For $j = 0 To UBound($A, 2) - 1                     ; for all cols in row
        ConsoleWrite($A[$i][$j] & ' ')                  ; output columns
    Next
    ConsoleWrite(@CRLF)                                 ; skip to next row
Next

kylomas

[Gianni]

@ kylomas

.... arrays within array are gone....?

I do not know if OP is intentionally trying to manage arrays of arrays
... or is not aware of what a 2d array is....

[Melba23]

Chimp,

.... arrays within array are gone....?

You can still have arrays within arrays - and accessing them is pretty easy too nowadays. All kylomas was suggesting is that they are not the easiest things to work with for less-experienced coders.

M23

[Gianni]

Alright then 

Edited October 20, 2015 by Chimp