Generate texte with date & time

[Zerobug]

Hi Guys,

For testing an analysis log software, I need to create an autoit script to generate "fake log".

I have tryied, some things, but unfortunnately, it does'nt works fine, for exemple, in the script below, the time don't update, always the same

The goal is to have a script which loop on a 4 messages (info, warning, error and fatal error)

#include <Date.au3>

$File = "logfile.log"
$Text = @MDAY & "/" & @MON & " " & @HOUR & ":" & @MIN & ":" & @MIN & " [ERROR] This is an Error Message" & @CRLF & _
@MDAY & "/" & @MON & " " & @HOUR & ":" & @MIN & ":" & @MIN & " [INFO] This is an Information Message" & @CRLF & _
@MDAY & "/" & @MON & " " & @HOUR & ":" & @MIN & ":" & @MIN & " [WARNING]This is a Warning Message" & @CRLF & _
@MDAY & "/" & @MON & " " & @HOUR & ":" & @MIN & ":" & @MIN & " [FATAL]This is a Message with Fatal Error" & @CRLF

HotKeySet("{ESC}","Quit") 

While True    
Sleep(5000)
    FileWrite($File, $Text)
    Sleep(2000)
        FileWrite($File, $Text)
    Sleep(2000)

    FileWrite($File, $Text)
    Sleep(2000)
        FileWrite($File, $Text)
    Sleep(2000)
WEnd

Func Quit()
    Exit
EndFunc

Can you help me ?

Many thanks

[jchd]

Try this (more randomized):

#include <Date.au3>

$File = "logfile.log"
Local $aText = [ _
    "[ERROR] This is an Error Message", _
    "[INFO] This is an Information Message", _
    "[WARNING] This is a Warning Message", _
    "[FATAL] This is a Message with Fatal Error" _
], $sText, $sDate = _NowCalc()

HotKeySet("{ESC}", _Quit)

While True
    $sDate = _DateAdd("s", Random(1, 86400, 1), $sDate)
    $sText = $sDate & " " & $aText[Random(0, UBound($aText) - 1, 1)] & @CRLF
    FileWrite($File, $sText)
WEnd

Func _Quit()
    Exit
EndFunc

 

Edited October 23, 2016 by jchd
Fixed typo in variable name

[mikell]

@Zerobug

The time should be updated inside the While loop 

#include <Date.au3>

$File = "logfile.log"
HotKeySet("{ESC}","Quit") 

While True    
Sleep(5000)
    FileWrite($File, _MyCurrentTime() & " [ERROR] This is an Error Message" & @crlf)
    Sleep(2000)
    FileWrite($File, _MyCurrentTime() & " [INFO] This is an Information Message" & @crlf)
    Sleep(2000)
    FileWrite($File, _MyCurrentTime() & " [WARNING] This is a Warning Message" & @crlf)
    Sleep(2000)
    FileWrite($File, _MyCurrentTime() & " [FATAL] This is a Message with Fatal Error" & @crlf)
    Sleep(2000)
WEnd

Func _MyCurrentTime()
   Return @MDAY & "/" & @MON & " " & @HOUR & ":" & @MIN & ":" & @SEC
EndFunc

Func Quit()
    Exit
EndFunc

 

[Zerobug]

I've juste replaced 

FileWrite($File, $Text

by

FileWrite($File, $sText

and, i's perfect (also awesome).

 

Many thanks for your help.

[jchd]

Ah, sorry for the typo (now fixed).

Feel free to make the random progression in seconds smaller (< 86400) or bigger (> 86400) to make the output more realistic for your use case.

Edited October 23, 2016 by jchd