How to have Esc close child dialog without it closing main dialog

[c.haslam]

I have a child dialog that should close when Esc is pressed, but Esc should not close the parent dialog.

I have Opt('GUICloseOnESC',0) at the top of the parent dialog to disable Esc closing this dialog (which works), but when I put Opt('GUICloseOnESC',1) at the top of the child dialog, pressing Esc does not close the child (I wish it would).

Am I not understanding something?

Is there a way other than GUICloseOnESC ?

[JohnOne]

Simple reproducer?

[nend]

You can use HotKeySet("{Esc}") and close the child window when the hotkey is pressed.

[Melba23]

c.haslam,

I would use an Accelerator key like this:

expandcollapse popup

#include <GUIConstantsEx.au3>

Opt('GUICloseOnESC', 0)

$hGUI = GUICreate("Test", 500, 500)
$cGo = GUICtrlCreateButton("Child", 10, 10, 80, 30)
GUISetState()

$hChild = GUICreate("Child", 200, 200)
$cEscape = GUICtrlCreateDummy()

GUISetState(@SW_HIDE)

Local $aAccelKeys[1][2] = [["{ESCAPE}", $cEscape]]

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $cGo
                    GUISetState(@SW_SHOW, $hChild)
                    GUICtrlSetState($cGo, $GUI_DISABLE)
                    GUISetAccelerators($aAccelKeys, $hChild)
            EndSwitch
        Case $hChild
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE, $cEscape
                    GUISetState(@SW_HIDE, $hChild)
                    GUICtrlSetState($cGo, $GUI_ENABLE)
                    GUISetAccelerators(0, $hChild)
            EndSwitch
    EndSwitch

WEnd

M23

[c.haslam]

Thank you all

Edited February 5, 2016 by c.haslam

[spudw2k]

Using GUIOnEventMode you can specify a function to run on the GUI_CLOSE event.  I use this method in my Plasma_kIt script.  

;psuedo-code / snippets
Opt("GUIOnEventMode", 1)

$hGUI1 = GUICreate(....
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI1Close")

$hGUI2 = GUICreate(....
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI2Close")

Nice and clean.

edit: keep in mind that my child guis "close" functions are really "hide" functions.  I just wanted to share another method.    Search for the GUISetOnEvent lines in my script for closer inspection.

Edited February 24, 2016 by spudw2k