_SendMessage or _WinAPI_PostMessage Failing [Solved]

[IanN1990]

Hi,

 

I am writing a script to automated IE in a controlled manner. For most of my scripting I have been able to use IE.au3 functions for this but some aspect this isn't enough and i am forced to use send commands. (Some inputs have no ID or Name or the website is using Javas elements)

I need to move away from control send as the script can be running for long periods and it prevents me doing other functions (As control send in my aspect requires focus).

 

The Code below is a hours of researching and is almost perfect but failing at the finial stage. I am hoping someone will be able to help.

The script is an example

1. Opens a IE object and Embeds it into a GUI

2. Loads Google as a test website

3. Sends 8 _PostMessage Tab Commands to get Focus on the Input

4. Sends a _PostMessage Letter <--- Here is where it fails

 

expandcollapse popup

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <Constants.au3>
#include <IE.au3>

Dim $hGUI, $oIE, $h_HWND

$hGUI = GUICreate("Test", 1024, 768)
$oIE = IECreatePseudoEmbedded(0, 0, 1024, 768, $hGUI)
_IENavigate($oIE, "www.google.com")
GUISetState(@SW_SHOWNOACTIVATE, $hGUI)

SuperSend(19)

_WinAPI_PostMessage($h_HWND, $WM_KEYDOWN, 0x41, 0);
_WinAPI_PostMessage($h_HWND, $WM_KEYUP, 0x41, 0);

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
Exit

Func IECreatePseudoEmbedded($i_Left, $i_Top, $i_Width, $i_Height, $h_Parent)
   Local $o_IE

   $o_IE = ObjCreate("InternetExplorer.Application")
   $o_IE.theatermode = True
   $o_IE.fullscreen = True
   $o_IE.statusbar = False

   $h_HWND = _IEPropertyGet($o_IE, "hwnd")
   _WinAPI_SetParent($h_HWND, $h_Parent)
   _WinAPI_MoveWindow($h_HWND, $i_Left, $i_Top, $i_Width, $i_Height, False)
   _WinAPI_SetWindowLong($h_HWND, $GWL_STYLE, $WS_POPUP + $WS_VISIBLE)

   Return $o_IE
EndFunc ;==>IECreatePseudoEmbedded

Func SuperSend($Ammount)
   For $i=1 to $Ammount
      _WinAPI_PostMessage($h_HWND, $WM_KEYDOWN, 0x09, 0);
      _WinAPI_PostMessage($h_HWND, $WM_KEYUP, 0x09, 0);
      _WinAPI_PostMessage($h_HWND, $WM_KEYDOWN, 0x09, 0);
      _WinAPI_PostMessage($h_HWND, $WM_KEYUP, 0x09, 0);
   Next
EndFunc

 

Would anyone know where i have gone wrong or how to correct it?

Ian

Edited August 19, 2016 by IanN1990

[IanN1990]

Does anyone have any ideas?

 

I have spent the best of three days looking over the forums but from my understanding the code is correct.

The only other thing i have tired is putting a delay between the key down and key. Up but that has had no effect

[BrewManNH]

Aren't you sending 38 tab keys to the window? You're doing 2 tabs per $ammount and you're doing 19 loops through that, so that would be 38 tab keys sent wouldn't it?

[Bowmore]

This is the first IE automation that I have tried so this is probably not the best way to do it, but it worked for me.
Tested on Windows 10 Pro 64Bit

expandcollapse popup

#AutoIt3Wrapper_UseX64=Y
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <Constants.au3>
#include <IE.au3>

Dim $hGUI, $oIE, $h_HWND

$hGUI = GUICreate("Test", 1024, 768)
$oIE = IECreatePseudoEmbedded(0, 0, 1024, 768, $hGUI)
_IENavigate($oIE, "www.google.com")
GUISetState(@SW_SHOWNOACTIVATE              , $hGUI)

