draw a rectanlge to an image

[vkrisz81]

hello

so i tried but i cant find out WHY not

i wanted to draw a single rectangle to an existing image file to test gdi.

but nothing happens

maybe i use wrong that gdi i dont know, but i could not find a simple example for it..

$bitmap=_GDIPlus_ImageLoadFromFile(@ScriptDir&"\image1.jpg")
$bitmap_w=_GDIPlus_ImageGetWidth($bitmap)
$hBrush = _GDIPlus_BrushCreateSolid(0x7F00007F)

_GDIPlus_GraphicsFillRect($bitmap,2,2,100,123,$hBrush)
_GDIPlus_ImageSaveToFile($bitmap,@ScriptDir&"\image1_b.jpg")
_GDIPlus_ImageDispose($bitmap)

so maybe miss something? i cant understand really its logic..

[InunoTaishou]

Looks like you're just trying to draw a rectangle and save it, not draw it. You can draw on bitmaps and you can draw on graphics objects, you cannot draw directly on images loaded from file. Of course I'm sure some GDI+ guru knows how to do it, just not me.

_GDIPlus_Startup()
; Load the image from the file
Local $hWnd_image = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\image1.png")
; Create a bitmap based on the width and height of the image
Local $hWnd_bitmap = _GDIPlus_BitmapCreateFromScan0(_GDIPlus_ImageGetWidth($hWnd_image), _GDIPlus_ImageGetHeight($hWnd_image))
; create a graphics object from the bitmap
Local $hWnd_graphics = _GDIPlus_ImageGetGraphicsContext($hWnd_bitmap)

; draw the image onto the graphic
_GDIPlus_GraphicsDrawImage($hWnd_graphics, $hWnd_image, 0, 0)
; draw a filled rectangle
_GDIPlus_GraphicsFillRect($hWnd_graphics, 2, 2, 100, 123)
; save the bitmap that was used to create the graphic
_GDIPlus_ImageSaveToFile($hWnd_bitmap, @ScriptDir & "\image1_b.jpg")

; clean up resources
_GDIPlus_ImageDispose($hWnd_image)
_GDIPlus_ImageDispose($hWnd_bitmap)
_GDIPlus_GraphicsDispose($hWnd_graphics)
_GDIPlus_Shutdown()

 

[vkrisz81]

yes i wanted to modify directly an image because as if i would like to make watermark, put my logo to photos on my directory, but at first i wish only to be able to draw a rectangle and after it to be able to write some letters to my rectanlge to a given image. i test your script ty

[vkrisz81]

so i tried your script but nothing happens :S

there is no the new file.

i dont know if this is problem, but you start with a PNG file but i have JPG source. i think gdi should handle it so maybe other problem..

[UEZ]

The _GDIPlus_Graphics* draw/fill functions need a graphic handle not an image handle. You have to create a wrapper handle using _GDIPlus_ImageGetGraphicsContext to be able to draw to the image,

Try this:

#include <GDIPlus.au3>

_GDIPlus_Startup()
$bitmap=_GDIPlus_ImageLoadFromFile(@ScriptDir&"\image1.jpg")
$hGfx=_GDIPlus_ImageGetGraphicsContext($bitmap)
$bitmap_w=_GDIPlus_ImageGetWidth($bitmap)
$hBrush=_GDIPlus_BrushCreateSolid(0x7F00007F)

_GDIPlus_GraphicsFillRect($hGfx,2,2,100,123,$hBrush)
_GDIPlus_ImageSaveToFile($bitmap,@ScriptDir&"\image1_b.jpg")
_GDIPlus_GraphicsDispose($hGfx)
_GDIPlus_ImageDispose($bitmap)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_Shutdown()

 

[vkrisz81]

does happen every!  finally just could do it ty uez, now i can start seeking the world of gdi functions.. so it works! now i can step forward to be able to type to the picture

 

Edited February 19, 2016 by vkrisz81