ObjEvent (COM error handling) - AutoIt 3.3.14.2

[francoiste]

i have just upgraded from autoit 3.3.12.0 to 3.3.14.2 and noticed a difference in behaviour.

through WMI i'm querying some system specs of the local environment.

• with the previous version of autoit i was simply getting an empty string when trying to query a property that is invalid or doesn't exist.
• with the new version of autoit i'm getting a runtime error and my compiled script terminates.

code snippet:

_MyTest()

Func _MyTest()
    Local $oWMI = ObjGet('winmgmts:\\' & '.' & '\root\cimv2')
    If Not IsObj($oWMI) Then
        MsgBox(48, "WARNING", "Failed to use WMI (winmgmts)!")
        Return
    EndIf

    For $i In $oWMI.ExecQuery('SELECT * FROM Win32_BIOS', 'WQL', 48)
        ;# CAUTION: "$i.Product" throws runtime error after upgrading to AutoIt 3.3.14.2:
        Local $sIdentifier = $i.Manufacturer & "; " & $i.Product & "; " & $i.Version & "; " & $i.SerialNumber

        ConsoleWrite("[Hardware] BIOS fingerprint: " & $sIdentifier & @CRLF)
    Next
    ConsoleWrite("FINISHED." & @CRLF)
EndFunc

i can avoid the termination of my script by adding a custom COM error handler ("ObjEvent") as follows:

_MyTest()

Func _MyTest()
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc") ;# <--- LOOK HERE

    Local $oWMI = ObjGet('winmgmts:\\' & '.' & '\root\cimv2')
    If Not IsObj($oWMI) Then
        MsgBox(48, "WARNING", "Failed to use WMI (winmgmts)!")
        Return
    EndIf

    For $i In $oWMI.ExecQuery('SELECT * FROM Win32_BIOS', 'WQL', 48)
        ;# CAUTION: "$i.Product" throws runtime error after upgrading to AutoIt 3.3.14.2:
        Local $sIdentifier = $i.Manufacturer & "; " & $i.Product & "; " & $i.Version & "; " & $i.SerialNumber

        ConsoleWrite("[Hardware] BIOS fingerprint: " & $sIdentifier & @CRLF)
    Next
    ConsoleWrite("FINISHED." & @CRLF)
EndFunc

;# Custom COM error handler
Func _ErrFunc($oError)
    Local $sMessage = @ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF
    ConsoleWrite($sMessage)
    MsgBox(48, "WARNING - COM error", $sMessage)
EndFunc

 

but still i'd be curious to learn the background of the different runtime behaviour with autoit 3.3.14.2

any thoughts?

Edited October 23, 2015 by francoiste

[mLipok]

You must use COM Error Handler

Read in helpfile about 

ObjEvent()

EDIT: as it was change in last AutoIt 3.3.14.x version.

 

mLipok

btw.

Welcome to the forum

 

Edited October 23, 2015 by mLipok

[mLipok]

And what Error Handler show to you in SciTE console output pane ?

[francoiste]

are you saying that custom COM error handlers are now "mandatory", as otherwise any script will terminate with error?

can you point to some references, please?
i cannot find anything in the "script breaking changes" section ...

Edited October 23, 2015 by francoiste

[BrewManNH]

It's not listed in the help file.

But then, the removal of COM errors being fatal wasn't mentioned either and only lasted a version or 2.

[francoiste]

interesting.

in the changelog i found for version "3.3.10.0"

Run-time errors on objects no longer fatal (execution of the script is not halted)

so it seems this was now rolled-back by version "3.3.14.2"?

conclusion:
from now on i'll put custom COM error handlers all over the place.
because otherwise it breaks my scripts.

[mLipok]

Even if there was no obligation to use it, it's good practice is to use it.
It is my experience as a creator of many of the UDF based on ActiveX and COM objects.

 

Edit:
If you want to know why, just answer here to this my question:

And what Error Handler show to you in SciTE console output pane ?

Edited October 23, 2015 by mLipok

[JohnOne]

are you saying that custom COM error handlers are now "mandatory", as otherwise any script will terminate with error?

Not quite, the opposite really, COM errors are not fatal in themselves but will obviously affect your script and could cause them to fail.

But yes error handlers must be used by any sane person. In the past AutoIt was handling them when one was not present.