Jump to content

how to end a while loop with a stop button


Recommended Posts

.

Hi everyone, I am new to autoIt. I'm sure this is a common question but I searched the forums and haven't had any luck.

I've made a GUI that requires a user input. When "button1" is pressed, it begins a while loop with a counter and stops once the counter reaches the number the user inputs.

The problem is sometimes I would like to end the script before the counter reaches the number the user inputed. However, the script is unresponsive when I hit  "button2", the stop button. Can anyone point out how I could fix this?

 

Thanks!

 

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 0)
#Region ### START Koda GUI section ### Form=c:\users\atkinspr\documents\main1.kxf
Global $main1 = GUICreate("main1", 543, 313, 281, 283)
Global $Input1 = GUICtrlCreateInput("", 40, 128, 121, 24)
Global $Button1 = GUICtrlCreateButton("Start", 40, 168, 123, 25)
Global $Label1 = GUICtrlCreateLabel("Counter: ", 40, 232, 70, 25)
Global $Button2 = GUICtrlCreateButton("Stop", 200, 168, 123, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
            Exit
          Case $button1
            $DataFromUser = GUICtrlRead($input1)
            $i = 0
            while $i < $DataFromUser
               $i = $i + 1
               Sleep(1000)
               GUICtrlSetData($Label1,  "Counter: " &$i)
               ConsoleWrite("output:  " &$i &@LF )
            WEnd
         Case $Button2
            Exit
    EndSwitch
 WEnd

 

Link to comment
Share on other sites

This is one of possible solution:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 0)
#Region ### START Koda GUI section ### Form=c:\users\atkinspr\documents\main1.kxf
Global $main1 = GUICreate("main1", 543, 313, 281, 283)
Global $Input1 = GUICtrlCreateInput("", 40, 128, 121, 24)
Global $Button1 = GUICtrlCreateButton("Start", 40, 168, 123, 25)
Global $Label1 = GUICtrlCreateLabel("Counter: ", 40, 232, 70, 25)
Global $Button2 = GUICtrlCreateButton("Stop", 200, 168, 123, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global $bWorkInProgress = False
Global $i, $DataFromUser
While 1
    If $bWorkInProgress Then
        $i = $i + 1
        If $i >= $DataFromUser Then
            $bWorkInProgress = False
        Else
            Sleep(100)
            GUICtrlSetData($Label1, "Counter: " & $i)
            ConsoleWrite("output:  " & $i & @LF)
        EndIf
    EndIf
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            $bWorkInProgress = True
            $DataFromUser = GUICtrlRead($Input1)
            $i = 0
        Case $Button2
            ConsoleWrite("! END" & @CRLF)
            $bWorkInProgress = False
    EndSwitch
WEnd

 

I'm sure, not the best one.
 

Edited by mLipok

Signature beginning:
Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Codefor other useful stuff click the following button:

Spoiler

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind. 

My contribution (my own projects): * Debenu Quick PDF Library - UDF * Debenu PDF Viewer SDK - UDF * Acrobat Reader - ActiveX Viewer * UDF for PDFCreator v1.x.x * XZip - UDF * AppCompatFlags UDF * CrowdinAPI UDF * _WinMergeCompare2Files() * _JavaExceptionAdd() * _IsBeta() * Writing DPI Awareness App - workaround * _AutoIt_RequiredVersion() * Chilkatsoft.au3 UDF * TeamViewer.au3 UDF * JavaManagement UDF * VIES over SOAP * WinSCP UDF * GHAPI UDF - modest begining - comunication with GitHub REST APIErrorLog.au3 UDF - A logging Library * Include Dependency Tree (Tool for analyzing script relations) * Show_Macro_Values.au3 *

 

My contribution to others projects or UDF based on  others projects: * _sql.au3 UDF  * POP3.au3 UDF *  RTF Printer - UDF * XML.au3 UDF * ADO.au3 UDF SMTP Mailer UDF * Dual Monitor resolution detection * * 2GUI on Dual Monitor System * _SciLexer.au3 UDF * SciTE - Lexer for console pane

Useful links: * Forum Rules * Forum etiquette *  Forum Information and FAQs * How to post code on the forum * AutoIt Online Documentation * AutoIt Online Beta Documentation * SciTE4AutoIt3 getting started * Convert text blocks to AutoIt code * Games made in Autoit * Programming related sites * Polish AutoIt Tutorial * DllCall Code Generator * 

Wiki: Expand your knowledge - AutoIt Wiki * Collection of User Defined Functions * How to use HelpFile * Good coding practices in AutoIt * 

OpenOffice/LibreOffice/XLS Related: WriterDemo.au3 * XLS/MDB from scratch with ADOX

IE Related:  * How to use IE.au3  UDF with  AutoIt v3.3.14.x * Why isn't Autoit able to click a Javascript Dialog? * Clicking javascript button with no ID * IE document >> save as MHT file * IETab Switcher (by LarsJ ) * HTML Entities * _IEquerySelectorAll() (by uncommon) * IE in TaskSchedulerIE Embedded Control Versioning (use IE9+ and HTML5 in a GUI) * PDF Related:How to get reference to PDF object embeded in IE * IE on Windows 11

I encourage you to read: * Global Vars * Best Coding Practices * Please explain code used in Help file for several File functions * OOP-like approach in AutoIt * UDF-Spec Questions *  EXAMPLE: How To Catch ConsoleWrite() output to a file or to CMD *

I also encourage you to check awesome @trancexx code:  * Create COM objects from modules without any demand on user to register anything. * Another COM object registering stuffOnHungApp handlerAvoid "AutoIt Error" message box in unknown errors  * HTML editor

winhttp.au3 related : * https://www.autoitscript.com/forum/topic/206771-winhttpau3-download-problem-youre-speaking-plain-http-to-an-ssl-enabled-server-port/

"Homo sum; humani nil a me alienum puto" - Publius Terentius Afer
"Program are meant to be read by humans and only incidentally for computers and execute" - Donald Knuth, "The Art of Computer Programming"
:naughty:  :ranting:, be  :) and       \\//_.

