JavaScript - How to click on specific value? (Virtual Keyboard in JS)

[kelso]

Hello All,

I am trying to utilize a virtual keyboard website and click on specific values, the website is written and javascript and I am seeking your help-

JavaScript code:

<div id = "keyboard"></div>
  
 #each button is:
 #this is example for the letter D
  
  <input type="button" value="D" onclick="oKeyboard.doKeyHandle(this.value);" style="border:black 2px solid; padding:4px; margin:0px 2px 2px 0px; width:30px;font-weight:bold;font-family:arial; min-height:12px;">

 

Now my mission is "simple", click on the button for the letter "D" 5 times using an AutoIT script.

What functions can I use in AutoIT to do so?

 

Thank you!

 

Edited June 25, 2016 by kelso

[AutoBert]

You can use the functions of the IE.au3. I think

_IE_Example

is a good startpoint for beginning.

[kelso]

17 minutes ago, AutoBert said:

You can use the functions of the IE.au3. I think

_IE_Example

is a good startpoint for beginning.

Thank You AutoBert,

I reviewed the examples and went through the documentation, but clearly there is something simple I am missing. I understand how to take the right elements from the code, I just don't understand which AutoIt functions can help in my case.

 

Any suggestions?

[kelso]

ping, anyone?

[mLipok]

try this:

Func _IE_ClickInInput_D(ByRef $oIE)
    Local $oInput_coll = _IETagNameGetCollection($oIE,'input')
    If @error then Return SetError(@error, @extended, 0)

    For $oInput_enum In $oInput_coll
        If $oInput_enum.value="D" And $oInput_enum.onclick = "oKeyboard.doKeyHandle(this.value);" Then 
            $oInput_enum.click()
            If @error then Return SetError($_IESTATUS_ComError, @error, 0)
            
            Return SetError($_IESTATUS_Success, 0, 1)
        EndIf
    Next
    Return SetError($_IESTATUS_NoMatch, 2,0)
EndFunc

 

Edited June 27, 2016 by mLipok

[MichaelHB]

Hi @kelso

Two questions:

Can you share the website that has this virtual keyboard?

Did you try to click the input element (_IEAction($oElement, "click"))?

[kelso]

5 minutes ago, mLipok said:

try this:

Func _IE_ClickInInput_D(ByRef $oIE)
    Local $oInput_coll = _IETagNameGetCollection($oIE,'input')
    If @error then Return SetError(@error, @extended, 0)

    For $oInput_enum In $oInput_coll
        If $oInput_enum.onclick = "oKeyboard.doKeyHandle(this.value);" Then 
            $oInput_enum.click()
            Return SetError($_IESTATUS_Success, 0, 1)
        EndIf
    Next
    Return SetError($_IESTATUS_NoMatch, 2,0)
EndFunc

 

didn't work, I don't thin we specify the value "d" here.

5 minutes ago, MichaelHB said:

Hi @kelso

Two questions:

Can you share the website that has this virtual keyboard?

Did you try to click the input element (_IEAction($oElement, "click"))?

I have, but failed miserably.

here is the link:

http://www.jamesburt.com/Demos/Javascript/VirtualKeyboard/

 

[mLipok]

8 minutes ago, kelso said:

didn't work, I don't thin we specify the value "d" here.

Refresh your browser, and read again my example.

 

[kelso]

3 minutes ago, mLipok said:

Refresh your browser, and read again my example.

 

here is what I tried, still doesn't work and doesn't show an error

 

Local $ie = _IECreate("http://www.jamesburt.com/Demos/Javascript/VirtualKeyboard/")
sleep(5000)
Func _IE_ClickInInput_D(ByRef $oIE)
    Local $oInput_coll = _IETagNameGetCollection($oIE,'input')
    If @error then Return SetError(@error, @extended, 0)

    For $oInput_enum In $oInput_coll
        If $oInput_enum.value="D" And $oInput_enum.onclick = "oKeyboard.doKeyHandle(this.value);" Then
            $oInput_enum.click()
            If @error then Return SetError($_IESTATUS_ComError, @error, 0)

            Return SetError($_IESTATUS_Success, 0, 1)
        EndIf
    Next
    Return SetError($_IESTATUS_NoMatch, 2,0)
EndFunc

 

[mLipok]

Tryt this snippet:

#include <IE.au3>
#include <MsgBoxConstants.au3>


_Example()
Func _Example()
    Local $oIE = _IEAttach('http://www.jamesburt.com/Demos/Javascript/VirtualKeyboard/', 'url')
    _IE_ClickInInput_D($oIE)
    If @error Then MsgBox($MB_ICONERROR, 'ClickInput D', '@error = ' & @error & @CRLF & '@extended = ' & @extended)

EndFunc


Func _IE_ClickInInput_D(ByRef $oIE)
    Local $oInput_coll = _IETagNameGetCollection($oIE,'input')
    If @error then Return SetError(@error, @extended, 0)

    For $oInput_enum In $oInput_coll
        ConsoleWrite('! ' & $oInput_enum.onclick & @CRLF)
        If $oInput_enum.value="D" And StringInStr($oInput_enum.outerhtml, "oKeyboard.doKeyHandle(this.value);") Then
            $oInput_enum.click()
            If @error then Return SetError(@error, @extended, 0)

            Return SetError($_IESTATUS_Success, 0, 1)
        EndIf
    Next
    Return SetError($_IESTATUS_NoMatch, 2,0)
EndFunc

ConsoleWrite shows why previous attempt wont work.

mLipok

Edited June 27, 2016 by mLipok

[kelso]

7 minutes ago, mLipok said:

Tryt this snippet:

#include <IE.au3>
#include <MsgBoxConstants.au3>


_Example()
Func _Example()
    Local $oIE = _IEAttach('http://www.jamesburt.com/Demos/Javascript/VirtualKeyboard/', 'url')
    _IE_ClickInInput_D($oIE)
    If @error Then MsgBox($MB_ICONERROR, 'ClickInput D', '@error = ' & @error & @CRLF & '@extended = ' & @extended)

EndFunc


Func _IE_ClickInInput_D(ByRef $oIE)
    Local $oInput_coll = _IETagNameGetCollection($oIE,'input')
    If @error then Return SetError(@error, @extended, 0)

    For $oInput_enum In $oInput_coll
        ConsoleWrite('! ' & $oInput_enum.onclick & @CRLF)
        If $oInput_enum.value="D" And StringInStr($oInput_enum.outerhtml, "oKeyboard.doKeyHandle(this.value);") Then
            $oInput_enum.click()
            If @error then Return SetError(@error, @extended, 0)

            Return SetError($_IESTATUS_Success, 0, 1)
        EndIf
    Next
    Return SetError($_IESTATUS_NoMatch, 2,0)
EndFunc

ConsoleWrite shows why previous attempt wont work.

mLipok

didn't gave an error beside "!" with the 'url', when I removed the 'url' it gave the following error:

 

.

 

 

[mLipok]

18 minutes ago, kelso said:

didn't gave an error beside "!" with the 'url',

??
Show me ConsoleOutput from my snippet (without any changes) .
NOTE: this url should be already opened in IE .

 

Edited June 27, 2016 by mLipok

[kelso]

my bad. it worked!

you are the man!!!

[mLipok]

I'm glad it works as intended

mLipok