Unable to click on colored frame

[sammy1983]

Hi Folks,

Can anyone assist me in identifying the colored rectangle and click on it?

<td class="tile" id="c_15" style="background-color: rgb(223, 223, 223);">YES</td>

I really don't know how to code it?

[rcmaehl]

; Most Basic Example

$aCoords = PixelSearch($x1, $y1, $x2, $y2, "#DFDFDF")
MouseClick("Primary", $aCoords[0], $aCoords[1])

 

Edited September 6, 2016 by rcmaehl

[sammy1983]

20 minutes ago, rcmaehl said:

; Most Basic Example

$aCoords = PixelSearch($x1, $y1, $x2, $y2, "#DFDFDF")
MouseClick("Primary", $aCoords[0], $aCoords[1])

 

Thanks but what is $x1, $y1, $x2, $y2?

[rcmaehl]

2 minutes ago, sammy1983 said:

Thanks but what is $x1, $y1, $x2, $y2?

Here's the Helpfile for PixelSearch. It explains it better than I can:

https://www.autoitscript.com/autoit3/docs/functions/PixelSearch.htm

[sammy1983]

20 hours ago, rcmaehl said:

Here's the Helpfile for PixelSearch. It explains it better than I can:

https://www.autoitscript.com/autoit3/docs/functions/PixelSearch.htm

Thanks rcmaehl.. I tried this and it worked. 

Local $sHTML = _IEDocReadHTML($oIE1)
$array = StringRegExp($sHTML, '(?i)style="background-color: (.*?);">YES', 3)
For $i = 0 To UBound($array) - 1
    $test = $array[$i]
    If $test = "rgb(223, 223, 223)" then        
        Local $Color = _IEGetObjById($oIE1, "c_" & $j)
        _IEAction($Color, "click")
        Exit
    EndIf
Next

 

[mLipok]

Just try this:

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/184447-unable-to-click-on-colored-frame
.......
.......
.......
_Example($oIE)
.......
.......
.......

Func _Example(ByRef $oIE)
    ; <td class="tile" id="c_15" style="background-color: rgb(223, 223, 223);">YES</td>

    ; https://www.w3.org/TR/css3-selectors/#selectors
    ; find TD tag with attribute style="background-color: rgb(223, 223, 223);"
    Local $oSelection = _IEquerySelectorAll($oIE, 'td[style="background-color: rgb(223, 223, 223);"]', 0)
    If Not @error Then _IEAction($oSelection, 'click')
EndFunc   ;==>_Example




;#FUNCTION#=============================================================================================================
; Name...........: _IEquerySelectorAll()
; Description ...: Returns an Object or a Colection of objects
; Syntax.........: (ByRef $oDoc, $sQuery, $iItemIndex = Default)
; Parameters ....: $oDoc - The document object from IE
;                  $sQuery - String of Query. Example: _IEquerySelectorAll($oDoc, '"div.note, div.alert"', Default) will return a colection of div elements with classes of note and alert
;                  $iItemIndex -     [optional] Default returns a colection, else use a 0 based index to indicate the object in sequence
; Return values .: Success - Object or a Colection of objects
;                  Failure - returns 0 sets the @error flag to non-zero.
;                   3 ($_IEStatus_InvalidDataType) - Invalid Data Type
;                   4 ($_IEStatus_InvalidObjectType) - Invalid Object Type
;                   5 ($_IEStatus_InvalidValue) - Invalid Value
;                   7 ($_IEStatus_NoMatch) - No Match
; Author ........: XThrax aka uncommon
; Remarks .......: This fuction was pretty much stolen from Dale Hohm the IE UDF creator so much credit to him, also to mLipok who made the error checking better.
;                   Also note that this a relatively recent add-on to IE so it requires IE 9 and above.
;                   If you find you receive a com error of "unknown name" its likely the site is using meta tag attribute X-UA-Compatible which has reverted the browser to forget about it.
;
; Related .......: _IETagNameAllGetCollection();_IEClassNameGetCollection()
; Link ..........;https://www.autoitscript.com/forum/topic/181376-_iequeryselectorall/
;                 https://msdn.microsoft.com/en-us/library/cc304115(v=vs.85).aspx
; Example .......; No
; =====================================================================================================================


Func _IEquerySelectorAll(ByRef $oDoc, $sQuery, $iItemIndex = Default)
    If Not IsObj($oDoc) Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidDataType & " Invalid DataType" & @LF)
        Return SetError($_IEStatus_InvalidDataType, 1, 0)
    ElseIf Not __IEIsObjType($oDoc, "browserdom") Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidObjectType & " Invalid ObjectType" & @LF)
        Return SetError($_IEStatus_InvalidObjectType, 2, 0)
    ElseIf Not IsNumber($iItemIndex) And $iItemIndex <> Default Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Index" & @LF)
        Return SetError($_IEStatus_InvalidValue, 3, 0)
    ElseIf $iItemIndex = Default Or $iItemIndex >= 0 Then
        Local $oTemp = Null
        If __IEIsObjType($oDoc, "documentcontainer") Then
            $oTemp = _IEDocGetObj($oDoc)
            If @error Then Return SetError(@error, @extended, 0)
        Else
            $oTemp = $oDoc
        EndIf
        Local $oClassColl = $oTemp.querySelectorAll($sQuery)
        If @error Then
            ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IESTATUS_GeneralError & " GeneralError1: " & @error & @LF)
            Return SetError($_IESTATUS_GeneralError, 3, 0)
        ElseIf (Not IsObj($oClassColl)) Or $oClassColl = Null Or $oClassColl.length = 0 Then
            ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_NoMatch & " NoMatch" & @LF)
            Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
        Else
            If $iItemIndex = Default Then
                Return SetError($_IEStatus_Success, $oClassColl.length, $oClassColl)
            ElseIf $iItemIndex > $oClassColl.length Then
                ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Value" & @LF)
                Return SetError($_IEStatus_InvalidValue, $oClassColl.length, 0)
            Else
                $oItem = $oClassColl.Item($iItemIndex)
                If @error Then
                    ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IESTATUS_GeneralError & " GeneralError2: " & @error & @LF)
                    Return SetError($_IESTATUS_GeneralError, 3, 0)
                ElseIf (Not IsObj($oItem)) Or $oItem = Null Then
                    ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_NoMatch & " NoMatch Index: " & $iItemIndex & @LF)
                    Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
                Else
                    Return SetError($_IEStatus_Success, 0, $oItem)
                EndIf
            EndIf
        EndIf
    Else
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Value: " & $iItemIndex & @LF)
        Return SetError($_IEStatus_InvalidValue, 3, 0)
    EndIf
EndFunc   ;==>_IEquerySelectorAll