HoyKey UDF (Glicth Fix?)

[zone97]

I am using the hotkey_21b.au3 UDF.. And as others have pointed out there is a glitch where the keys get stuck.. Here is an example script where I tried to make a work around. Anyone know how I might fix this? Short of not using the UDF...  The test, I opened notepad put in some text, hit the hot key and it selected all and cleared. But often the CTRL or ALT key gets hung? I have even had it trigger CTRL-ALT-DEL .. Ideally Id like to find the glitch in the UDF and fix it.

 

#include ".\Includes\HotKey_21b.au3"

; - 1620 = CTRL-ALT-T

 _HotKey_Assign('1620', 'test', $HK_FLAG_DEFAULT)

 While 1
 Sleep(100)
 WEnd

Func Test()
    ReleaseModifiers()
    Send("^a")
    Send("{DEL}")
    MsgBox(0, "test", "I sent a CTRL-A followed by DELETE")
    Exit
EndFunc

Func ReleaseModifiers()
    Send("{SHIFTUP}")
    Send("{CTRLUP}")
    Send("{ALTUP}")
    Sleep(100)
EndFunc   ;==>ReleaseModifiers

 

HotKey_21b.au3

[anthonyjr2]

Is this related at all to this?

https://www.autoitscript.com/wiki/FAQ#Why_does_the_Ctrl_key_get_stuck_down_after_I_run_my_script.3F

Edited January 11, 2017 by anthonyjr2

[zone97]

Yes and no...

Last post on this page did something similar, but don't think the issue is resolved yet.

https://www.autoitscript.com/forum/topic/90492-hotkey-udf/?page=10

[zone97]

After trying several fixes. This one seems to be the most reliable. I replaced the built in Send() function with SendEx()

Func SendEx($ss, $warn = "")
    Local $iT = TimerInit()
    ; - Check for stuck modifiers ALT, SHIFT, CTRL, LWIN, RWIN
    While _IsPressed("10") Or _IsPressed("11") Or _IsPressed("12") Or _IsPressed("5B") Or _IsPressed("5C")
        If $warn <> "" And TimerDiff($iT) > 1000 Then
            SplashTextOn("", "Working!", 130, 43, -1, -1, 1)
            Sleep(500)
            SplashOff()
        EndIf
        Sleep(50)
    WEnd
    Send($ss)
EndFunc   ;==>SendEx

 

[careca]

I can't remember what it was exactly but you could send the key up, after using any ctrl or alt or shift.

Edited January 18, 2017 by careca

[zone97]

I had tried the {CTRLUP} option, didn't work. Here is my text example with applied fixes. Not 100% but closest I could get.

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Run_Tidy=y
#Tidy_Parameters=/tc 4 /reel
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include ".\Includes\HotKey_21b.au3"
; - Functional UDFs
#include <Timers.au3>
#include <Misc.au3>

; - 1621 = CTRL-ALT-U

; - Keyboard cleanup handler
Global $dll = DllOpen(@WindowsDir & "\System32\user32.dll")
Global Const $vKeys[8] = [0xA0, 0xA1, 0xA2, 0xA3, 0xA4, 0xA5, 0x5B, 0x5C]

_HotKey_Assign('1621', 'test', $HK_FLAG_DEFAULT)

While 1
    Sleep(100)
WEnd

Func Test()
    ReleaseModifiers()
    SendEx("^a")
    SendEx("{DEL}")
    MsgBox(0, "test", "I sent a CTRL-A followed by DELETE")
    Quit()
EndFunc   ;==>Test

Func SendEx($ss, $warn = "")
    Local $iT = TimerInit()
    ; - Check for stuck modifiers ALT, SHIFT, CTRL, LWIN, RWIN
    While _IsPressed("10") Or _IsPressed("11") Or _IsPressed("12") Or _IsPressed("5B") Or _IsPressed("5C")
        If $warn <> "" And TimerDiff($iT) > 1000 Then
            SplashTextOn("", "Working!", 100, 43, -1, -1, 1)
            Sleep(500)
            SplashOff()
        EndIf
        Sleep(50)
    WEnd
    Send($ss)
EndFunc   ;==>SendEx

Func ReleaseModifiers()
    For $vKvalue In $vKeys
        DllCall($dll, "int", "keybd_event", "int", $vKvalue, "int", 0, "long", 2, "long", 0) ; Release each key
        Sleep(10)
    Next
    Sleep(100)
EndFunc   ;==>ReleaseModifiers

Func Quit()
    DllClose($dll)
    ReleaseModifiers()
    Exit
EndFunc   ;==>Quit