Need refresher on date conversion

[qwert]

Every now and then, I come upon the need to compare file dates. Then I realize that I don't have any snippet for the necessary conversions, so I search the help and forum for a simple call. Here's what I mean:

FileGetTime returns YYYYMMDDHHMMSS ... which is great for comparing file dates.

But when a user enters a date on a form and I read it (GUICtrlRead), there isn't a format option that matches the above. Even _NowCalc() doesn't have a matching choice.

Is there a Au3 feature or call to convert an entered date to a "file date"?  Or is there a different common denominator format that I should be using for date comparisons?

Thanks in advance for help.

[czardas]

The date shown above can be interpreted in two different ways. Knowing the user's location would help, a bit. Although I haven't used it myself, you could try Melba's Date_Time_Convert UDF. https://www.autoitscript.com/forum/topic/154684-date_time_convert-bugfix-version-27-may-15/

I did some work on interpreting the format returned from the calendar control. You might be able to modify my code (it's rather complicated though, and I don't have much time to explain it). There's a lot of GUI code that you don't need:

 

Edited January 7, 2017 by czardas

[qwert]

Thanks for your quick reply.

Melba23's UDF is tantalizingly close. But I don't see anything that handles YYYYMMDDHHMMSS.

This is why I get the uncomfortable feeling that I'm off the main path and am comparing dates the wrong way.

 

BTW, the date I'm reading is formatted M/D/YYYY.

Edited January 7, 2017 by qwert

[czardas]

Are all your users in the same country? If not then the order may change. You should be able to force the calendar control to always return the same format.

[qwert]

 

Quote

Are all your users in the same country?

Yes ... although I'm not wild about the way the date is formatted in the form's entry field. Having blanks only serves to confuse. But I haven't had time to see if there are alternatives.

 

[zone97]

Maybe this could help some.

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#Tidy_Parameters=/tc 3 /reel
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <DateTimeConstants.au3>
#include <GuiDateTimePicker.au3>
#include <Date.au3>

#Region ### START Koda GUI section ### Form=
$hGui = GUICreate("Date Picker", 285, 70, -1, -1)
GUISetBkColor(0xC0C0C0)
$hdate1 = GUICtrlCreateDate("", 16, 26, 250, 20)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

GUICtrlSetData($hdate1, _Now())
$hWndDate1 = ControlGetHandle($hGui, "", $hdate1)
_GUICtrlDTP_SetFormat($hWndDate1, "MM/dd/yyyy")

While 1
   $msg = GUIGetMsg()
   Switch $msg
      Case -3
         Quit()
      Case $hdate1
         Create_File()
   EndSwitch
WEnd

Func Create_File()
   FileDelete("all_reports.acsauto")

   $date_array = StringSplit(GUICtrlRead($hdate1), "/")

   $yDate = $date_array[3]
   $mDate = $date_array[1]
   $dDate = $date_array[2]

   MsgBox(0, "Done", $yDate&$mDate&$dDate)
EndFunc   ;==>Create_File

Func Quit()
   Exit
EndFunc   ;==>Quit

 

[czardas]

In my code you can find an example of forcing a four digit year in the control:

; force a four digit year in the date control
    GUICtrlSendMsg($idDate1, 0x1032, 0, LongYearFormat()) ; what is this magic?
    GUICtrlSendMsg($idDate2, 0x1032, 0, LongYearFormat())
    ; https://www.autoitscript.com/forum/topic/93701-how-to-format-date-time-picker-selected-date/#comment-673255 [Melba23]

and

Func LongYearFormat() ; convert yy to yyyy
    Local $iID = _WinAPI_GetUserDefaultLCID(), _
    $sFormat = _WinAPI_GetLocaleInfo($iID, $LOCALE_SSHORTDATE)
    $sFormat = StringRegExpReplace($sFormat, '(?i)(\byy\b)', 'yyyy')
    Return $sFormat
EndFunc ;==> LongYearFormat

With modification, you can force the calendar to always return mm/dd/yyyy (or similar). Then you can swap the order very easily. There are various ways you can do this.

Edit: Or use DTP like @zone97 suggested.

Edited January 7, 2017 by czardas

[qwert]

That's more like it! Date Picker solves the problem of blanks on the form ... and gives the format I need for comparisons.

Thanks to you both.

 

[Melba23]

qwert,

Quote

Melba23's UDF is tantalizingly close. But I don't see anything that handles YYYYMMDDHHMMSS

The UDF handles it very well - as you can see here:

#include "DTC.au3"

; Convert from YYYYMMDDHHMMSS to M/D/YYYY
$sIn_Date = "20170107123456"

$sOut_Date = _Date_Time_Convert($sIn_Date, "yyyyMMddHHmmss", "M/d/yyyy")

ConsoleWrite($sOut_Date & @CRLF)

; And back again

$sIn_Date = $sOut_Date

$sOut_Date = _Date_Time_Convert($sIn_Date, "M/d/yyyy", "yyyyMMdd000000") ; No time defined so force to "000000"

ConsoleWrite($sOut_Date & @CRLF)

M23