Why is SciTE reading the output of another process executed by the script?

[TheDcoder]

Hello, I discovered this a few days ago but I am not able to explain why would this happen... here is the script:

#include <AutoItConstants.au3>

$iPID = Run("sort.exe", @SystemDir, @SW_SHOW, $STDIN_CHILD)
ConsoleWrite("PID: " & $iPID & @CRLF)

$sSortString = "Banana" & @CRLF & "Elephant" & @CRLF & "Apple" & @CRLF & "Deer" & @CRLF & "Car" & @CRLF

StdinWrite($iPID, $sSortString)

And here is the console output:

PID: 1234
Apple
Banana
Car
Deer
Elephant

Why is the STDOUT being redirected to SciTE?

 

Thanks in Advance, TD .

Edited November 6, 2016 by TheDcoder
Edited the thread titile

[Jos]

2 minutes ago, TheDcoder said:

Why is the STDOUT being redirected to SciTE?

Why not?  Isn't it always unless captured by another process?

Jos

[TheDcoder]

SciTE is reading the output of sort.exe, it should only be reading the output of the script... am I correct?

[mLipok]

check this:
 

#include <AutoItConstants.au3>

$iPID = Run("sort.exe", @SystemDir, @SW_SHOW, $STDIN_CHILD)
ConsoleWrite("PID: " & $iPID & @CRLF)

$sSortString = "Banana" & @CRLF & "Elephant" & @CRLF & "Apple" & @CRLF & "Deer" & @CRLF & "Car" & @CRLF

Sleep(10000)
StdinWrite($iPID, $sSortString)

 

you will see that sort.exe is staying an waiting ....
When sort.exe is taking data then make his job and return output to parent process , in this case to SciTE.

 

Edited November 6, 2016 by mLipok

[TheDcoder]

I have already played around with Stdin and Sleeps . The thing which amazes me is why does using $STDIN_CHILD instead of $STDIN_CHILD + $STDOUT_CHILD make the output get redirected to the parent process? . If I use $STDIN_CHILD + $STDOUT_CHILD, I will have to use StdOutRead to read the output (as shown in the example for StdinWrite).

[TheDcoder]

Today I experimented more... Added $RUN_CREATE_NEW_CONSOLE to create a new console for the child process itself, it should output to the console window... but its is not doing that!

#include <AutoItConstants.au3>

$iPID = Run("sort.exe", @SystemDir, @SW_SHOW, $STDIN_CHILD + $RUN_CREATE_NEW_CONSOLE)
ConsoleWrite("PID: " & $iPID & @CRLF)

$sSortString = "Banana" & @CRLF & "Elephant" & @CRLF & "Apple" & @CRLF & "Deer" & @CRLF & "Car" & @CRLF

Sleep(10000) ; Time for you to see the newly created console
StdinWrite($iPID, $sSortString)

While I was researching and asking around, someone proposed a plausible theory, here is the relevant part from my IRC Log:

[17:22:32] <Mysoft> so maybe AutoIT is using a pipe for STDOUT and writing to it's own console
[17:22:42] <Mysoft> instead of specifying the "standard handle"
[17:22:53] <Mysoft> which would then be converted to the handle of the new console
[17:23:15] <Mysoft> that explains why you get that only when "acquiring the STDIN"

This thing is getting stranger .

[Jos]

SciTE is Shelling Autoit3.exe which is shelling Sort, so Guess SciTE is capturing all Child processes.

Jos

[TheDcoder]

looks like it... but why is AutoIt3.exe not shelling sort.exe in the example for StdinWrite?

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $iPID = Run("sort.exe", @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDOUT_CHILD)

    ; Write a string of items to be sorted to child sort.exe's Stdin.
    StdinWrite($iPID, "Banana" & @CRLF & "Elephant" & @CRLF & "Apple" & @CRLF & "Deer" & @CRLF & "Car" & @CRLF)

    ; Calling StdinWrite without a second parameter closes the stream.
    StdinWrite($iPID)

    Local $sOutput = "" ; Store the output of StdoutRead to a variable.

    While 1
        $sOutput &= StdoutRead($iPID) ; Read the Stdout stream of the PID returned by Run.
        If @error Then ; Exit the loop if the process closes or StdoutRead returns an error.
            ExitLoop
        EndIf
    WEnd

    MsgBox($MB_SYSTEMMODAL, "", "The sorted string is: " & @CRLF & $sOutput)
EndFunc   ;==>Example