WinActivate($h_HWND)
WinWaitActive($h_HWND)

Sleep(100)
ControlSend($h_HWND,"",'',"{TAB 42}")
Sleep(100)
ControlSend($h_HWND,"",'',"TEST",1)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
Exit

Func IECreatePseudoEmbedded($i_Left, $i_Top, $i_Width, $i_Height, $h_Parent)
   Local $o_IE

   $o_IE = ObjCreate("InternetExplorer.Application")
   $o_IE.theatermode = True
   $o_IE.fullscreen = True
   $o_IE.statusbar = False

   $h_HWND = _IEPropertyGet($o_IE, "hwnd")
   _WinAPI_SetParent($h_HWND, $h_Parent)
   _WinAPI_MoveWindow($h_HWND, $i_Left, $i_Top, $i_Width, $i_Height, False)
   _WinAPI_SetWindowLong($h_HWND, $GWL_STYLE, $WS_POPUP + $WS_VISIBLE)

   Return $o_IE
EndFunc ;==>IECreatePseudoEmbedded

 

[IanN1990]

@BrewManNH

That is correct That's because what i found is sending the tab command changes focus from IE Frame to (Address / Toolbars / etc). As It is in full screen / theater mode with no status bar it only has one thing it can tab to. That's why i send two tabs for every one tab i need

 

@Bowmore

The code you have posted is correct and would help most people. The issue i would have with Send and ControlSend is requires focus, as this script could spend hours setting up accounts this would lock down my system for that duration.

[BrewManNH]

6 hours ago, IanN1990 said:

That is correct That's because what i found is sending the tab command changes focus from IE Frame to (Address / Toolbars / etc). As It is in full screen / theater mode with no status bar it only has one thing it can tab to. That's why i send two tabs for every one tab i need

But you're sending 38 of them, do you NEED all 38 to get to one control?

Also this UDF might be a better choice.

[mLipok]

There is also an example made by @LarsJ

 

 

[IanN1990]

On 11 August 2016 at 4:12 PM, BrewManNH said:

But you're sending 38 of them, do you NEED all 38 to get to one control?

Also this UDF might be a better choice.

During my long hours of researching i did come across this UDF but struggled to make heads or tails of it.

 

I thought i would share the answer i found to get into better habits, as i am getting more active in coding.

The problem was down to sending the Postmessage to a HWND of the window but not the HWND that could receive it.

 

$avChildren = ""
   WinListChildren(wingethandle("IE Window Title"), $avChildren)
   
   Func WinListChildren($hWnd, ByRef $avArr)
    If UBound($avArr, 0) <> 2 Then
        Local $avTmp[10][2] = [[0]]
        $avArr = $avTmp
    EndIf

    Local $hChild = _WinAPI_GetWindow($hWnd, $GW_CHILD)

    While $hChild
        If $avArr[0][0]+1 > UBound($avArr, 1)-1 Then ReDim $avArr[$avArr[0][0]+10][2]
        $avArr[$avArr[0][0]+1][0] = $hChild
        $avArr[$avArr[0][0]+1][1] = _WinAPI_GetWindowText($hChild)
        $avArr[0][0] += 1
        WinListChildren($hChild, $avArr)
        $hChild = _WinAPI_GetWindow($hChild, $GW_HWNDNEXT)
    WEnd

    ReDim $avArr[$avArr[0][0]+1][2]
 EndFunc

 

I take no credit for the code  but it displays all the control handles for the Window, then by using a For ... Next loop go through the way sending a message until it appeared on screen.

 

Though things to note for anyone else that finds this.

1. The total control number can change depending on IE settings (I am rolling this out across a team who all have different Addons in IE, i got around this by using an embeeded browser though).

2. Some controls do require focus for this to work, even if it is only for a second. Example i needed to click a button which couldn't be tab focused to. So i used control click to give focus, actived back to past window and let the postmessages carry on.

 

Hope this helps anyone else that comes across this one day.