Need help with this loop

[Queener]

For $x = 0 To 13
        
        If GUICtrlRead($InputStatus[$x]) = "Senior" Then
      IniWrite($xfile, "ChildMembers", $xfileSeniorKey & $x + 1, GUICtrlRead($inputname[$x]))
      IniWrite($xfile, "ChildMembers", $xfileSeniorDOB & $x + 1, GUICtrlRead($InputDate[$x]))
      EndIf
      Next

Correct me if I'm wrong, but doesn't this loop supposed to write each status field that contain the string "Senior" into the ini file? When I run this code; it picked the last row into the ini only which it ignores the rest. So for example:

Textbox 1 = Senior Name

Textbox 2 = Senior Name

DOB Text 1 = 12/12/1960

DOB Text 2 = 12/12/1950

Status Textbox 1= Senior

Status Textbox 2 = Senior

 

Outputs

[ChildMembers]
Senior2=Test
Senior_DOB2=Test

 

$xfileSeniorKey and $xfileDOB is only a variables of string to test.

$xfileSeniorKey = "Senior"

$xfileDOB = "Senior_DOB"

So when it writes to ini, it would look something like

[ChildMembers]

Senior1=Test

Senior_DOB=12/12/1960

Edited December 20, 2016 by Queener

[orbs]

@Queener,

you are not making it easy for anyone to help you. if you take the 5 minutes it takes to post a simple runnable reproducer, you may find your issue very easily, because this one works for me flawlessly:

#include <GUIConstantsEx.au3>
Global $hGUI = GUICreate('Example', 300, 410)
GUISetBkColor(0xABCDEF)
GUICtrlCreateLabel('Name:', 10, 5, 80, 20)
GUICtrlCreateLabel('Date:', 110, 5, 80, 20)
GUICtrlCreateLabel('Type:', 210, 5, 80, 20)
Global $agName[14], $agDate[14], $agType[14]
For $i = 0 To 13
    $agName[$i] = GUICtrlCreateInput('Name#' & ($i + 1), 10, ($i + 1) * 25, 80, 20)
    $agDate[$i] = GUICtrlCreateInput(($i + 1) & '/12/1975', 110, ($i + 1) * 25, 80, 20)
    $agType[$i] = GUICtrlCreateInput('Senior', 210, ($i + 1) * 25, 80, 20)
Next
Global $gSave = GUICtrlCreateButton('Save to Ini', 10, 380, 280, 25)
GUISetState(@SW_SHOW, $hGUI)
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $gSave
            FileDelete('senior.ini')
            For $i = 0 To 13
                If GUICtrlRead($agType[$i]) = 'Senior' Then
                    IniWrite('senior.ini', 'ChildMembers', 'Name' & ($i + 1), GUICtrlRead($agName[$i]))
                    IniWrite('senior.ini', 'ChildMembers', 'Date' & ($i + 1), GUICtrlRead($agDate[$i]))
                EndIf
            Next
    EndSwitch
WEnd
GUIDelete($hGUI)

 

Edited December 20, 2016 by orbs

[careca]

Exactly my thoughts, kinda hard to get the whole picture without the rest of it.

[kylomas]

Queener,

When using an INI file with incremental keys you need to find the highest key for the starting increment for successive runs.  Otherwise you will be writing over existing values.

If this is a frequently run or a high volume app you might consider SQLite.  It is not much harder than INI files for simple structures.

kylomas