StdoutRead

[hendrikhe]

Hello AutoIt community,

I am executing several CMD commands and I would like to display / save the output but the array is almost empty:

 

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3>


$CMD = 'echo C:\Users:ipconfig /flushdns && ' & _
       'ipconfig /flushdns && ' & _
        'echo C:\Users:net stop dnscache && ' & _
        'net stop dnscache && ' & _
        'echo C:\Users:ipconfig /flushdns && ' & _
        'ipconfig /flushdns && ' & _
        'echo C:\Users:net start dnscache && ' & _
        'net start dnscache && ' & _
        'echo C:\Users:ipconfig /flushdns && ' & _
        'ipconfig /flushdns && ' & _
        'echo C:\Users:ipconfig /all && ' & _
        'ipconfig /all && ' & _
        'echo C:\Users:hostname && ' & _
        'hostname && ' & _
         'dir | clip'

Local $iPID = RunWait('"' & @ComSpec & '" /k ' & $CMD, @SystemDir)
Local $sOutput = StdoutRead($iPID)
Local $aArray = StringSplit(StringTrimRight(StringStripCR($sOutput), StringLen(@CRLF)), @CRLF)


 _ArrayDisplay($aArray)

[mLipok]

Check HelpFile for:

StderrRead()

Focus on:
 

...
    While 1
        $sOutput = StdoutRead($iPID)
        If @error Then ; Exit the loop if the process closes or StdoutRead returns an error.
            ExitLoop
        EndIf
        MsgBox($MB_SYSTEMMODAL, "Stdout Read:", $sOutput)
    WEnd
...

 

[MattHiggs]

You also might want to take a look in the help file concerning the differences between "Run" and "runwait".  In other words, use "run" rather than "runwait", since it has the opt flag you need.  In terms of waiting for process to complete, use "processwaitclose" with the handle to the process.

[SadBunny]

Couple of points:

1. the /k makes the spawned cmd.exe remain open, you probably want the /c
2. 99% sure you should quote the dos commands you're chaining
3. you have to include the $STDOUT_CHILD flag

Try this example:

#include <AutoItConstants.au3>

$CMD = 'echo ipconfig /all && ipconfig /all'
Local $iPID = Run(@ComSpec & ' /c "' & $CMD & '"', @SystemDir, @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($iPID)
Local $sOutput = StdoutRead($iPID)
MsgBox(0, "Output", $sOutput)

Note that I put quotes around the actual $CMD, I switched the /k to /c and I added the $STDOUT_CHILD. (And the @SW_HIDE for good measure to   )

That $aArray line in your script looks like it was copypasted from the helpfile. Don't know if you actually want that output split into that array but of course it's not necessary if you just want to store all that output in a variable.

Hope this helps.

[hendrikhe]

Thank you SadBunny that worked very well.

I am trying now to save the output in a file, it does not create the file on my desktop

and even with I uncomment _FileCreate(@DesktopDir & "xxxxx.txt") it does not create the file on my desktop

 

Now I got an Output

 

$CMD = 'echo C:\Users:ipconfig /flushdns && ' & _
       'ipconfig /flushdns && ' & _
        'echo C:\Users:net stop dnscache && ' & _
        'net stop dnscache && ' & _
        'echo C:\Users:ipconfig /flushdns && ' & _
        'ipconfig /flushdns && ' & _
        'echo C:\Users:net start dnscache && ' & _
        'net start dnscache && ' & _
        'echo C:\Users:ipconfig /flushdns && ' & _
        'ipconfig /flushdns && ' & _
        'echo C:\Users:ipconfig /all && ' & _
        'ipconfig /all && ' & _
        'echo C:\Users:hostname && ' & _
        'hostname && ' & _
         'echo C:\Users:PLEASE RESTART COMPUTER '

RunWait('"' & @ComSpec & '" /k ' & $CMD, @SystemDir)

Local $iPID = Run(@ComSpec & ' /c "' & $CMD & '"', @SystemDir, @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($iPID)
Local $sOutput = StdoutRead($iPID)

;~ _FileCreate(@DesktopDir & "xxxxx.txt")

$file = FileOpen (@DesktopDir & "xxxxx.txt", 2)
FileWrite($file, $sOutput)
FileClose($file)

MsgBox(0, "Output", $sOutput)

 

 

Edited July 6, 2016 by hendrikhe

[SadBunny]

Try adding a backslash before your filename, as @DesktopDir does not add that for you. So

$file = FileOpen (@DesktopDir & "\xxxxx.txt", 2)

(And check for a file in your c:\users\blah\ called "Desktopxxxxx.txt"  )

[hendrikhe]

that "\" changed my life, thank you

[SadBunny]

No problem, glad I could help.