How can I get text of selected option from a dropdown in IE?

[pushkar_nagle]

I am creating a script which will take an asset ID as input from user, put it in a URL, open IE and go to that URL.

After that particular page is opened, it will read data from it and put it in a previously formatted email.

 

I have used innertext, but its returning all the items.

My code snippet below:

;Get Division
Local $oForm = _IEFormGetObjByName($oIE, "aspnetForm")
Local $oTag = _IEFormElementGetObjByName($oForm, "ctl00$middleContentPlaceHolder$ctrlAssets$pAssetDetails$DivisionID$DropDownList1")
Local $Division = _IEPropertyGet($oTag, "innertext")

Edited October 2, 2017 by pushkar_nagle

[mLipok]

Welcome to the forum.
Please red this: 
* How to post code on the forum *
* How to use IE.au3  UDF with  AutoIt v3.3.14.x *

Below you can see how this should look:

HTML snippet: -- removed on request of the OP --

AutoIt code snippet:

;Get Division
Local $oForm = _IEFormGetObjByName($oIE, "aspnetForm")
Local $oTag = _IEFormElementGetObjByName($oForm, "ctl00$middleContentPlaceHolder$ctrlAssets$pAssetDetails$DivisionID$DropDownList1")
Local $Division = _IEPropertyGet($oTag, "innertext")

 

Edited October 2, 2017 by Jos
Removed HTML snippet on request of the OP

[mLipok]

Here is modified Example from HelpFile:

; Open a browser with the form example, get reference to form, get reference
; to select element, cycle 10 times selecting options byValue, byText and byIndex

#include <IE.au3>
#include <MsgBoxConstants.au3>

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oSelect = _IEFormElementGetObjByName($oForm, "selectExample")
_IEAction($oSelect, "focus")
For $i = 1 To 10
    _IEFormElementOptionSelect($oSelect, "Freepage", 1, "byText")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "midipage.html", 1, "byValue")
    MsgBox($MB_SYSTEMMODAL, "Form Element Value", _IEFormElementGetValue($oSelect))

    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, 0, 1, "byIndex")
    Sleep(1000)
Next

_IEQuit($oIE)

I hope it helps you to find how you can solve your problem.

 

---

EDIT:
Some better example:

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/182738-how-can-i-get-text-of-selected-option-from-a-dropdown-in-ie

; Open a browser with the form example, get reference to form, get reference
; to select element, cycle 10 times selecting options byValue, byText and byIndex

#include <IE.au3>
#include <MsgBoxConstants.au3>

_Example()
Func _Example()
    Local $oIE = _IE_Example("form")
    Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
    Local $oSelect = _IEFormElementGetObjByName($oForm, "selectExample")
    _IEAction($oSelect, "focus")

    _IEFormElementOptionSelect($oSelect, "Freepage", 1, "byText")
    ConsoleWrite(_IEFormElementOptionGetSelection($oSelect) & @CRLF)
    MsgBox($MB_SYSTEMMODAL, "Form Element Value", _IEFormElementGetValue($oSelect))

    _IEFormElementOptionSelect($oSelect, "midipage.html", 1, "byValue")
    ConsoleWrite(_IEFormElementOptionGetSelection($oSelect) & @CRLF)
    MsgBox($MB_SYSTEMMODAL, "Form Element Value", _IEFormElementGetValue($oSelect))

    _IEFormElementOptionSelect($oSelect, 0, 1, "byIndex")
    ConsoleWrite(_IEFormElementOptionGetSelection($oSelect) & @CRLF)
    MsgBox($MB_SYSTEMMODAL, "Form Element Value", _IEFormElementGetValue($oSelect))


    _IEQuit($oIE)
EndFunc   ;==>_Example

Func _IEFormElementOptionGetSelection($oObject)
    Local $oOptions_coll = $oObject.Options
    For $oOption_enum In $oOptions_coll
        If $oOption_enum.selected Then Return $oOption_enum.outerHtml
    Next
EndFunc

 

Edited May 27, 2016 by mLipok

[pushkar_nagle]

Thanks mLipok for your suggestion.

I corrected my code and its working properly now.

Corrected code:

;Get Division
Local $oForm = _IEFormGetObjByName($oIE, "aspnetForm")
Local $oTag = _IEFormElementGetObjByName($oForm, "ctl00$middleContentPlaceHolder$ctrlAssets$pAssetDetails$DivisionID$DropDownList1")
_IEAction($oTag, "focus")
Func _IEFormElementOptionGetSelection($oTag)
    Local $oOptions_coll = $oTag.Options
    For $oOption_enum In $oOptions_coll
        If $oOption_enum.selected Then Return $oOption_enum.innertext
           Next
EndFunc
     Local $Division = _IEFormElementOptionGetSelection($oTag)