How to restore previous value in an Input control

[c.haslam]

I have a bunch of Input controls that should accept only digits or -1.

Here is a snippet from the GuiGetMsg() loop::

Case $inpIx11Min,$inpIx32Min, ....
    Local $oldVal = ???
    Local $val = GUICtrlRead($nMsg)
    If $val="-1" Or StringIsDigit($val) Then
        $nuVal = $val
    Else
        MsgBox(16,'Invalid index','Enter digit(s) or -1 for no logging of 1D arrays')
        GUICtrlSetData($nMsg,$oldVal)
        ControlClick($Form1,'',$nMsg)
    EndIf

How can I get $oldVal?

[InunoTaishou]

#include <GUIConstants.au3>

Global $frmExample = GUICreate("", 100, 70)
Global $inpUserInput = GUICtrlCreateInput("", 10, 10, 80, 20)
Global $btnUserButton = GUICtrlCreateButton("Press Me", 10, 40, 80, 20)
Global $new_val = ""
Global $old_val = ""

GUISetState(@SW_SHOW, $frmExample)

While (True)
    Switch (GUIGetMsg())
        Case $GUI_EVENT_CLOSe
            GUIDelete($frmExample)
            Exit 0
        Case $btnUserButton
            $new_val = GUICtrlRead($inpUserInput)
            If (Not ($new_val = -1 or $new_val > 0)) Then
                GUICtrlSetData($inpUserInput, $old_val)
                MsgBox("", "", "Invalid number")
            Else
                $old_val = $new_val
            EndIf
    EndSwitch
WEnd

 

Edited February 29, 2016 by InunoTaishou

[BrewManNH]

I'm going to assume that $oldVal is the last value that the input control contained? The only way to do that is to store the contents in the variable somewhere in your script so you can restore it later. Just be aware that where you put the variable assignment depends on how far back the restoration will go, so if you change the contents, you need to decide when you read the old value and when you read the new value.

[Melba23]

c.haslam,

Best to deal with the current content directly:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("",  10, 10, 200, 20)
GUICtrlSetLimit($cInput, 2)

GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

     ; If it was an update message from our input
    If _WinAPI_HiWord($wParam) = $EN_CHANGE And _WinAPI_LoWord($wParam) = $cInput Then

        ; Read the content
        $sContent = GUICtrlRead($cInput)
        ; If it contains anything other than -1 or 0-9
        If Not StringRegExp($sContent, "^(-1|[0-9])$") Then
            ; Replace those characters by spaces
            $sContent = StringRegExpReplace($sContent, "[^-0-9]", "")
            ; If there is a unuary minus
            If StringLeft($sContent, 1) = "-" Then
                ; Remove digit (-1 would have matched above)
                $sContent = "-"
            Else
                ; If not then max 1 digit allowed
                $sContent = StringLeft($sContent, 1)
            EndIf
            ; Reset the content
            GUICtrlSetData($cInput, $sContent)
        EndIf

    EndIf

EndFunc

If you are not used to dealing with Windows messages, I recommend the GUIRegisterMsg tutorial in the Wiki as a starting point. Please ask if you still have any further questions after having read the tutorial.

M23

 

[c.haslam]

Thnak you all -- especially M23