Telegram Bot UDF

[LinkOut]

Hi! I wrote an UDF that can simplify the way you can control Telegram Bot with AutoIt. If you don't know what is a Telegram Bot, maybe you should read their official website here. All about this UDF is on my GitHub: what is, how it work, how to use and also a Test.au3 to see the script in action. But... let's talk about this UDF.

• What is: It's an UDF that contain functions to control a Telegram Bot. Send messages, photo, video, stickers, wait for incoming messages and answer to them.
• How it works: Insert you Token given from BotFather, initialize your bot with _InitBot() function and... you're ready!
• All functions are commented: You will find a description of what it does, an explanation for every argument that function has need and what it return.

This is the test script, that initialize your bot, run all functions and write the return value.

#include "Telegram UDF.au3"

$ChatID = "Your_Chat_ID_For_Test"
_InitBot("Bot_ID","Bot_Token")

ConsoleWrite("Test _GetUpdates   -> "  & @TAB & _GetUpdates() & @CRLF)
ConsoleWrite("Test _GetMe        -> "  & @TAB & _GetMe() & @CRLF)

ConsoleWrite("Test _SendMsg      -> "  & @TAB & _SendMsg($ChatID,"Test _SendMsg") & @CRLF)
ConsoleWrite("Test _ForwardMsg   -> "  & @TAB & _ForwardMsg($ChatID,$ChatID,'MsgID') & @CRLF)

ConsoleWrite("Test _SendPhoto    -> "  & @TAB & _SendPhoto($ChatID,"C:\image.jpg","Test _SendPhoto") & @CRLF)
ConsoleWrite("Test _SendVideo    -> "  & @TAB & _SendVideo($ChatID,"C:\video.mp4","Test _SendVideo") & @CRLF)
ConsoleWrite("Test _SendAudio    -> "  & @TAB & _SendAudio($ChatID,"C:\audio.mp3","Test _SendAudio") & @CRLF)
ConsoleWrite("Test _SendDocument -> "  & @TAB & _SendDocument($ChatID,"C:\document.txt","Test _SendDocument") & @CRLF)
ConsoleWrite("Test _SendVoice    -> "  & @TAB & _SendVoice($ChatID,"C:\voice.ogg","Test _SendVoice") & @CRLF)
ConsoleWrite("Test _SendSticker  -> "  & @TAB & _SendSticker($ChatID,"C:\sticker.webp") & @CRLF)
ConsoleWrite("Test _SendLocation -> "  & @TAB & _SendLocation($ChatID,"74.808889","-42.275391") & @CRLF)
ConsoleWrite("Test _SendContact  -> "  & @TAB & _SendContact($ChatID,"0123456789","Josh") & @CRLF)
ConsoleWrite("Test _SendChatAction -> " & @TAB & _SendChatAction($ChatID,"typing") & @CRLF)

ConsoleWrite("Test _GetUserProfilePhotos -> " & @TAB & _GetUserProfilePhotos($ChatID) & @CRLF)
ConsoleWrite("Test _GetChat              -> " & @TAB & _GetChat($ChatID) & @CRLF)

While 1
   $msgData = _Polling()
   _SendMsg($msgData[2],$msgData[3])
WEnd

