BinaryToString

[antmar904]

Hi,

I am trying to get a list of all websites in a users compatibility view list but they are all in binary and I'm trying to convert them into strings.

It will show me the binary but not the string.

This is what I have so far.

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
Local $Binary = RegRead("HKCU\SOFTWARE\Microsoft\Internet Explorer\BrowserEmulation\ClearableListData", "UserFilter")
MsgBox(0, "Binary Data", $Binary)
For $i = 0 To UBound($Binary) -1
    Local $String = BinaryToString($Binary, "")
Next
MsgBox(0, "String", $String)

 

[Jfish]

I don't think RegRead returns an array, does it?  If not, you should see an error on the MsgBox because $String would not be set to a value. 

Edited October 13, 2016 by Jfish

[BrewManNH]

This might work for you, at least it converts it to a semi-usable string.

#include <MsgBoxConstants.au3>
Local $Binary = RegRead("HKCU\SOFTWARE\Microsoft\Internet Explorer\BrowserEmulation\ClearableListData", "UserFilter")
$Binary = StringReplace(String($Binary), "00", ASC("."))
MsgBox(0, "Binary Data", $Binary)
Local $String = BinaryToString($Binary)
MsgBox(0, "String", $String)

The problem with the BinaryToString function is that it stops as soon as it hits a NULL, which is why only part of your string would show in the second msgbox.

[antmar904]

That did not work.

 

Edited October 13, 2016 by antmar904

[antmar904]

Can this be done with AutoIT?

I think there is a function for this in Powershell.

[JLogan3o13]

@antmar904 please wait 24 hours before bumping your post.

[BrewManNH]

Actually that did work, if you look at the end of the string in the MsgBox you will see the msn.com in between all the "F"s in it.

[antmar904]

@BrewManNH

Your right, I didn't even catch that.

Can we make the output string more ledgible?

Edited October 14, 2016 by antmar904

[Danyfirex]

You can do this...

 

#include <Array.au3>

Local $aUrls = _GetUsersCompatibilityViewList()

_ArrayDisplay($aUrls)

Func _GetUsersCompatibilityViewList()
    Local Const $sTag_UserFilter = "byte Dummy[8];dword NumberOfEntries;"
    Local Const $sTag_Entry = "byte Dummy[16];word Length;"
    Local $aList[0]
    Local $sBinary = RegRead("HKCU\SOFTWARE\Microsoft\Internet Explorer\BrowserEmulation\ClearableListData", "UserFilter")
    If @error Then Return
    Local $tData = DllStructCreate("byte Data[" & BinaryLen($sBinary) & "]")
    $tData.Data = $sBinary


    Local $tInInfo = DllStructCreate($sTag_UserFilter, DllStructGetPtr($tData))
    Local $nEntries = $tInInfo.NumberOfEntries
    ReDim $aList[$nEntries]



    Local $tEntryInfo = 0
    Local $NextIndex = 24
    Local $iLength = 0
    Local $tUrl = 0

    For $i = 1 To $nEntries
        $tEntryInfo = DllStructCreate($sTag_Entry, DllStructGetPtr($tData) + $NextIndex)
        $iLength = DllStructGetData($tEntryInfo, 2)
        $tUrl = DllStructCreate("wchar String[" & $iLength & "]", DllStructGetPtr($tEntryInfo) + 18)
        $aList[$i - 1] = $tUrl.String
        $NextIndex += ($iLength * 2) + 18
    Next
    Return $aList
EndFunc   ;==>_GetUsersCompatibilityViewList

Saludos

 

[antmar904]

@Danyfirex

That worked thank you.  

[haijie1223]

@Danyfirex

How to add a website to the compatibility view list ？ Please！Thank You

[Danyfirex]

I'll check later.  @haijie1223

 

Saludos