First Input capable field

[Docfxit]

How can I position the cursor to the first input capable field of a program that I open?

Thanks,

Docfxit

[InunoTaishou]

_WinAPI_SetFocus will select the control you want

#include <WinAPI.au3>
#include <GUIConstants.au3>

Global $frmMain = GUICreate("", 130, 160)
Global $inp1 = GUICtrlCreateInput("", 10, 10, 50, 20)
Global $inp2 = GUICtrlCreateInput("", 70, 10, 50, 20)
Global $inp3 = GUICtrlCreateInput("", 10, 40, 50, 20)
Global $inp4 = GUICtrlCreateInput("", 70, 40, 50, 20)
Global $inp5 = GUICtrlCreateInput("", 10, 70, 50, 20)
Global $inp6 = GUICtrlCreateInput("", 70, 70, 50, 20)
Global $inp7 = GUICtrlCreateInput("", 10, 100, 50, 20)
Global $inp8 = GUICtrlCreateInput("", 70, 100, 50, 20)
Global $btnFocus = GUICtrlCreateButton("Focus!", 10, 130, 110, 20)

GUISetState(@SW_SHOW, $frmMain)

While (True)
    Switch (GUIGetMsg())
        Case $GUI_EVENT_CLOSE
            Exit 0

        Case $btnFocus
            _WinAPI_SetFocus(GUICtrlGetHandle(Eval("inp" & Random(1, 8, 1))))
    EndSwitch
WEnd

 

Edited August 7, 2016 by InunoTaishou

[Melba23]

Docfxit,

If you are speaking of an AutoIt script you have coded then it is a little bit simpler than that:

#include <GUIConstantsEx.au3>

Global $aInput[8]

$hGUI = GUICreate("Test", 500, 500)

For $i = 0 To 7
    $aInput[$i] = GUICtrlCreateInput("", 10, ($i * 30) + 10, 200, 20)
Next

$cFocus = GUICtrlCreateButton("Focus!", 10, 400, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cFocus
            GUICtrlSetState($aInput[Random(0, 7, 1)], $GUI_FOCUS)
    EndSwitch

WEnd

But if, as I suspect, you are asking about third-party apps, then what apps are you trying to automate? Do they not preselect the first available field automatically?

M23

[Docfxit]

The first input capable field that I need the cursor at is not an AutoIt script.  The program doesn't automatically go to that field.

The Info Window shows:

Title COREL

Window Info Class: #32770

Control Info Class ComboBox

Thanks,

Docfxit

[AutoBert]

Read about Control* functions in the help file.

[spudw2k]

Here is a tailored example from help file for ControlFocus function (You will also need the instance of the control in addition to the class, in this example the instance is 1)

Example()

Func Example()
    ; Wait 10 seconds for the Notepad window to appear.
    Local $hWnd = WinWait("Corel", "", 10)

    ; Set input focus to the edit control of Corel using the handle returned by WinWait.
    ControlFocus($hWnd, "", "ComboBox1")
EndFunc   ;==>Example

 

Edited August 10, 2016 by spudw2k