Help with loop returning an element

[aloalo]

Hello again. I have having some trouble passing an object out of a loop properly in order to deal with it more nicely outside of the function searching for it. The thing I want passed out is the $oTag object, but I can't seem to do anything with the object after my function returns.

expandcollapse popup

Func FrameCrawlerTagSearch($poFrame, $pTag, $pProperty, $pPropertyValue, $pAction = "click", $pLoadWait = 1, $pReturn = 0)
    Local $bDone = False
    _IELoadWait($poFrame)
    $Test = _IEDocReadHTML($poFrame)
    $oTags = _IETagNameAllGetCollection($poFrame)
    For $oTag In $oTags
        If $oTag.tagname = $pTag Then
            If $pProperty = "id" And $oTag.id = $pPropertyValue Then
                MsgBox(0, "", $oTag.id & $pReturn)
                _IEAction($oTag, $pAction)
                If $pLoadWait = 1 Then
                    _IELoadWait($poFrame)
                EndIf
                If $pReturn = 1 Then
                    MsgBox(0, "", "Returning the tag " & $oTag.tagname)
                    Return $oTag
                EndIf
            ElseIf $pProperty = "name" And $oTag.name = $pPropertyValue Then
                _IEAction($oTag, $pAction)
                If $pLoadWait = 1 Then
                    _IELoadWait($poFrame)
                EndIf
            ElseIf $pProperty = "innertext" And StringInStr($oTag.innertext, $pPropertyValue) Then
;~              MsgBox(0, "", $oTag.innertext)
                _IEAction($oTag, $pAction)
                If $pLoadWait = 1 Then
                    _IELoadWait($poFrame)
                EndIf
            EndIf
            $dxCounter = $dxCounter + 1
        EndIf
    Next
    $aSubFrames = _IEFrameGetCollection($poFrame)
    $iNumFrames = @extended
    If $iNumFrames > 0 Then
        $i = 0
        While Not $bDone And $i < $iNumFrames
            $oSubFrame = _IEFrameGetCollection($aSubFrames, $i)
            $bDone = FrameCrawlerTagSearch($oSubFrame, $pTag, $pProperty, $pPropertyValue, $pAction, $pLoadWait, $pReturn)
            If $bDone Then
                Return $bDone
            EndIf
            $i = $i + 1
        WEnd
    EndIf
    Return False
EndFunc   ;==>FrameCrawlerTagSearch

 

[jdelaney]

You will probably need to return an array of objects: 1 for the specific frame object you found it in, and another for the $oTag.

[mLipok]

I suppose the problem is here:

If $bDone Then
                Return $bDone
            EndIf

here is proposal to fix:

expandcollapse popup

Func FrameCrawlerTagSearch($poFrame, $pTag, $pProperty, $pPropertyValue, $pAction = "click", $pLoadWait = 1, $pReturn = 0)
    Local $bDone = False
    _IELoadWait($poFrame)
    $Test = _IEDocReadHTML($poFrame)
    $oTags = _IETagNameAllGetCollection($poFrame)
    For $oTag In $oTags
        If $oTag.tagname = $pTag Then
            If $pProperty = "id" And $oTag.id = $pPropertyValue Then
                MsgBox(0, "", $oTag.id & $pReturn)
                _IEAction($oTag, $pAction)
                If $pLoadWait = 1 Then
                    _IELoadWait($poFrame)
                EndIf
                If $pReturn = 1 Then
                    MsgBox(0, "", "Returning the tag " & $oTag.tagname)
                    Return SetError(0, 1, $oTag)
                EndIf
            ElseIf $pProperty = "name" And $oTag.name = $pPropertyValue Then
                _IEAction($oTag, $pAction)
                If $pLoadWait = 1 Then
                    _IELoadWait($poFrame)
                EndIf
            ElseIf $pProperty = "innertext" And StringInStr($oTag.innertext, $pPropertyValue) Then
;~              MsgBox(0, "", $oTag.innertext)
                _IEAction($oTag, $pAction)
                If $pLoadWait = 1 Then
                    _IELoadWait($poFrame)
                EndIf
            EndIf
            $dxCounter = $dxCounter + 1
        EndIf
    Next
    $aSubFrames = _IEFrameGetCollection($poFrame)
    $iNumFrames = @extended
    If $iNumFrames > 0 Then
        $i = 0
        While Not $bDone And $i < $iNumFrames
            $oSubFrame = _IEFrameGetCollection($aSubFrames, $i)
            $bDone = FrameCrawlerTagSearch($oSubFrame, $pTag, $pProperty, $pPropertyValue, $pAction, $pLoadWait, $pReturn)
            If @extended = 1 Then
                Return SetError(0, 2, $bDone)
            EndIf
            $i = $i + 1
        WEnd
    EndIf
    Return SetError(1, 3, False)
EndFunc   ;==>FrameCrawlerTagSearch

 

EDIT:
btw. if you 

$pReturn = 0

then you always return in 

Return SetError(1, 3, False)

Edited November 19, 2015 by mLipok

[jdelaney]

You can also do this instead...

If IsObj($bDone) Then
   Return $bDone
EndIf

 

Edited November 19, 2015 by jdelaney