Last part of the script (While cycle) use Polling function to put the script in a wait-state for incoming messages: _Polling() function return an array ($msgData in this case) that contain information about the received message (for example, $msgData[2] is the Chat ID of the user that send the message, important to send a reply. See GitHub page for other info.

So, finally, here you can find and download the library -> https://github.com/xLinkOut/telegram-udf-autoit <-

UPDATE: Thanks to @mLipok to added my Telegram UDF on AutoItScript Wiki!  

UPDATE 2: Functions that send files to Telegram Servers (photos, videos..) don't need anymore cURL executable file. Thanks to @Jos that suggested how to use WinHttp UDF by trancexx.

If you have question, bug report or anything else just contact me or reply to this Thread Don't forget to follow me on GitHub for future updates. Bye!

Edited January 15, 2017 by LinkOut
Update

[mLipok]

Added to UDF List on AutoIt WikiPage, here:
https://www.autoitscript.com/wiki/User_Defined_Functions#Social_Media_and_other_Website_API

 

[Jos]

I think you shouldn't be downloading an exe (curl.exe) and shelling without any notification/= or asking first.
Maybe you could change the UDF by using the set of WINHTTP udf's made by trancexx?

Jos
 

[mLipok]

1 hour ago, Jos said:

Maybe you could change the UDF by using the set of WINHTTP udf's made by trancexx?

This was my second thought about this UDF.

 

[JLogan3o13]

Perhaps we should give people who post UDFs a short time to get feedback from the community and improve the scripts, before we rush to add them to the Wiki.

[mLipok]

Perhaps .... , on the other hand, if in this way, we do not overlook or forget about a little used UDF?
See what's on the Wiki Page, it was even a few years ago?
Now this is actually a treasure trove.

I think that the assessment of the UDF should be taken in the thread and not on the list of UDFs. Of course, if a UDF proves to be dangerous, they should be removed from the list.

 

[Jos]

Let's not argue in this thread, but agree with @JLogan3o13 to first let it mature before publishing in the WiKi.
Further discussion can be done via PM.  

Jos

[mLipok]

Ok.

[LinkOut]

Thanks @mLipok !

I try for days to get functions like _SendPhoto work, to upload files like photos, videos, audios ecc to Telegram Server without cURL,  just with HTTP API, but without any result. At the end I use cURL and the best way to keep end user with less things to do is let UDF provide itself to download and use cURL executable file. The library download the exe file from official web site of cURL (https://curl.haxx.se/download.html) , it's 100% safe and secure, I can post a VirusTotal scan if you need to verify or at least tell me how to make it work without cURL

[Jos]

10 hours ago, LinkOut said:

it's 100% safe and secure

Understand, but it is for me more the fact you are downloading an exe without informing the user of the script. You could also simply state your script needs CURL and have the user of the script download themselves or even allow them to indicate where it is located in case they already have CURL installed.

Jos 

 

[LinkOut]

Ok, I will change the script to inform the user that the UDF need cURL executable. If the user agree, the script download itself the .exe, otherwise user can adapt th code to find a pre-downloaded curl.exe. I will add this also on the GitHub page. Thanks

[Jos]

.. and maybe somebody can help you on how to implement the winhttp udf option.

Jos

[mLipok]

In relation to the change from cURL to winhttp , @LinkOut please check my Crowding API UDF , and Crowdin API documentation.
On Crowdin site in documentation there are examples for cURL , but I have used winhttp.

This should show you how to make a first step.

 

[Jos]

I took one of the examples posted by trancexx and modified it to the below alternative UDF for SendPhoto:

expandcollapse popup

#include <WinHttp.au3>

;~ ConsoleWrite("Test _SendMsg      -> "  & @TAB & _SendMsg($ChatID,"Test _SendMsg") & @CRLF)
;~ ConsoleWrite("Test _SendPhoto    -> " & @TAB & _SendPhoto($ChatID, "d:\temp\image.jpg", "Test _SendPhoto") & @CRLF)
ConsoleWrite("Test _SendPhoto    -> " & @TAB & _SendPhotoN($ChatID, "d:\temp\image.jpg", "Test _SendPhoto") & @CRLF)


; @SEND MEDIA FUNCTION using WINHTTP ================================================================================
Func _SendPhotoN($ChatID, $Path, $Caption = "")
    Local $Query = $URL & '/sendPhoto'
    $sForm = _
            '<form action="' & $Query & '" method="post" enctype="multipart/form-data">' & _
            ' <input type="text" name="chat_id"/>' & _
            ' <input type="file" name="photo"/>' & _
            ' <input type="text" name="caption"/>' & _
            '</form>'

    ; Initialize and get session handle
    $hOpen = _WinHttpOpen()
    $hConnect = $sForm ; will pass form as string so this is for coding correctness because $hConnect goes in byref
    ; Register callback function
    _WinHttpSimpleFormFill_SetUploadCallback(UploadCallback)
    ; Fill form
    $sHTML = _WinHttpSimpleFormFill($hConnect, $hOpen, _
            Default, _
            "name:chat_id", $ChatID, _
            "name:photo", $Path, _
            "name:caption", $Caption)
    ; Collect error number
    $iErr = @error
    ; Unregister callback function
    _WinHttpSimpleFormFill_SetUploadCallback(0)
    ; Kill progress bar window
    ; Close handles
    _WinHttpCloseHandle($hConnect)
    _WinHttpCloseHandle($hOpen)

    If $iErr Then
        MsgBox(4096, "Error", "Error number = " & $iErr)
        ConsoleWrite("! error:" & $iErr & @CRLF & $sHTML & @CRLF)
    Else
        ConsoleWrite($sHTML & @CRLF)
    EndIf
    Return $iErr

EndFunc   ;==>_SendPhotoN

This is working nicely for me

Jos

Edited January 6, 2017 by Jos
Updated the form to contain all param's

[LinkOut]

Wow.. it works!! Ok, asap I'll rewrite the UDFs and remove cURL. One question about this:

_WinHttpSimpleFormFill_SetUploadCallback(UploadCallback)

what is "UploadCallback" exactly? SciTe return me error and I've changed it to '1' just for test and worked anyway.

[LinkOut]

On 6/1/2017 at 11:38 AM, mLipok said:

In relation to the change from cURL to winhttp , @LinkOut please check my Crowding API UDF , and Crowdin API documentation.
On Crowdin site in documentation there are examples for cURL , but I have used winhttp.

This should show you how to make a first step.

 

I'm reading your UDF.

[mLipok]

Good for you, I hope
 

[Jos]

4 hours ago, LinkOut said:

Wow.. it works!! Ok, asap I'll rewrite the UDFs and remove cURL. One question about this:

_WinHttpSimpleFormFill_SetUploadCallback(UploadCallback)

what is "UploadCallback" exactly? SciTe return me error and I've changed it to '1' just for test and worked anyway.

Sorry about that, I forgot to copy that as well into the posted example:

; Callback function. For example, update progress control
Func UploadCallback($iPrecent)
    If $iPrecent = 100 Then
        ; ProgressSet(100, "Done", "Complete")
        Sleep(800) ; give some time for the progress bar to fill-in completely
    Else
        ; ProgressSet($iPrecent, $iPrecent & "%")
    EndIf
EndFunc   ;==>UploadCallback

It was used in the original example to update the percentage uploaded, but I have removed the Progress as we probably talk here about small files.

.. or simply remove the 2 Callback lines as you don't need them for this function

Just add Func and you should be in business.

Jos

Edited January 7, 2017 by Jos

[LinkOut]

Oh ok no problem! It's clear now

[bambus1980]

its cool, but, what about using proxy server, ntlm proxy? if I use curl it will be: curl -s -k -U : --proxy-ntlm --proxy server:port https://google.com -o index.htm

how make that UDF working with proxy?