Jump to content

TreeView to ListView


Recommended Posts

 Hi,

I need some help please.
I need a simple example, drag & drop from
TreeView to ListView.
I need put in ListView, any item from TreeView, but without elements: Base1 and Base2

 

Thank you!

 

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 457, 192, 192, 124)
$TreeView1 = GUICtrlCreateTreeView(8, 8, 177, 169)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
$TreeView1_0 = GUICtrlCreateTreeViewItem("Base1", $TreeView1)
$TreeView1_1 = GUICtrlCreateTreeViewItem("test1", $TreeView1_0)
$TreeView1_2 = GUICtrlCreateTreeViewItem("test2", $TreeView1_0)
$TreeView1_3 = GUICtrlCreateTreeViewItem("test3", $TreeView1_0)
$TreeView1_4 = GUICtrlCreateTreeViewItem("Base2", $TreeView1)
$TreeView1_5 = GUICtrlCreateTreeViewItem("test1", $TreeView1_4)
$TreeView1_6 = GUICtrlCreateTreeViewItem("test2", $TreeView1_4)
$ListView1 = GUICtrlCreateListView("Items...", 192, 8, 250, 166)

GUICtrlSetState($TreeView1_0, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))
GUICtrlSetState($TreeView1_4, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd
 
Edited by incepator
Link to comment
Share on other sites

  • Moderators

incepator,

Would it not be easier to use a doubleclick?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#include <GuiTreeView.au3>

$hGUI = GUICreate("Test", 500, 500)

$cTreeView = GUICtrlCreateTreeView(8, 8, 177, 169)

$cTreeView_0 = GUICtrlCreateTreeViewItem("Base1", $cTreeView)
GUICtrlCreateTreeViewItem("test1", $cTreeView_0)
GUICtrlCreateTreeViewItem("test2", $cTreeView_0)
GUICtrlCreateTreeViewItem("test3", $cTreeView_0)
$cTreeView_2 = GUICtrlCreateTreeViewItem("Base2", $cTreeView)
GUICtrlCreateTreeViewItem("test4", $cTreeView_2)
GUICtrlCreateTreeViewItem("test5", $cTreeView_2)

GUICtrlSetState($cTreeView_0, $GUI_EXPAND)
GUICtrlSetState($cTreeView_2, $GUI_EXPAND)

$cListView = GUICtrlCreateListView("Items...", 192, 8, 250, 166)

$cAutoExpand = GUICtrlCreateDummy()

GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cAutoExpand

            ; Re-expand the tree
            _GUICtrlTreeView_Expand($cTreeView, GUICtrlRead($cAutoExpand))
    EndSwitch

WEnd



Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $wParam



    ; Create structure
    Local $tStruct = DllStructCreate("hwnd hWndFrom;uint_ptr IDFrom;int Code", $lParam)
    Local $cCID = DllStructGetData($tStruct, "IDFrom")
    Local $iCode = DllStructGetData($tStruct, "Code")

    If $cCID = $cTreeView Then
        ; Check action
        Switch $iCode

            Case $NM_DBLCLK
                ; Get handle of clicked item
                $hItem = GUICtrlGetHandle(GUICtrlRead($cTreeView))
                ; If not at level 0
                If _GUICtrlTreeView_Level($cTreeView, $hItem) Then
                    ; Get text of clicked item
                    $sItem = GUICtrlRead($cTreeView, 1)
                    ; Insert in ListView

                    GUICtrlCreateListViewItem($sItem, $cListView)
                Else
                    ; Fire the dummy to re-expand the tree - cannot be done in the handler
                    GUICtrlSendToDummy($cAutoExpand, $hItem)
                EndIf

        EndSwitch

    EndIf

EndFunc

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

  • Moderators

incepator,

Simple is usually the best way. I will keep looking for a drag/drop solution.

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

  • Moderators

incepator,

Kept me amused this afternoon - drag from TreeView to ListView:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>

Global $fDragging = False, $sDragText, $hDragItem

$hGUI = GUICreate("Test", 300, 200)

$hTreeView = _GUICtrlTreeView_Create($hGUI, 10, 10, 140, 140, _
        BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)
For $i = 1 To 5
    $hItem = _GUICtrlTreeView_Add($hTreeView, $i, "Item" & $i)
    For $j = 1 To 5
        _GUICtrlTreeView_AddChild($hTreeView, $hItem, "SubItem" & $i & "." & $j)
    Next
Next

$cListView = GUICtrlCreateListView("Items       ", 160, 10, 120, 140)

GUISetState(@SW_SHOW, $hGUI)

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYUP
            If $fDragging Then
                $fDragging = False
                ; Look for ListView under cursor
                $aCInfo = GUIGetCursorInfo($hGUI)
                If $aCInfo[4] = $cListView Then
                    ; If not at level 0
                    If _GUICtrlTreeView_Level($hTreeView, $hDragItem) Then
                        ; Insert in ListView
                        GUICtrlCreateListViewItem($sDragText, $cListView)
                    EndIf
                EndIf
            EndIf
    EndSwitch
WEnd

Func _WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHDR, $HwndFrom, $iCode, $tInfo
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $HwndFrom = DllStructGetData($tNMHDR, "HwndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $HwndFrom
        Case $hTreeView
            Switch $iCode
                Case $TVN_BEGINDRAGA, $TVN_BEGINDRAGW
                    Local $tInfo = DllStructCreate($tagNMTREEVIEW, $lParam)
                    $hDragItem = DllStructGetData($tInfo, "NewhItem")
                    $sDragText = _GUICtrlTreeView_GetText($hTreeView, $hDragItem)
                    $fDragging = True
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_NOTIFY

It only works with a UDF-created TreeView - I have yet to work out why this is the case.

M23

Edited by Melba23
Code paste went wrong

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

  • Moderators

incepator,

And here is the drag with a native ListView:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>

Global $fDragging = False

$hGUI = GUICreate("Test", 300, 200)

$cTreeView = GUICtrlCreateTreeView(10, 10, 140, 140)
$cTreeView_0 = GUICtrlCreateTreeViewItem("Base1", $cTreeView)
GUICtrlCreateTreeViewItem("test1", $cTreeView_0)
GUICtrlCreateTreeViewItem("test2", $cTreeView_0)
GUICtrlCreateTreeViewItem("test3", $cTreeView_0)
$cTreeView_2 = GUICtrlCreateTreeViewItem("Base2", $cTreeView)
GUICtrlCreateTreeViewItem("test4", $cTreeView_2)
GUICtrlCreateTreeViewItem("test5", $cTreeView_2)

GUICtrlSetState($cTreeView_0, $GUI_EXPAND)
GUICtrlSetState($cTreeView_2, $GUI_EXPAND)

$cListView = GUICtrlCreateListView("Items       ", 160, 10, 120, 140)

GUISetState(@SW_SHOW, $hGUI)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYUP
            If $fDragging Then
                $fDragging = False
                ; Look for ListView under cursor
                $aCInfo = GUIGetCursorInfo($hGUI)
                If $aCInfo[4] = $cListView Then
                    ; Get handle and text of clicked item
                    $hDragItem = GUICtrlGetHandle(GUICtrlRead($cTreeView))
                    $sDragText = _GUICtrlTreeView_GetText($cTreeView, $hDragItem)
                    ; If not at level 0
                    If _GUICtrlTreeView_Level($cTreeView, $hDragItem) Then
                        ; Insert in ListView
                        GUICtrlCreateListViewItem($sDragText, $cListView)
                    EndIf
                EndIf
            EndIf
        Case $GUI_EVENT_PRIMARYDOWN
            ; Look for ListView under cursor
            $aCInfo = GUIGetCursorInfo($hGUI)
            If $aCInfo[4] = $cTreeView Then
                $fDragging = True

            EndIf
    EndSwitch
WEnd

M23

Edited by Melba23
Simplified code

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

  • Moderators

incepator,

you are very good at some things

I have to tell you that your words do not mean what you think (at least I hope that is the case), but as I believe it was meant as a compliment I shall reply as such.

Glad I could help and comment much appreciated.

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

  • 1 month later...

I encountered a seemingly simple problem, but I can't find a solution :sweating:

I added another gui form, it appears when you click on the item "test1".
The problem is I can not find a way to block "$Form1" when using "$Form2".

Also, when I press 'Esc', I show the msgbox, although I opened Form2.

Perhaps the solution is simple, but I never have encountered this problem before.

 

CODE:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GuiTreeView.au3>
#NoTrayIcon
Opt("GUIOnEventMode", 1)

$Form1 = GUICreate("Form1", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_RESTORE, "SpecialEvents")
$cTreeView = GUICtrlCreateTreeView(8, 8, 177, 169)
$cTreeView_0 = GUICtrlCreateTreeViewItem("Base1", $cTreeView)
GUICtrlCreateTreeViewItem("test1", $cTreeView_0)
GUICtrlCreateTreeViewItem("test2", $cTreeView_0)
GUICtrlCreateTreeViewItem("test3", $cTreeView_0)
$cTreeView_2 = GUICtrlCreateTreeViewItem("Base2", $cTreeView)
GUICtrlCreateTreeViewItem("test4", $cTreeView_2)
GUICtrlCreateTreeViewItem("test5", $cTreeView_2)
GUICtrlSetState($cTreeView_0, $GUI_EXPAND)
GUICtrlSetState($cTreeView_2, $GUI_EXPAND)
$cListView = GUICtrlCreateListView("Items|Items2", 192, 8, 250, 166)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")




$Form2 = GUICreate("Form2", 336, 78, -1, -1, -1, BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $WS_EX_WINDOWEDGE),$Form1)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents2")
$Button1 = GUICtrlCreateButton("add", 152, 16, 75, 25)
GUICtrlSetOnEvent($Button1, "_Button1_add")
$Input1 = GUICtrlCreateInput("exemple", 16, 16, 121, 21)

While 1
    Sleep(100)
WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    Local $tStruct = DllStructCreate("hwnd hWndFrom;uint_ptr IDFrom;int Code", $lParam)
    Local $cCID = DllStructGetData($tStruct, "IDFrom")
    Local $iCode = DllStructGetData($tStruct, "Code")

    If $cCID = $cTreeView Then
        Switch $iCode
            Case $NM_DBLCLK
                $hItem = GUICtrlGetHandle(GUICtrlRead($cTreeView))
                If _GUICtrlTreeView_Level($cTreeView, $hItem) Then
                    $sItem = GUICtrlRead($cTreeView, 1)
                    If $sItem = "test1" Then
                        GUISetState(@SW_SHOW, $Form2)
                    EndIf
                EndIf
        EndSwitch
    EndIf
EndFunc   ;==>_WM_NOTIFY

Func _Button1_add()
    GUICtrlCreateListViewItem("test"&"|"&GUICtrlRead($Input1), $cListView)
EndFunc   ;==>_Button1_add

Func SpecialEvents()
    Select
        Case @GUI_CtrlId = $GUI_EVENT_CLOSE
            If Not IsDeclared("iMsgBoxAnswer") Then Local $iMsgBoxAnswer
            $iMsgBoxAnswer = MsgBox(260, "Info", "Are you sure you want to exit ?", "", $Form1)
            Select
                Case $iMsgBoxAnswer = 6 ;Yes
                    Exit
                Case $iMsgBoxAnswer = 7 ;No
            EndSelect
        Case @GUI_CtrlId = $GUI_EVENT_MINIMIZE
        Case @GUI_CtrlId = $GUI_EVENT_RESTORE
    EndSelect
EndFunc   ;==>SpecialEvents

Func SpecialEvents2()
    Select
        Case @GUI_CtrlId = $GUI_EVENT_CLOSE
            GUISetState(@SW_HIDE, $Form2)
    EndSelect
EndFunc   ;==>SpecialEvents2

Thank you for your time!

Link to comment
Share on other sites

  • Moderators

incepator,

You need to read the Managing Multiple GUIs tutorial in the Wiki.  Here is how your code might look if you had read it:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GuiTreeView.au3>

Opt("GUIOnEventMode", 1)

$Form1 = GUICreate("Form1", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_RESTORE, "SpecialEvents")
$cTreeView = GUICtrlCreateTreeView(8, 8, 177, 169)
$cTreeView_0 = GUICtrlCreateTreeViewItem("Base1", $cTreeView)
GUICtrlCreateTreeViewItem("test1", $cTreeView_0)
GUICtrlCreateTreeViewItem("test2", $cTreeView_0)
GUICtrlCreateTreeViewItem("test3", $cTreeView_0)
$cTreeView_2 = GUICtrlCreateTreeViewItem("Base2", $cTreeView)
GUICtrlCreateTreeViewItem("test4", $cTreeView_2)
GUICtrlCreateTreeViewItem("test5", $cTreeView_2)
GUICtrlSetState($cTreeView_0, $GUI_EXPAND)
GUICtrlSetState($cTreeView_2, $GUI_EXPAND)
$cListView = GUICtrlCreateListView("Items|Items2", 192, 8, 250, 166)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

$Form2 = GUICreate("Form2", 336, 78, -1, -1, -1, BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $WS_EX_WINDOWEDGE),$Form1)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
$Button1 = GUICtrlCreateButton("add", 152, 16, 75, 25)
GUICtrlSetOnEvent($Button1, "_Button1_add")
$Input1 = GUICtrlCreateInput("exemple", 16, 16, 121, 21)
GUISetState(@SW_HIDE, $Form2) ; Hide form2

