StringRegExpReplace the nth string

[xcaliber13]

Hello,

         Once again I continue to struggle with regex statements.    I have searched the forums and the internet and still cannot get this to work.  I have a csv file that is comma delimited.   What I am trying to do is to replace the 3rd occurrence of a comma with a space on every line.    Example:

FIN,MRN,LastName,FirstName,DateOfService,Mercy Dept Name,ServiceCode     would become

FIN,MRN,LastName FirstName,DateOfService,Mercy Dept Name,ServiceCode      on every line of the file.

Also  should I be writing the csv file to an array first and then do the StringRegExpReplace? 

Any help to point me in the right direction would be great!    Thank you

[iamtheky]

thats not really a problem for regex, but they rarely are..

$str = "FIN,MRN,LastName,FirstName,DateOfService,Mercy Dept Name,ServiceCode"

MsgBox(0, '' , stringreplace($str , StringInStr($str , "," , 0 , 3) , " "))

 

[funkey]

I would read the file into an array, then use a loop with StringInStr() and StringReplace(). I'm no RegExp user

[jchd]

Regexp:

Local $sIn = _
    "FIN,MRN,LastNameA,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameB,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameC,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameD,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameE,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF

Local $sOut = StringRegExpReplace($sIn, "(?m)([^,]*,[^,]*,[^,]*),(.*)", "$1 $2")
ConsoleWrite($sOut)

 

[iamtheky]

I made one, probably buggy as shit but i think it works for the ex.

Local $sIn = _
    "FIN,MRN,LastNameA,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameB,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameC,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameD,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameE,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF



msgbox(0, 'regexpreplace' , stringregexpreplace($sIn , "((.*?,){2}.*?),(.*\r)" , "$1 $3"))

 

[jguinch]

Using \K, it seems faster :

Local $sOut = StringRegExpReplace($sIn, "(?m)^[^,]*,[^,]*,[^,]*\K,", " ")

 

[mikell]

Agreed 

Local $sOut = StringRegExpReplace ($sIn, '(?m)^([^,]*\K,){3}' , " " )

 

Edited August 17, 2016 by mikell
typo

[iamtheky]

in case you wanted to bring array into it i would go arraytostring, its easy to read

#include<array.au3>

Local $sIn = _
    "FIN,MRN,LastNameA,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameB,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameC,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameD,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameE,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF


$aIn = stringsplit($sIn , @CRLF , 2)
$sOut = ""

For $i = 0 to ubound ($aIn) - 1
$sOut &= _ArrayToString(stringsplit($aIn[$i] , "," , 2) , "," , 0 , 2) & " " & _ArrayToString(stringsplit($aIn[$i] , "," , 2) , "," , 3)
Next

msgbox(0, '' , $sOut)

 

[iamtheky]

I went to make another example and made post #2 again, so one more vote for that...

[mikell]

Good idea, but using post #2 to replace the code in post #8 which is totally awful - performance side 

BTW jguinch, using \K is faster indeed

expandcollapse popup

#include<array.au3>

Local $sIn = _
    "FIN,MRN,LastNameA,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameB,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameC,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameD,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF & _
    "FIN,MRN,LastNameE,FirstName,DateOfService,Mercy Dept Name,ServiceCode" & @CRLF

Local $hTimer = TimerInit()
Local $sOut = StringRegExpReplace($sIn, "(?m)([^,]*,[^,]*,[^,]*),(.*)", "$1 $2")
$fDiff0 = TimerDiff($hTimer)
;msgbox(0, '1' , $sOut)

$hTimer = TimerInit()
Local $sOut = StringRegExpReplace ($sIn, '(?m)^([^,]*\K,){3}' , " " )
$fDiff1 = TimerDiff($hTimer)
;msgbox(0, '1' , $sOut)

$hTimer = TimerInit()
$aIn = stringsplit($sIn , @CRLF , 3)
$sOut = ""
For $i = 0 to ubound ($aIn) - 1
$sOut &= _ArrayToString(stringsplit($aIn[$i] , "," , 2) , "," , 0 , 2) & " " & _ArrayToString(stringsplit($aIn[$i] , "," , 2) , "," , 3) & @crlf 
Next
$fDiff2 = TimerDiff($hTimer)
;msgbox(0, '2' , $sOut)

$hTimer = TimerInit()
$aIn = stringsplit($sIn , @CRLF , 3)
$sOut = ""
For $i = 0 to ubound ($aIn) - 1
$sOut &= stringreplace($aIn[$i] , StringInStr($aIn[$i] , "," , 0 , 3) , " ") & @crlf 
Next
$fDiff3 = TimerDiff($hTimer)
;msgbox(0, '3' , $sOut)

msgbox(0, '' ,  "regex1 = " & $fDiff0 & @crlf & _ 
        "regex2 = " & $fDiff1 & @crlf & _ 
        "array = " & $fDiff2 & @crlf & _ 
        "string = " & $fDiff3 )