Help with retrieving (per-core) CPU usage

[nss]

Greetings, I am writing some sort of a system info application, in which I need to display the CPU usage both in total and per core. I found this function, but it seems to report the wrong data, i.e., sometimes it will report negative percentage, and it just seems to report fake info. Any help on this would be appreciated as for right now I'm stuck with my program making because of this function. This is the function that I found:

expandcollapse popup

Func _GetCPUUsage()
    Local Const $SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION = 8
    Local Const $SYSTEM_TIME_INFO = 3
    Local Const $tagS_SPPI = "int64 IdleTime;int64 KernelTime;int64 UserTime;int64 DpcTime;int64 InterruptTime;long InterruptCount"


    Local $CpuNum, $IdleOldArr[1], $IdleNewArr[1], $tmpStruct
    Local $timediff = 0, $starttime = 0
    Local $S_SYSTEM_TIME_INFORMATION, $S_SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION
    Local $RetArr[1]

    Local $S_SYSTEM_INFO = DllStructCreate("ushort dwOemId;short wProcessorArchitecture;dword dwPageSize;ptr lpMinimumApplicationAddress;" & _
            "ptr lpMaximumApplicationAddress;long_ptr dwActiveProcessorMask;dword dwNumberOfProcessors;dword dwProcessorType;dword dwAllocationGranularity;" & _
            "short wProcessorLevel;short wProcessorRevision")

    $err = DllCall("Kernel32.dll", "none", "GetSystemInfo", "ptr", DllStructGetPtr($S_SYSTEM_INFO))

    If @error Or Not IsArray($err) Then
        Return $RetArr[0] = -1
    Else
        $CpuNum = DllStructGetData($S_SYSTEM_INFO, "dwNumberOfProcessors")
        ReDim $RetArr[$CpuNum + 1]
        $RetArr[0] = $CpuNum
    EndIf
    $S_SYSTEM_INFO = 0

    While 1
        $S_SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION = DllStructCreate($tagS_SPPI)
        $StructSize = DllStructGetSize($S_SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION)
        $S_SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION = DllStructCreate("byte puffer[" & $StructSize * $CpuNum & "]")
        $pointer = DllStructGetPtr($S_SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION)

        $err = DllCall("ntdll.dll", "int", "NtQuerySystemInformation", _
                "int", $SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION, _
                "ptr", DllStructGetPtr($S_SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION), _
                "int", DllStructGetSize($S_SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION), _
                "int", 0)

        If $err[0] Then
            Return $RetArr[0] = -2
        EndIf

        Local $S_SYSTEM_TIME_INFORMATION = DllStructCreate("int64;int64;int64;uint;int")
        $err = DllCall("ntdll.dll", "int", "NtQuerySystemInformation", _
                "int", $SYSTEM_TIME_INFO, _
                "ptr", DllStructGetPtr($S_SYSTEM_TIME_INFORMATION), _
                "int", DllStructGetSize($S_SYSTEM_TIME_INFORMATION), _
                "int", 0)

        If $err[0] Then
            Return $RetArr[0] = -3
        EndIf

        If $starttime = 0 Then
            ReDim $IdleOldArr[$CpuNum]
            For $i = 0 To $CpuNum - 1
                $tmpStruct = DllStructCreate($tagS_SPPI, $pointer + $i * $StructSize)
                $IdleOldArr[$i] = DllStructGetData($tmpStruct, "IdleTime")
            Next
            $starttime = DllStructGetData($S_SYSTEM_TIME_INFORMATION, 2)
            Sleep(100)
        Else
            ReDim $IdleNewArr[$CpuNum]
            For $i = 0 To $CpuNum - 1
                $tmpStruct = DllStructCreate($tagS_SPPI, $pointer + $i * $StructSize)
                $IdleNewArr[$i] = DllStructGetData($tmpStruct, "IdleTime")
            Next

            $timediff = DllStructGetData($S_SYSTEM_TIME_INFORMATION, 2) - $starttime

            For $i = 0 To $CpuNum - 1
                $RetArr[$i + 1] = Round(100 - (($IdleNewArr[$i] - $IdleOldArr[$i]) * 100 / $timediff))
            Next

            Return $RetArr
        EndIf

        $S_SYSTEM_PROCESSOR_PERFORMANCE_INFORMATION = 0
        $S_SYSTEM_TIME_INFORMATION = 0
        $tmpStruct = 0
    WEnd
EndFunc   ;==>_GetCPUUsage

 

Edited January 6, 2017 by Melba23
Added code tags

[Melba23]

nss,

When you post code please use Code tags - see here how to do it.  Then you get a scrolling box and syntax colouring as you can see above now I have added the tags.

M23

[JLogan3o13]

Have you compared just a simply WMI call? This seems to be accurate on my PC:

$oWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
$aSystem = $oWMI.ExecQuery("SELECT * FROM Win32_PerfFormattedData_PerfOS_Processor")


    For $sProc In $aSystem
        ConsoleWrite($sProc.Name & ": " & $sProc.PercentProcessorTime & @CRLF)
    Next

 

[nss]

Thank you JLogan; that seems to be accurate. Sorry @melba; I wasn't sure how to make it treat like the code, now that I know, I will remember that for the future posts.