How to hide focus rectangle for any control?

[kosamja]

Is it possible to hide focus rectangle for any control in any window? I tried this, but focus rectangle appears on mouse hover or click:

expandcollapse popup

; www.autoitscript.com/forum/topic/56536-easy-shell-hooking-example/?page=2
; autohotkey.com/board/topic/82458-how-to-disable-the-standard-focus-rectangle/

#NoTrayIcon
#include<WinAPI.au3>
#include<WinAPISys.au3>
#include<WindowsConstants.au3>

Opt("WinWaitDelay", 0)
Opt("MouseClickDelay", 0)
Opt("MouseClickDownDelay", 0)
Opt("MouseClickDragDelay", 0)
Opt("SendKeyDelay", 0)
Opt("SendKeyDownDelay", 0)
Opt("WinTitleMatchMode", 3)

Global Const $UISF_HIDEFOCUS = 0x10001
$hHookFunc = DllCallbackRegister('_WinEventProc', 'none', 'ptr;uint;hwnd;int;int;uint;uint')
$hWinHook = _WinAPI_SetWinEventHook($EVENT_OBJECT_FOCUS, $EVENT_OBJECT_FOCUS, DllCallbackGetPtr($hHookFunc))

While 1
   _HighPrecisionSleep(0.1)
WEnd

Func _WinEventProc($hHook, $iEvent, $hWnd, $iObjectID, $iChildID, $iEventThread, $imsEventTime)
   If $iEvent = $EVENT_OBJECT_FOCUS Then
      _SendMessage($hWnd, $WM_CHANGEUISTATE, $UISF_HIDEFOCUS)
      _SendMessage($hWnd, $WM_UPDATEUISTATE, $UISF_HIDEFOCUS)
   EndIf
EndFunc

Func _HighPrecisionSleep($iMicroSeconds,$hDll=False)
   Local $hStruct, $bLoaded
   If Not $hDll Then
      $hDll=DllOpen("ntdll.dll")
      $bLoaded=True
   EndIf
   $hStruct=DllStructCreate("int64 time;")
   DllStructSetData($hStruct,"time",-1*($iMicroSeconds*10))
   DllCall($hDll,"dword","ZwDelayExecution","int",0,"ptr",DllStructGetPtr($hStruct))
   If $bLoaded Then DllClose($hDll)
EndFunc

 

Edited August 7, 2016 by kosamja

[kosamja]

bump... Just to check is this not possible without dll?

[UEZ]

Is this what you are looking for? -> 

 

[kosamja]

yes, but for every window.  NoFocusLines works only for autoit gui.

Edited August 12, 2016 by kosamja

[UEZ]

Ok, what is the purpose to do so for external windows?

[kosamja]

to remove that ugly dotted focus rectangle...

[water]

So it is just for cosmetic reasons?

[kosamja]

Yes, and because its annoying since it appears on every control that is clicked or has focus.

Edited August 12, 2016 by kosamja

[Jos]

Maybe I can recommend a mental coach to help you deal with a standard Windows feature?

[kosamja]

standard Windows feature I havent seen for years thanks to RemoveFocusRect.dll. Unfortunately that dll doesnt work if secure boot on UEFI is enabled since in that case AppInit_DLLs is disabled. I guess I can just disable secure boot, but I thought I can instead use autoit for removal of focus rectangle, but it looks I cant.

[Danyfirex]

Hello. First UISF_HIDEFOCUS constant has not that value :S It's defined as UISF_HIDEFOCUS=0x1

_HighPrecisionSleep Function is pretty wrong.

Check

expandcollapse popup

; www.autoitscript.com/forum/topic/56536-easy-shell-hooking-example/?page=2
; autohotkey.com/board/topic/82458-how-to-disable-the-standard-focus-rectangle/

;~ #NoTrayIcon
#include <WinAPI.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Opt("WinWaitDelay", 0)
Opt("MouseClickDelay", 0)
Opt("MouseClickDownDelay", 0)
Opt("MouseClickDragDelay", 0)
Opt("SendKeyDelay", 0)
Opt("SendKeyDownDelay", 0)
Opt("WinTitleMatchMode", 3)

Global $hNTDll = DllOpen("ntdll.dll") ;just load once :P

Global Const $UIS_SET = 1
Global Const $UIS_CLEAR = 2
Global Const $UISF_HIDEFOCUS = 0x1

OnAutoItExitRegister("_Free")


Global $hHookFunc = DllCallbackRegister('_WinEventProc', 'none', 'ptr;uint;hwnd;int;int;uint;uint')
Global $hWinHook = _WinAPI_SetWinEventHook($EVENT_OBJECT_CREATE, $EVENT_OBJECT_CREATE, DllCallbackGetPtr($hHookFunc))


While 1
    _HighPrecisionSleep(0.1)
WEnd

Func _Free()
    If $hWinHook Then _WinAPI_UnhookWinEvent($hWinHook)
    If $hHookFunc Then DllCallbackFree($hHookFunc)
    If $hNTDll Then DllClose($hNTDll)
EndFunc   ;==>_Free


Func _WinEventProc($hHook, $iEvent, $hWnd, $iObjectID, $iChildID, $iEventThread, $imsEventTime)
    _SendMessage($hWnd, $WM_CHANGEUISTATE, _WinAPI_MakeLong($UIS_CLEAR, $UISF_HIDEFOCUS))
    _SendMessage($hWnd, $WM_UPDATEUISTATE, _WinAPI_MakeLong($UIS_SET, $UISF_HIDEFOCUS))
EndFunc   ;==>_WinEventProc



Func _HighPrecisionSleep($iMicroSeconds)
    Local $hStruct = DllStructCreate("int64 time;")
    DllStructSetData($hStruct, "time", -1 * ($iMicroSeconds * 10))
    DllCall($hNTDll, "dword", "NtDelayExecution", "int", 0, "ptr", DllStructGetPtr($hStruct))
EndFunc   ;==>_HighPrecisionSleep

 

 

Saludos