Function called 'empty' from PHP languange in Autoit?

[maniootek]

I couldn't find any build in function in Autoit which can work just like function "empty" in PHP language

http://php.net/manual/en/function.empty.php

I know I can make that function myself but I am just curious if this is already build in. If not what do you think to implement it?

[InunoTaishou]

Anything not an array I use

StringLen($var)

If you want to account for the false then you'll have to add another expression to the statement

(StringLen($var) = 0 or $var == 0)

 

[mikell]

It seems of poor interest while you can use a one-liner

; $var = ""
If not (IsDeclared("var") and $var <> 0) Then Msgbox(0,"", "$var doesn't exist or is empty")

 

[InunoTaishou]

Global $var = "This is a test"

If not (IsDeclared("var") and $var <> 0) Then Msgbox(0,"", "$var doesn't exist or is empty")

Says $var doesn't exist or is empty, but it's not empty. One of the issues I've discovered in autoit is the implicit conversion of string to number. If the string is a number then this is okay but if the string is a normal string then it implicitly converts to 0, as is the case in your example. This is why I use ==, to compare type and value. That works in most cases.

Global $aVars[] = [0, "0", "This is a test", "", 42, "33"]

For $i = 0 To UBound($aVars) - 1
    If (StringLen($aVars[$i]) = 0 Or $aVars[$i] == 0) Then
        MsgBox(0, "", "$aVars[" & $i & "] (" & $aVars[$i] & ") is empty")
    Else
        MsgBox(0, "", "$aVars[" & $i & "] (" & $aVars[$i] & ") is not empty")
    EndIf
Next

Using my example then it will execute as you would think it should.

[mikell]

My bad. I was too hurried and did a mistake

If not (IsDeclared("var") and $var <> false) Then Msgbox(0,"", "$var doesn't exist or is empty")

 

[maniootek]

edited: sorry I was too hurry

 

Edited April 23, 2016 by maniootek

[maniootek]

What do you think about it?

expandcollapse popup

#include <MsgBoxConstants.au3>

Local $aArray[2] = [1, "Example"]
Local $aArray2[0]
Local $dBinary = Binary("")
Local $bBoolean = False
Local $hWnd = WinGetHandle("notexistingwindow")
Local $iInt = 0
Local $fFloat = 0.0
Local $oObject = ObjCreate("Scripting.Dictionary")
Local $sString = ""
Local $tStruct = DllStructCreate("wchar[256]")
Local $vKeyword = Default
Local $fuFunc = ConsoleWrite
Local $fuUserFunc = Test
Func Test()
EndFunc   ;==>Test

MsgBox($MB_SYSTEMMODAL, "", _
        "Variable Types" & @CRLF & @CRLF & _
        "$aArray : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($aArray) & @CRLF & _
        "$aArray2 : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($aArray2) & @CRLF & _
        "$dBinary : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($dBinary) & @CRLF & _
        "$bBoolean : " & @TAB & "IsEmpty: " & IsEmpty($bBoolean) & @CRLF & _
        "$hWnd : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($hWnd) & @CRLF & _
        "$iInt : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($iInt) & @CRLF & _
        "$fFloat : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($fFloat) & @CRLF & _
        "$oObject : " & @TAB & "IsEmpty: " & IsEmpty($oObject) & @CRLF & _
        "$sString : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($sString) & @CRLF & _
        "$tStruct : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($tStruct) & @CRLF & _
        "$vKeyword : " & @TAB & "IsEmpty: " & IsEmpty($vKeyword) & @CRLF & _
        "MsgBox : " & @TAB & @TAB & "IsEmpty: " & IsEmpty(MsgBox) & @CRLF & _
        "$fuFunc : " & @TAB & @TAB & "IsEmpty: " & IsEmpty($fuFunc) & @CRLF & _
        "Func 'Test' : " & @TAB & "IsEmpty: " & IsEmpty(Test) & @CRLF & _
        "$fuUserFunc : " & @TAB & "IsEmpty: " & IsEmpty($fuUserFunc))

Func IsEmpty($data)
    If IsArray($data) Then Return -1
    If StringLen($data) = 0 Then Return True
    If $data = 0 Then Return True
    If $data = Default Then Return True
    Return False
EndFunc   ;==>IsEmpty

 

[mLipok]

Why you are using this:

If IsArray($data) Then Return -1

I think this should be like this:

If IsArray($data) Then 
    If UBound($data) Then Return False
    Return True
EndIf

Edit:

or even beter

If IsArray($data) Then Return (UBound($data) > 0)

 

Edited April 23, 2016 by mLipok

[maniootek]

On 23.04.2016 at 1:56 AM, mLipok said:

I think this should be like this:

If IsArray($data) Then 
    If UBound($data) Then Return False
    Return True
EndIf

 

I tried this, but array still could be "empty". Ubound check size of array (number of rows and cols), not content. Anyway, array check is not needed that much.

[mLipok]

There is difference beetwen entire array and array element.

Array is empty when UBound = 0
Array element is empty when desired element is =0 or is ='' or is =NULL - But this depends on the intended use  of the array variable.