LTR Control in an RTL GUI

[Anas]

Hello,

I've a Right-to-Left GUI with a couple of ComboLists that I want to make LTR. I've managed to get the GuiControl to be LTR, but the Drop List is still RTL.

Is this possible?

 

GUICreate("RTL GUI", 200, 100, -1, -1, -1, 0x400000)

GUICtrlCreateCombo("", 50, 10, 120, 20, 0x0003)
GUICtrlSetData(-1, '14-DA-E9-0F-82-8B|C (50 of 200)', '14-DA-E9-0F-82-8B')
GUICtrlSetStyle(-1, 0, 0x04000000)

GUISetState()
While 1
    Switch GUIGetMsg()
        Case -3
            ExitLoop
    EndSwitch
WEnd

 

[Melba23]

Anas,

If you use a standard List control, then this should work:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIComboBox.au3>

$hGUI = GUICreate("Test", 500, 500, Default, Default, Default, $WS_EX_LAYOUTRTL)

$cCombo = GUICtrlCreateCombo("", 10, 10, 200, 20, $CBS_DROPDOWNLIST)
GUICtrlSetData($cCombo, "1|2|3|4|5")
Local $tInfo

_GUICtrlComboBox_GetComboBoxInfo($cCombo, $tInfo)
_WinAPI_SetWindowLong(DllStructGetData($tInfo, "hCombo"), $GWL_EXSTYLE, 0)
_WinAPI_SetWindowLong(DllStructGetData($tInfo, "hList"), $GWL_EXSTYLE, 0)

$cList = GUICtrlCreateList("", 10, 50, 200, 200)
GUICtrlSetData($cList, "1|2|3|4|5")
_WinAPI_SetWindowLong(GUICtrlGetHandle($cList), $GWL_EXSTYLE, 0)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

Note the use of named constants rather than "magic numbers" - much better coding practice to do that, and it helps when you come back to the script a few months later and wonder what those pesky numbers mean!

M23

[Anas]

Hi,

The drop list creates it's own taskbar when opened.  Adding _WinAPI_SetWindowLong(DllStructGetData($tInfo, "hList"), $GWL_HWNDPARENT, $hGUI) Fixed it.

I do use the named constants, honest , but I've been messing with window Info which doesn't give me a "magic number" that I can find in the help file.

 

Thanks Melba.

Edited November 26, 2015 by Anas

[Melba23]

Anas,

I do use the named constants, honest

Delighted to hear it.

M23