_IE script crashes after few minutes

[Adisma]

Hello,

First, here is the script

 

expandcollapse popup

;*****************************************
;PMU.au3 by Romain
;Créé avec ISN AutoIt Studio v. 0.99 BETA
;*****************************************
#include <IE.au3>


_IEErrorHandlerRegister(_User_ErrFunc)

Run("notepad.exe")
Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

$oIE = _IECreate()

for $jour = 10 to 31
    _IENavigate($oIE, "http://www.canalturf.com/courses_archives.php?date=2017-01-" & $jour)

    ;~ On parcourt tous les a, dont la classe est btn btn-sm btn-primary ==> les pronos
    $tags = $oIE.document.GetElementsByTagName("a")
    For $tag in $tags
        $class_value = $tag.className
        If $class_value = "btn btn-sm btn-primary" Then
            $url = $tag.getAttribute("href")
            
            $oIE_prono =  _IECreate()
            _IENavigate($oIE_prono, $url)
            sleep(250)
            $tagsProno = $oIE_prono.document.GetElementsByTagName("td")
            
            $prono = $url
            for $tagProno in $tagsProno
                $wv = $tagProno.getAttribute("width")
                if $wv = 30 Then
                    $prono = $prono & "," & _IEPropertyGet($tagProno,"innerText")                
                EndIf
            Next
            sleep(250)
            WinActivate($hWnd)
            sleep(200)
            Send($prono)
            Send("{ENTER}")
            
            Sleep(250)
            _IEQuit($oIE_prono)
        EndIf
    Next
next


Func _User_ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptFullPath & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc

Purpose : get pronostic history to do statistics on it

In the 1st page, I get all <a> tags with correct class attribute to have all links to the pronostic page.

Then I loop on each page to get the last 3 tables with the number of horses.

And I write it into notepad.

All works fine during 2~3minutes, but after this, the script crashes with errors : 
 

C:\Users\Romain\Documents\ISN AutoIt Studio\Projects\PMU\PMU.au3 (28) : ==> COM Error intercepted !
    err.number is:         0x80020008
    err.windescription:    Type de variable incorrect.

    err.description is:     
    err.source is:         
    err.helpfile is:     
    err.helpcontext is:     
    err.lastdllerror is:     0
    err.scriptline is:     28
    err.retcode is:     0x00000000

C:\Users\Romain\Documents\ISN AutoIt Studio\Projects\PMU\PMU.au3 (31) : ==> COM Error intercepted !
    err.number is:         0x000000A9
    err.windescription:    Variable is not of type 'Object'.
    err.description is:     
    err.source is:         
    err.helpfile is:     
    err.helpcontext is:     
    err.lastdllerror is:     0
    err.scriptline is:     31
    err.retcode is:     0x00000000

Any idea how to fix it ?

 

Thanks in advance

[Danp2]

What version of AutoIT? FWIW, I ran your script without encountering this error.

P.S. Here's a slightly modified version that eliminates the constant creation / deletion of the 2nd IE object, and also uses ControlSend instead of Send so that output will correctly go to Notepad even if the user has switched active windows --

expandcollapse popup

;*****************************************
;PMU.au3 by Romain
;Créé avec ISN AutoIt Studio v. 0.99 BETA
;*****************************************
#include <IE.au3>


_IEErrorHandlerRegister(_User_ErrFunc)

Run("notepad.exe")
Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

$oIE = _IECreate()
$oIE_prono =  _IECreate()

for $jour = 10 to 31
    _IENavigate($oIE, "http://www.canalturf.com/courses_archives.php?date=2017-01-" & $jour)

    ;~ On parcourt tous les a, dont la classe est btn btn-sm btn-primary ==> les pronos
    $tags = $oIE.document.GetElementsByTagName("a")
    For $tag in $tags
        $class_value = $tag.className
        If $class_value = "btn btn-sm btn-primary" Then
            $url = $tag.getAttribute("href")

            _IENavigate($oIE_prono, $url)
            sleep(250)
            $tagsProno = $oIE_prono.document.GetElementsByTagName("td")

            $prono = $url
            for $tagProno in $tagsProno
                $wv = $tagProno.getAttribute("width")
                if $wv = 30 Then
                    $prono = $prono & "," & _IEPropertyGet($tagProno,"innerText")
                EndIf
            Next
;            sleep(250)
;            WinActivate($hWnd)
;            sleep(200)
            ControlSend($hWnd, "", "Edit1",$prono)
            ControlSend($hWnd, "", "Edit1","{ENTER}")

            Sleep(250)
        EndIf
    Next
next

_IEQuit($oIE)
_IEQuit($oIE_prono)


Func _User_ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptFullPath & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc

 

[mLipok]

If you are using AutoIt 3.3.14.x then I can only say that this look's familiar with this track ticket.

https://www.autoitscript.com/trac/autoit/ticket/3097

And if so you should wait to @Jon fix it.

.... quick answer: As soon as it's will be fixed, it will be announced to the community.

 

[Adisma]

Indeed, I'm in 3.3.14.2.

@Danp2, I tested your version with the same issue.

 

I think I'll downgrade my AutoIT while this issues isn't fixed.

 

 

[Adisma]

With AutoIT 3.3.12, it works like a charm