While 1
    Sleep(100)
WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    Local $tStruct = DllStructCreate("hwnd hWndFrom;uint_ptr IDFrom;int Code", $lParam)
    Local $cCID = DllStructGetData($tStruct, "IDFrom")
    Local $iCode = DllStructGetData($tStruct, "Code")

    If $cCID = $cTreeView Then
        Switch $iCode
            Case $NM_DBLCLK
                $hItem = GUICtrlGetHandle(GUICtrlRead($cTreeView))
                If _GUICtrlTreeView_Level($cTreeView, $hItem) Then
                    $sItem = GUICtrlRead($cTreeView, 1)
                    If $sItem = "test1" Then
                        GUISetState(@SW_DISABLE, $Form1) ; Disable form1
                        GUISetState(@SW_SHOW, $Form2)    ; Show form2
                    EndIf
                EndIf
        EndSwitch
    EndIf
EndFunc   ;==>_WM_NOTIFY

Func _Button1_add()
    GUICtrlCreateListViewItem("test"&"|"&GUICtrlRead($Input1), $cListView)
EndFunc   ;==>_Button1_add

Func SpecialEvents()
    ; Which GUI sent the event
    Switch @GUI_WinHandle
        Case $Form1
            Switch @GUI_CtrlId
                Case $GUI_EVENT_CLOSE
                    ; Check if form2 visible
                    If Not BitAnd(WinGetState($Form2), 2) Then ; $WIN_STATE_VISIBLE
                        ; If not then display MsgBox
                        If MsgBox(260, "Info", "Are you sure you want to exit ?", "", $Form1) = 6 Then ;Yes
                            Exit
                        EndIf
                    EndIf
                Case $GUI_EVENT_MINIMIZE
                Case $GUI_EVENT_RESTORE
            EndSwitch
        Case $Form2
            Switch @GUI_CtrlId
                Case $GUI_EVENT_CLOSE
                    GUISetState(@SW_ENABLE, $Form1) ; Re-enable form1
                    GUISetState(@SW_HIDE, $Form2)   ; Hide form2
                    WinActivate($Form1)
            EndSwitch
    EndSwitch

EndFunc   ;==>SpecialEvents

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...