Continue the current for loop if interrupted by AdlibRegister

[Timppa]

Hello!

I have a function that checks for either completed update or update that had errors.

This is one part of function (rest doesn't matter because they don't affect on anything, just variables)

for $i = 0 To $RepeatNumber Step + 1
      ToolTip("Not ready yet")
      Sleep(1000)
      CheckScreen() ;Returns $Confirm variable
      If $Confirm = 1 Then
         ToolTip("The update is now completed!")
         Sleep(1000)
         AdlibRegister("InformUser()")
      EndIf
   Next
      Sleep(200)
      for $i = 0 To $RepeatNumber Step + 1
         ToolTip("Finding for errors")
         Sleep(1000)
         $FindErrors = 1
         CheckScreen()
         If $Confirm = 1 Then
            AdlibRegister("InformUser()")
         EndIf
      Next
         ToolTip("Nothing found yet")
         Sleep(1000)
         $Repeat = 1

 

So what I want to do now is that it checks first for completed update, if there is certain button (that the update succeeded), it will then do whatever it needs to.

Then if after $i == $RepeatNumber (Input integer to define how many times should it be checked), go check for errors for $RepeatNumber times. If there still is no succeeded update or errors on update, it runs the same Function again as long as either is found.

Now what my script does is that if there is succeeded update, it will just restart the function. For example my function finds succeeded update after the $i = 5, then it does the function that it will call from AdlibRegister and then continue checking UNTIL $i = $RepeatNumber, there is many of them to be checked. Then after that go to error section.

 

I thought it would work with the AdlibRegister but it just starts it over again. Is there any other methods to do this?

 

Thanks in advance!

[Melba23]

Timppa,

That looks a very confused snippet. Why are you using Adlib to announce a single event? Why not announce it directly?

From what you have described (rather vaguely), I think this will do what you want:

expandcollapse popup

Global $bConfirm = False, $bFindErrors = False

Local $iRepeatNumber = 5, $iSuccess = 0, $iError = 0

While 1

    For $i = 1 To $iRepeatNumber ; No need for Step if it is +1

        Sleep(100)
        ; Look for success
        CheckScreen() ; Sets $bConfirm variable
        ; Depending on setting
        If $bConfirm Then
            Sleep(100)
            InformUser($i, 1) ; Index and mode = success
            ; Clear flag
            $bConfirm = False
            ; Increase count
            $iSuccess += 1
        EndIf



        ; Look for failure
        CheckScreen() ; Sets $bConfirm variable
        If $bConfirm Then
            Sleep(100)
            InformUser($i, 0) ; Index and mode = failure
            $bConfirm = False
            $iError += 1
        EndIf



    Next

    ; Check if all succeeded or failed
    If $iSuccess + $iError = $iRepeatNumber Then
        ; If so, then exit the loop
        ExitLoop

    EndIf

    ; If not then reloop

    ConsoleWrite("Restarting loop" & @CRLF)

WEnd



Func CheckScreen()

    ; Random chance of success
    If Random(0, 1) > 0.9 Then
        $bConfirm = True
    EndIf



EndFunc



Func InformUser($iIndex, $iMode)

    ; Determine if success or failure
    $sMsg = ( ($iMode = 1) ? (" Succeeded") : (" Failed") )
    ; Tell user
    ConsoleWrite("!Update " & $iIndex & $sMsg & @CRLF)
    
EndFunc

Obviously as I do not have access to the various functions you call I have had to produce my own, but I hope that the logic flow does what you require: keep looping until there have been as many success/fail events as there are updates. I can well imagine that you may need to introduce some form of check to make sure that you do not keep counting the same update on every pass - this would be trivial to achieve, but without more details I cannot suggest a suitable method.

M23