Jump to content

_GUICtrlIpAddress_Disable : Disable fields of IPAddress control individually


jguinch
 Share

Recommended Posts

Not sure this is helpful to someone other than me ... :)

#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>
#include <WinAPISys.au3>

Local $hGui = GUICreate("IP Address Control Enable/Disable Example", 400, 300)
Local $hIPAddress1 = _GUICtrlIpAddress_Create($hGui, 10, 10)
Local $hIPAddress2 = _GUICtrlIpAddress_Create($hGui, 10, 40)
Local $hIPAddress3 = _GUICtrlIpAddress_Create($hGui, 10, 70)

_GUICtrlIpAddress_Set($hIPAddress1, "192.168.1.10")
_GUICtrlIpAddress_Set($hIPAddress2, "255.255.255.0")
_GUICtrlIpAddress_Set($hIPAddress3, "192.168.1.1")

_GUICtrlIpAddress_Disable($hIPAddress1, 1)
_GUICtrlIpAddress_Disable($hIPAddress2, 7) ; 4 + 2 + 1
_GUICtrlIpAddress_Disable($hIPAddress3, 0xf) ; 8 + 4 + 2 + 1

GUISetState()

While 1
   $msg = GUIGetMsg()
   If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd


; #FUNCTION# ====================================================================================================================
; Name ..........: _GUICtrlIpAddress_Disable
; Description ...: Disable (grays-out) the specified fields of an IP Address control
; Syntax ........: _GUICtrlIpAddress_Disable($hWnd[, $iFields = 0])
; Parameters ....: $hWnd                - Handle to the control
;                  $iFields             - Fields to enable/disable. Can be a combination of the following :
;                                         0 : Enable all fields
;                                         1 : Disable the first field
;                                         2 : Disable the second field
;                                         4 : Disable the third field
;                                         8 : Disable the fourth field
; Return values .: On success1     - 1
;                  On failure      - 0 and set @error to non zero value
; Author ........: jguinch
; ===============================================================================================================================
Func _GUICtrlIpAddress_Disable($hWnd, $iFields = 0)
    Local $aFields[4], $n = 0, $hEdit

    If Not IsInt($iFields) Or $iFields < 0 Or $iFields > 15 Then Return SetError(3, 0, 0)

    Local $hWindow = _WinAPI_GetAncestor($hWnd)
    If @error Then Return SetError(1, 0, 0)
    If Not $hWindow Or Not WinExists($hWnd) Then Return SetError(2, 0, 0)

    Local $aFields = _WinAPI_EnumChildWindows ($hWnd, False)
    If @error Or $aFields[0][0] <> 4 Then Return SetError(1, 0, 0)

    If $iFields = 0xf Then Return ControlDisable($hWindow, "", $hWnd)
    Local $iRet = ControlEnable($hWindow, "", $hWnd)
    For $i = 0 to 3
        $iRet *= ( BitAND($iFields, 2 ^ $i) ? ControlDisable($hWindow, "", $aFields[4 - $i][0]) : ControlEnable($hWindow, "", $aFields[4 - $i][0]) )
    Next

    Return $iRet
EndFunc

 

Edited by jguinch
Link to comment
Share on other sites

  • 3 months later...
  • 3 weeks later...
  • 1 month later...

I just needed to use this on a project at work and found out that you can't disable the first octet of the IP address correctly. This section of the code was written wrong, and I've corrected it below.

 

;~ Was
    $iRet *= (BitAND($iFields, 1) ? ControlDisable($hWindow, "", $aFields[3][0]) : ControlEnable($hWindow, "", $aFields[4][0]))
    $iRet *= (BitAND($iFields, 2) ? ControlDisable($hWindow, "", $aFields[2][0]) : ControlEnable($hWindow, "", $aFields[3][0]))
    $iRet *= (BitAND($iFields, 4) ? ControlDisable($hWindow, "", $aFields[1][0]) : ControlEnable($hWindow, "", $aFields[2][0]))
    $iRet *= (BitAND($iFields, 8) ? ControlDisable($hWindow, "", $aFields[0][0]) : ControlEnable($hWindow, "", $aFields[1][0]))
