Mouse not Over Tray delay in loop

[careca]

Hey there, having this issue that is puzzling me:

#AutoIt3Wrapper_Run_Tidy=y
#AutoIt3Wrapper_Run_AU3Check=y
#AutoIt3Wrapper_Run_Debug_Mode=n

#include <Constants.au3>
#include <TrayConstants.au3>

While 1
    $_Msg = TrayGetMsg()
    Switch $_Msg
        Case $TRAY_EVENT_MOUSEOVER
            ConsoleWrite(' $over_icon = 1 - ' & @MSEC & @CRLF)
            ;$begin = TimerInit()
        Case Else
            ConsoleWrite(' $over_icon = 0 - ' & @MSEC & @CRLF)
    EndSwitch
    ;=============================================================================
    ;$Dn = TimerDiff($begin)
    ;If $Dn >= 2000 Then
    ;=============================================================================
    Sleep(100)
WEnd

So if i only pass the mouse over the icon it works fine, detects the mouseover and console responds, but if i keep the mouse over for a few seconds, when i remove the mouse, it keeps outputing as if it's still hovering, and only after some time it responds, it's as if it lags.

How can i make it respond instantly? hover = 1 / not hover =0

Thanks

[jguinch]

I think the Sleep(100) is not a good idea.
BTW, the $TRAY_EVENT_MOUSEOVER event is sent only when the mouse moves, so if the user keeps the mouse over the tray icon with moving it, you code won't know that mouse is still over.

I would use an Adlib function and the TrayOnEventMode option, but I think there is an easyer way :

 

#include <Constants.au3>
#include <TrayConstants.au3>

Global $aMousePos, $iMouseOver = 0

Opt("TrayOnEventMode", 1)

TraySetOnEvent($TRAY_EVENT_MOUSEOVER, "_overTray")

While 1
    Sleep(100)
WEnd


Func _overTray()
    $aMousePos = MouseGetPos()
    If Not $iMouseOver Then AdlibRegister("_checkMouseOverTrayAdlib", 100)
    $iMouseOver = 1
EndFunc


Func _checkMouseOverTrayAdlib()
    $aMousePos2 = MouseGetPos()
    If $aMousePos2[0] <> $aMousePos[0] Or $aMousePos2[1] <> $aMousePos[1] Then
        $iMouseOver = 0
        AdlibUnRegister("_checkMouseOverTrayAdlib")
        ConsoleWrite("Mouse not over tray" & @CRLF)
        Return
    EndIf
    ConsoleWrite("Mouse over tray" & @CRLF)
EndFunc

 

[careca]

Ahhh i see, very nice! Thank you.