Multiple ListBoxes problems

[A20017]

Hi

I want to use multiple ListBox in my GUI. So far no problem.

Now I need to delete single ListBox items with DEL key. This would work with one ListBox. I could not figure out how to handle multiple ListBoxes... Whenever I select one item and press DEL key, the selected index is deleted on all ListBoxes.

 

Sample code:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <Date.au3>
#include <Timers.au3>
#include <String.au3>
#include <StringConstants.au3>
#Include <GuiListBox.au3>
#include <Misc.au3>
$dll = DllOpen("user32.dll")


$hGUI = GUICreate("test", 478, 728, (@DesktopWidth - 478) / 2, (@DesktopHeight - 728) / 2, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, $WS_CLIPCHILDREN))

Global $hListBoxGlobal, $hListBoxMain, $hListBoxMini
    GUICtrlCreateGraphic(206,2,2,711,$SS_SUNKEN)
    $hListBoxGlobal = _GUICtrlListBox_Create($hGUI, "", 210, 4, 200, 240, $LBS_EXTENDEDSEL)
    $hListBoxMain = _GUICtrlListBox_Create($hGUI, "", 210, 244, 200, 240, $LBS_EXTENDEDSEL)
    $hListBoxMini = _GUICtrlListBox_Create($hGUI, "", 210, 484, 200, 240, $LBS_EXTENDEDSEL)

GUISetState()


_GUICtrlListBox_AddString ($hListBoxGlobal, "ONE-Global")
_GUICtrlListBox_AddString ($hListBoxGlobal, "TWO-Global")
_GUICtrlListBox_AddString ($hListBoxGlobal, "THREE-Global")

_GUICtrlListBox_AddString ($hListBoxMain, "ONE-Main")
_GUICtrlListBox_AddString ($hListBoxMain, "TWO-Main")

_GUICtrlListBox_AddString ($hListBoxMini, "ONE-Mini")
_GUICtrlListBox_AddString ($hListBoxMini, "TWO-Mini")
_GUICtrlListBox_AddString ($hListBoxMini, "THREE-Mini")
_GUICtrlListBox_AddString ($hListBoxMini, "FOUR-Mini")

While 1
    If _IsPressed("2E", $dll) Then
        ; Wait for key to be released to avoid multiple firing the code below
        While _IsPressed("2E", $dll)
            Sleep(10)
        WEnd
        If _GUICtrlListBox_GetCurSel($hListBoxGlobal) >= 0 Then
            Local $indice = _GUICtrlListBox_GetCurSel($hListBoxGlobal)
            _GUICtrlListBox_DeleteString($hListBoxGlobal, $indice)
        EndIf

        If _GUICtrlListBox_GetCurSel($hListBoxMain) >= 0 Then
            Local $indice = _GUICtrlListBox_GetCurSel($hListBoxMain)
            _GUICtrlListBox_DeleteString($hListBoxMain, $indice)
        EndIf

        If _GUICtrlListBox_GetCurSel($hListBoxMini) >= 0 Then
            Local $indice = _GUICtrlListBox_GetCurSel($hListBoxMini)
            _GUICtrlListBox_DeleteString($hListBoxMini, $indice)
        EndIf
    EndIf
WEnd

 

Can you help me?

Thanks.

[Melba23]

A20017,

Just check which ListBox has focus:

While 1
    If _IsPressed("2E", $dll) Then
        ; Wait for key to be released to avoid multiple firing the code below
        While _IsPressed("2E", $dll)
            Sleep(10)
        WEnd

        ; Detect focused ListBox
        Switch _WinAPI_GetFocus()
            Case $hListBoxGlobal
                $indice = _GUICtrlListBox_GetCurSel($hListBoxGlobal)
                _GUICtrlListBox_DeleteString($hListBoxGlobal, $indice)
            Case $hListBoxMain
                $indice = _GUICtrlListBox_GetCurSel($hListBoxMain)
                _GUICtrlListBox_DeleteString($hListBoxMain, $indice)
            Case $hListBoxMini
                $indice = _GUICtrlListBox_GetCurSel($hListBoxMini)
                _GUICtrlListBox_DeleteString($hListBoxMini, $indice)
        EndSwitch
    EndIf
WEnd

Good enough?

M23

[A20017]

Hi Melba23

Thank you. Exactly what I was searching for.

 

A20017

[Melba23]

A20017,#

Glad I could help - and welcome to the AutoIt forums.

M23