;~ Should be
    $iRet *= (BitAND($iFields, 1) ? ControlDisable($hWindow, "", $aFields[4][0]) : ControlEnable($hWindow, "", $aFields[4][0]))
    $iRet *= (BitAND($iFields, 2) ? ControlDisable($hWindow, "", $aFields[3][0]) : ControlEnable($hWindow, "", $aFields[3][0]))
    $iRet *= (BitAND($iFields, 4) ? ControlDisable($hWindow, "", $aFields[2][0]) : ControlEnable($hWindow, "", $aFields[2][0]))
    $iRet *= (BitAND($iFields, 8) ? ControlDisable($hWindow, "", $aFields[1][0]) : ControlEnable($hWindow, "", $aFields[1][0]))

 

If I posted any code, assume that code was written using the latest release version unless stated otherwise. Also, if it doesn't work on XP I can't help with that because I don't have access to XP, and I'm not going to.
Give a programmer the correct code and he can do his work for a day. Teach a programmer to debug and he can do his work for a lifetime - by Chirag Gude
How to ask questions the smart way!

I hereby grant any person the right to use any code I post, that I am the original author of, on the autoitscript.com forums, unless I've specifically stated otherwise in the code or the thread post. If you do use my code all I ask, as a courtesy, is to make note of where you got it from.

Back up and restore Windows user files _Array.au3 - Modified array functions that include support for 2D arrays.  -  ColorChooser - An add-on for SciTE that pops up a color dialog so you can select and paste a color code into a script.  -  Customizable Splashscreen GUI w/Progress Bar - Create a custom "splash screen" GUI with a progress bar and custom label.  -  _FileGetProperty - Retrieve the properties of a file  -  SciTE Toolbar - A toolbar demo for use with the SciTE editor  -  GUIRegisterMsg demo - Demo script to show how to use the Windows messages to interact with controls and your GUI.  -   Latin Square password generator

Link to comment
Share on other sites

If only all my bugs were so easy to fix :)

 

If I posted any code, assume that code was written using the latest release version unless stated otherwise. Also, if it doesn't work on XP I can't help with that because I don't have access to XP, and I'm not going to.
Give a programmer the correct code and he can do his work for a day. Teach a programmer to debug and he can do his work for a lifetime - by Chirag Gude
How to ask questions the smart way!

I hereby grant any person the right to use any code I post, that I am the original author of, on the autoitscript.com forums, unless I've specifically stated otherwise in the code or the thread post. If you do use my code all I ask, as a courtesy, is to make note of where you got it from.

Back up and restore Windows user files _Array.au3 - Modified array functions that include support for 2D arrays.  -  ColorChooser - An add-on for SciTE that pops up a color dialog so you can select and paste a color code into a script.  -  Customizable Splashscreen GUI w/Progress Bar - Create a custom "splash screen" GUI with a progress bar and custom label.  -  _FileGetProperty - Retrieve the properties of a file  -  SciTE Toolbar - A toolbar demo for use with the SciTE editor  -  GUIRegisterMsg demo - Demo script to show how to use the Windows messages to interact with controls and your GUI.  -   Latin Square password generator

Link to comment
Share on other sites

Cool stuff.   Minor tweak (more calculative logic, slight performance increase by my tests):

Local $iRet = ControlEnable($hWindow, "", $hWnd)
    For $iX = 0 to 3
        $iRet *= ( BitAND($iFields, 2 ^ $iX) ? ControlDisable($hWindow, "", $aFields[4-$iX][0]) : ControlEnable($hWindow, "", $aFields[4-$iX][0]) )
    Next
;~     $iRet *=  ( BitAND($iFields, 1) ? ControlDisable($hWindow, "", $aFields[4][0]) : ControlEnable($hWindow, "", $aFields[4][0]) )
;~     $iRet *=  ( BitAND($iFields, 2) ? ControlDisable($hWindow, "", $aFields[3][0]) : ControlEnable($hWindow, "", $aFields[3][0]) )
;~     $iRet *=  ( BitAND($iFields, 4) ? ControlDisable($hWindow, "", $aFields[2][0]) : ControlEnable($hWindow, "", $aFields[2][0]) )
;~     $iRet *=  ( BitAND($iFields, 8) ? ControlDisable($hWindow, "", $aFields[1][0]) : ControlEnable($hWindow, "", $aFields[1][0]) )

Good idea, bad idea?

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...