Anticipating Errors :  "Any program that accepts data from a user must include code to validate that data before sending it to the data store. You cannot rely on the data store, ...., or even your programming language to notify you of problems. You must check every byte entered by your users, making sure that data is the correct type for its field and that required fields are not empty."

Signature last update: 2023-04-24

Link to comment
Share on other sites

Or something like this (using AdlibRegister):

#include <GUIConstantsEx.au3>

#Region ### START Koda GUI section ### Form=c:\users\atkinspr\documents\main1.kxf
Global $main1 = GUICreate("main1", 543, 313, 281, 283)
Global $Input1 = GUICtrlCreateInput("", 40, 128, 121, 24)
Global $Button1 = GUICtrlCreateButton("Start", 40, 168, 123, 25)
Global $Label1 = GUICtrlCreateLabel("Counter: ", 40, 232, 70, 25)
Global $Button2 = GUICtrlCreateButton("Stop", 200, 168, 123, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global $i, $DataFromUser
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            $DataFromUser = GUICtrlRead($Input1)
            $i = 0
            AdlibRegister("_SetCounter", 100)
        Case $Button2
            AdlibUnRegister("_SetCounter")
    EndSwitch
WEnd

Func _SetCounter()
    $i = $i + 1
    If $i > $DataFromUser Then
        AdlibUnRegister("_SetCounter")
    Else
        GUICtrlSetData($Label1, "Counter: " & $i)
    EndIf
EndFunc   ;==>_SetCounter

 

My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2022-02-19 - Version 1.6.1.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2017-07-21 - Version 0.4.0.1) - Download - General Help & Support - Example Scripts
OutlookEX (2021-11-16 - Version 1.7.0.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX_GUI (2021-04-13 - Version 1.4.0.0) - Download
Outlook Tools (2019-07-22 - Version 0.6.0.0) - Download - General Help & Support - Wiki
PowerPoint (2021-08-31 - Version 1.5.0.0) - Download - General Help & Support - Example Scripts - Wiki
Task Scheduler (NEW 2022-07-28 - Version 1.6.0.1) - Download - General Help & Support - Wiki

Standard UDFs:
Excel - Example Scripts - Wiki
Word - Wiki

Tutorials:
ADO - Wiki
WebDriver - Wiki

 

Link to comment
Share on other sites

  • Moderators

atkinspr,

Welcome to the AutoIt forums.

The Interrupting a running function tutorial in the Wiki will explain several ways to do this.

M23

 

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

I replied to similar question very often, last time i created:

Func _WaitForGuiGetMsg($iMSec, $sIDs = String($GUI_EVENT_CLOSE))
    ;syntax _WaitForGuiGetMsg($iMSec, $sIDs)
    ;Parameters $iMSec:     maximum Time waiting for a Message
    ;           $sIDs:      a string with all watched Message-IDs seperated by "|"
    ;return     $iMsg       one of the watched IDs or 0
    Local $aIDs = StringSplit($sIDs, '|', 2)
    ;_ArrayDisplay($aIDs)
    Local $iStart = TimerInit()
    Local $iMsg
    Local $iRet = 0
    Do
        $iMsg = GUIGetMsg()
        For $i = 0 To UBound($aIDs) - 1
            If $aIDs[$i] = $iMsg Then
                ;ConsoleWrite('Found: ' & $iMsg & @CRLF)
                $iRet = $iMsg
                ExitLoop 2
            EndIf
        Next
    Until TimerDiff($iStart) >= $iMSec
    Return $iRet
EndFunc   ;==>_WaitForGuiGetMsg

You have to call this in your loop you want to exit in special cases and react on the returned MsgID.

Link to comment
Share on other sites

I might look like a noob but my solution is very simple lol, I find it effective though in my scripts.

 

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 0)
#Region ### START Koda GUI section ### Form=c:\users\atkinspr\documents\main1.kxf
Global $main1 = GUICreate("main1", 543, 313, 281, 283)
Global $Input1 = GUICtrlCreateInput("", 40, 128, 121, 24)
Global $Button1 = GUICtrlCreateButton("Start", 40, 168, 123, 25)
Global $Label1 = GUICtrlCreateLabel("Counter: ", 40, 232, 70, 25)
Global $Button2 = GUICtrlCreateButton("stoploop", 200, 168, 123, 25)
global $Stop = 0
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While $Stop < 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
            Exit
          Case $button1
            $DataFromUser = GUICtrlRead($input1)
            $i = 0
            while $i < $DataFromUser
               $i = $i + 1
               Sleep(1000)
               GUICtrlSetData($Label1,  "Counter: " &$i)
               ConsoleWrite("output:  " &$i &@LF )
            WEnd
         Case $Button2
            stoploop()
            $stop = 1
    EndSwitch
 WEnd

 func stoploop()
 $stop = $Stop+1
 EndFunc



 

Edited by Annonyreeder
Link to comment
Share on other sites

Your script doesn't do this

Quote

The problem is sometimes I would like to end the script before the counter reaches the number the user inputed.

 

My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2022-02-19 - Version 1.6.1.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2017-07-21 - Version 0.4.0.1) - Download - General Help & Support - Example Scripts
OutlookEX (2021-11-16 - Version 1.7.0.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX_GUI (2021-04-13 - Version 1.4.0.0) - Download
Outlook Tools (2019-07-22 - Version 0.6.0.0) - Download - General Help & Support - Wiki
PowerPoint (2021-08-31 - Version 1.5.0.0) - Download - General Help & Support - Example Scripts - Wiki
Task Scheduler (NEW 2022-07-28 - Version 1.6.0.1) - Download - General Help & Support - Wiki

Standard UDFs:
Excel - Example Scripts - Wiki
Word - Wiki

Tutorials:
ADO - Wiki
WebDriver - Wiki

 

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...