Jump to content
ModemJunki

Is it possible to create menu with no tab stops on the buttons?

Recommended Posts

I'm having a hard time figuring out how to make a menu without any tab stops for the buttons.

I made a shell menu for BIOS flashing in WinPE and in it I don't want *any* buttons to be tab stopped. If I try to use GUICtrlSetStyle to remove the tab stops from all the buttons, the first button declared in the menu ends up the default (so the user could press the spacebar and the button is activated).

Melba23 posted some code like below a long time ago in this post but it seems to do the same thing as GUICtrlSetStyle does.

Any tips/help is appreciated.

_WinAPI_SetWindowLong(GUICtrlGetHandle(-1), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle(-1), $GWL_STYLE), BitNOT($WS_TABSTOP)))
#include <ButtonConstants.au3>
#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>


Opt("GUICloseOnESC", 0) ; prevent user from pressing escape key and accidentally cancelling the GUI
HotKeySet("+!{ESC}", "_doCMD") ; shift-alt-escape for a command dialogue during GUI (lab/service use)

#include <Array.au3>
#include <ButtonConstants.au3>
#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

GLobal $s_Cmd1, $s_Cmd2, $s_Cmd3, $s_Cmd4, $s_Cmd5
$s_Debug = 0
$s_dbgArray = 0

Opt("GUICloseOnESC", 0) ; prevent user from pressing escape key and accidentally cancelling the GUI
HotKeySet("+!{ESC}", "_doCMD") ; shift-alt-escape for a command dialogue during GUI (lab/service use)

$MainMenu = GUICreate("Main BIOS Menu", 600, 400, -1, -1, 0, $WS_EX_TOPMOST)
$Button1 = GUICtrlCreateButton("1", 48, 64, 75, 25)
$Label1 = GUICtrlCreateLabel("One", 136, 68, 186, 20)
$Button2 = GUICtrlCreateButton("2", 48, 110, 75, 25)
$Label2 = GUICtrlCreateLabel("Two", 136, 113, 389, 20)
$Button3 = GUICtrlCreateButton("3", 48, 172, 75, 25)
$Label3 = GUICtrlCreateLabel("Three", 136, 176, 186, 20)
$Button4 = GUICtrlCreateButton("4", 48, 218, 75, 25)
$Label4 = GUICtrlCreateLabel("Four", 136, 221, 389, 20)
$Button5 = GUICtrlCreateButton("5", 48, 272, 75, 25)
$Label5 = GUICtrlCreateLabel("Five", 136, 274, 280, 20)
$Button6 = GUICtrlCreateButton("Cancel", 475, 340, 75, 25)
$Label6 = GUICtrlCreateLabel("Click to cancel the operations", 300, 345, 175, 20)
$Label0 = GUICtrlCreateLabel("Please choose one of the following 5 options:", 171, 16, 271, 20)
$Label7 = GUICtrlCreateLabel("Which system do you want to set up? [Press or click 1, 2, 3, 4 or use 5 to flash]", 78, 312, 456, 20)
$Group1 = GUICtrlCreateGroup("IVS", 36, 44, 513, 101)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("IAS", 36, 152, 513, 101)
GUICtrlCreateGroup("", -99, -99, 1, 1)

_WinAPI_SetWindowLong(GUICtrlGetHandle($Button1), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle($Button1), $GWL_STYLE), BitNOT($WS_TABSTOP)))
_WinAPI_SetWindowLong(GUICtrlGetHandle($Button2), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle($Button2), $GWL_STYLE), BitNOT($WS_TABSTOP)))
_WinAPI_SetWindowLong(GUICtrlGetHandle($Button3), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle($Button3), $GWL_STYLE), BitNOT($WS_TABSTOP)))
_WinAPI_SetWindowLong(GUICtrlGetHandle($Button4), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle($Button4), $GWL_STYLE), BitNOT($WS_TABSTOP)))
_WinAPI_SetWindowLong(GUICtrlGetHandle($Button5), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle($Button5), $GWL_STYLE), BitNOT($WS_TABSTOP)))
_WinAPI_SetWindowLong(GUICtrlGetHandle($Button6), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle($Button6), $GWL_STYLE), BitNOT($WS_TABSTOP)))

;~ GUICtrlSetStyle($Button1, 0)
;~ GUICtrlSetStyle($Button2, 0)
;~ GUICtrlSetStyle($Button3, 0)
;~ GUICtrlSetStyle($Button4, 0)
;~ GUICtrlSetStyle($Button5, 0)
;~ GUICtrlSetStyle($Button6, 0)
GUISetState(@SW_SHOW, $MainMenu)

While 1
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE Or $nMsg = $Button6
            GUISetState(@SW_HIDE, $MainMenu)
            MsgBox(4096, "Cancel", "Operation cancelled. Please remove the media and click OK to reboot.")
            Exit
        Case $nMsg = $Button1 Or _IsPressed("31") Or _IsPressed("61") ; is the button, keyboard number, or keypad number pressed?
            _doRun(@ScriptDir & "\" & $s_Cmd1)
        Case $nMsg = $Button2 Or _IsPressed("32") Or _IsPressed("62")
            _doRun(@ScriptDir & "\" & $s_Cmd2)
        Case $nMsg = $Button3 Or _IsPressed("33") Or _IsPressed("63")
            _doRun(@ScriptDir & "\" & $s_Cmd3)
        Case $nMsg = $Button4 Or _IsPressed("34") Or _IsPressed("64")
            _doRun(@ScriptDir & "\" & $s_Cmd4)
        Case $nMsg = $Button5 Or _IsPressed("35") Or _IsPressed("65")
            _doRun(@ScriptDir & "\" & $s_Cmd5)
    EndSelect
WEnd

;~ ;=============================================================================
;~ ;==================================Functions==================================
;~ ;=============================================================================

;~ ;=============================================================================
;~ ; Run function for batch or executable files, hides main menu when running
;~ ;=============================================================================
Func _doRun($RunFile)
    GUISetState(@SW_HIDE, $MainMenu)
    RunWait(@ComSpec & " /c " & $RunFile)
    GUISetState(@SW_SHOW, $MainMenu)
EndFunc   ;==>_doRun

; --------------------------------------------------
; Run a command prompt for lab/field troubleshooting
; --------------------------------------------------
Func _doCMD()
    HotKeySet("+!{ESC}") ; deactivate hotkey to prvent spawning multiple cmd boxes with it
    GUISetState(@SW_HIDE, $MainMenu) ; hide the GUI
    RunWait(@ComSpec & " /c " & "cmd.exe", "", @SW_SHOW)
    GUISetState(@SW_SHOW, $MainMenu) ; bring the GUI back up
    HotKeySet("+!{ESC}", "_doCMD") ; reset the hotkey shift-alt-escape for a command dialogue (emergency use)
EndFunc   ;==>_doCMD

 

Edited by ModemJunki

Share this post


Link to post
Share on other sites

ModemJunki,

Either the _WinAPI_SetWindowLong or GUICtrlSetStyle code works for me to remove the TAB_STOP style:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <Misc.au3>

Opt("GUICloseOnESC", 0) ; prevent user from pressing escape key and accidentally cancelling the GUI
HotKeySet("+!{ESC}", "_doCMD") ; shift-alt-escape for a command dialogue during GUI (lab/service use)

Global $aButton[6]
Global $aButtonData[6][2] = [["", ""], [1, "One"], [2, "Two"], [3, "Three"], [4, "Four"], [5, "Five"]]
Global $aCommand[6] = ["", "Command1", "Command2", "Command3", "Command4", "Command5"]

Local $hDLL = DllOpen("user32.dll")

$MainMenu = GUICreate("Main BIOS Menu", 600, 400, -1, -1, 0, $WS_EX_TOPMOST)

For $i = 1 To 5
    $aButton[$i] = GUICtrlCreateButton($aButtonData[$i][0], 48, 5 + (40 * $i), 75, 25)
    GUICtrlCreateLabel($aButtonData[$i][1], 136, 8 + (60 * $i), 186, 20)
    ;_WinAPI_SetWindowLong(GUICtrlGetHandle($aButton[$i]), $GWL_STYLE, BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle($aButton[$i]), $GWL_STYLE), BitNOT($WS_TABSTOP)))
    GUICtrlSetStyle($aButton[$i], 0)
Next
$Button6 = GUICtrlCreateButton("Cancel", 475, 340, 75, 25)
GUICtrlCreateLabel("Click to cancel the operations", 300, 345, 175, 20)
GUICtrlCreateLabel("Please choose one of the following 5 options:", 171, 16, 271, 20)
GUICtrlCreateLabel("Which system do you want to set up? [Press or click 1, 2, 3, 4 or use 5 to flash]", 78, 312, 456, 20)
$Group1 = GUICtrlCreateGroup("IVS", 36, 44, 513, 101)
$Group2 = GUICtrlCreateGroup("IAS", 36, 152, 513, 101)
GUICtrlCreateGroup("", -99, -99, 1, 1)

GUISetState(@SW_SHOW, $MainMenu)

While 1
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE Or $nMsg = $Button6
            GUISetState(@SW_HIDE, $MainMenu)
            MsgBox(4096, "Cancel", "Operation cancelled. Please remove the media and click OK to reboot.")
            DllClose($hDLL)
            Exit
        Case Else
            For $i = 1 To 5
                $sKeyCode1 = String(30 + $i)
                $sKeyCode2 = String(60 + $i)
                If $nMsg = $aButton[$i] Or _IsPressed($sKeyCode1, $hDLL) Or _IsPressed($sKeyCode2, $hDLL) Then ; is the button, keyboard number, or keypad number pressed?
                    _doRun(@ScriptDir & "\" & $aCommand[$i])
                    ExitLoop
                EndIf
            Next
    EndSelect
WEnd

;~ ;=============================================================================
;~ ;==================================Functions==================================
;~ ;=============================================================================

;~ ;=============================================================================
;~ ; Run function for batch or executable files, hides main menu when running
;~ ;=============================================================================
Func _doRun($RunFile)
    GUISetState(@SW_HIDE, $MainMenu)
    RunWait(@ComSpec & " /c " & $RunFile)
    GUISetState(@SW_SHOW, $MainMenu)
EndFunc   ;==>_doRun

; --------------------------------------------------
; Run a command prompt for lab/field troubleshooting
; --------------------------------------------------
Func _doCMD()
    HotKeySet("+!{ESC}") ; deactivate hotkey to prvent spawning multiple cmd boxes with it
    GUISetState(@SW_HIDE, $MainMenu) ; hide the GUI
    RunWait(@ComSpec & " /c " & "cmd.exe", "", @SW_SHOW)
    GUISetState(@SW_SHOW, $MainMenu) ; bring the GUI back up
    HotKeySet("+!{ESC}", "_doCMD") ; reset the hotkey shift-alt-escape for a command dialogue (emergency use)
EndFunc   ;==>_doCMD

I also took the opportunity to tidy up the code a bit - you will need to polish up the button location algorithm, but I am sure you can see the benefit of using loops when you have multiple controls in a grid.

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Melba23,

The end result is that a button is still in focus (e.g., Cancel button is defaulted as tab stop). Its the safest option for cancel to be in focus but I would prefer that no button is focused as the spacebar activates the focused button. It seems this "nothing-in-focus" may not actually be possible in this way.

I suppose the workaround can either be to create a button with zero size (e.g., GUICtrlCreateButton("", 0, 0 , 0 ,0)) for the default focus or to have Cancel popup an "Are you sure you want to cancel this operation?" with an OK/Cancel dialogue. (After typing this I think perhaps both might be a good idea.)

Thanks for the assistance - the tip about using a loop for the controls looks like it will make maintaining this much easier.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • By nacerbaaziz
      hi dears, i have a question please
      am now working for an audio player for the blind users
      and i added an option to open a file from the right click context menu.
      but here there is a small problem, i hope that you can help me to find a solution for it.
      the problem is as follow :
      when i added the problem into the context menu it work with successfuly if the user select just one file.
      but if the user selected more then one file, here the problem
      a multiple sections of the program will open.
      my question is :
      how i can detect the multiple selection from the context menu?
      i know that it so  hard, but i know also that you are harder than it
      for that dears please try to give me an solution for that problem.
      thanks in advance
    • By wolflake
      I've used PowerPro for years and it had a feature that let you turn an array into a menu.  It also let you know if it got a right click. I liked the right click feature because it doubled the menu item usage ie left/right on the same menu item.  I tried recreate that usage with a context menu.   With _ArrayToMenu you can pass menu items for 1 and 2 dimensional arrays. Note you can indicate sub-menu but using a -> at the end of the item.  Use a - to make a separater. Optionally you can pass Tooltips by passing a second array. This array must have the same dimensions as the items array even if not all the elements contain tips. The UDF returns an array with this index of row (and if submenus column), the third element is 1 if right clicked otherwise 0 and the fourth element of the array is the label of the menu item. If the user escapes without choosing an item the the first element returns a -1.  Same thing if the user clicks on another window.   @error returns 1 if there was no array passed, 2 if the second array has different dimensions than the first.   If you use the same label in two parts of your menu you will have to distinguish them.  You can do that by additionally making sure that the selection matches the index number(s).  Note that you'll have to match the index number plus label before you match just the label because Switch will use the first match it can find.  In the example below I am using a check on which column the data is in.  If it's not in the first column then it must be the other "Beef".   Beef
      Fruit
      Col2 > Beef
                  Bread   $aR = _ArrayToMenu($aM) Switch $aR[3]
      Case "Beef" and $aR[2] = 0
             Beef1()
       Case "Beef"
             Beef2()
      EndSwitch   On a technical note I attached the context menu to the window itself not a dummy control and I didn't use _GUICtrlMenu_TrackPopupMenu.  Instead I launched the context menu with "send shift-F10" and waited for GuiGetMsg() to give me the selection. Right click is picked up by GUIRegisterMsg WM_RBUTTONUP and Tooltips are done with GUIRegisterMsg WM_MENUSELECT. The whole thing is done with 3 functions. 
      I won't tell you how long it took me to figure this out but I'll say that on one of my early attempts it had two windows running at once and one was just to recieve the right click an tell the other it got it.  Suffice it to say I'm no wiz at Autoit but I really appreciate the support the community offers and I hope someone finds this useful. BTW I wrote a script to produce 1d and 2d auotit array code from excel in case you want to model your menu in excel. Here is the link.
      https://www.autoitscript.com/forum/topic/139260-autoit-snippets/?do=findComment&comment=1412314
      _ArrayToMenu() UDF
      ;ArrayToMenu with submenus, tooltips, rightclick and esc to close. ; #INDEX# ======================================================================================================================= ; Title .........: _ArrayToMenu ; AutoIt Version : 3.3.14.2 ; Description ...: Show an array as a popup menu optionally with tooltips and right click. ; Author(s) .....: Rick Sharp ; =============================================================================================================================== ; #FUNCTION# ==================================================================================================================== ; Name..........: _ArrayToMenu($aArray_menu[,$aArray_tooltips]) ; Description...: Display an array as a menu and return the users choice, display tooltips(optional), return right click. ; Syntax........: _ArrayToMenu($aArray_menu[,$aArray_tooltips]) ; ; Parameters....: ; Required......: A 1d or 2d array of menu items ; Use a minus sign in the item to indicate a menu separator. ; Use -> at the end of an item to indicate a sub-menu. ; Optional......: A 1d or 2d array of tooltips. The array must use the same dimensions as the menu items array. ; ; Return values.: An Array ; $aArray[0] is index of the row (-1 if exited with no choice) ; $aArray[1] is index of the column ; $aArray[2] is 1 if right clicked ; $aArray[3] is the selected item (if any) ; Notes.........: If the user clicks on another window the ArrayToMenu returns as if esc were pressed. ; Sub-Menus are limited to 10 levels if you need more change $ahM[10] ; =============================================================================================================================== ; #VARIABLES# =================================================================================================================== ; Global $__g_iRT = 0, $__g_aTT1, $__g_ahi ; "$__g_iRT" for right click flag, "$__g_aTT1" for tips, "$__g_ahi" for index of id's in menu and tips ; =============================================================================================================================== ; #@error# ====================================================================================================================== ; 1 - First parameter is Not an array ; 2 - The Menu/Items array and the Tips array are not the same number of dimensions ; =============================================================================================================================== #include-once #include <WindowsConstants.au3> #include <GuiMenu.au3> #include <array.au3> #include <misc.au3> Func _ArrayToMenu($aMenu, $att = "") If Not IsArray($aMenu) Then Return SetError(1, 0, -1) Global $__g_iRT = 0 Local $ahM[10], $iCcnt = UBound($aMenu, 2), $iRcnt = UBound($aMenu), $iRow, $iCol, $b_Esc If UBound($aMenu, 2) = 0 Then _ArrayColInsert($aMenu, 1) ;if 1d array make it 2d EndIf ;Prep Loop to make Menus and Sub-Menus $iRcnt = UBound($aMenu) ;Count of Rows/Items $iCcnt = UBound($aMenu, 2) ;Count of Cols/Menus GUIRegisterMsg($WM_RBUTTONUP, "WM_RBUTTONUP") ;handles Right Click If IsArray($att) Then If UBound($att, 2) = 0 Then _ArrayColInsert($att, 1) If UBound($att, 2) <> $iCcnt Or UBound($att) <> $iRcnt Then Return SetError(2, 0, -1) ;$amenu and $att not same dimensions Global $__g_aTT1 = $att ;added $__g_aTT1 because $att was not seen by WM_MenuSelect for tooltips GUIRegisterMsg($WM_MENUSELECT, "WM_MENUSELECT") ;handles tooltips EndIf Local $mPos = MouseGetPos() #Region ### START Koda GUI section ### Form= $hMenu = GUICreate("C_menu", 10, 10, $mPos[0], $mPos[1], $WS_POPUP, $WS_EX_TOPMOST) GUISetState(@SW_SHOW) #EndRegion ### END Koda GUI section ### ;Build Menus Global $__g_ahi[$iRcnt + 1][$iCcnt + 1] ;array to hold Menu Item id's $iMcnt = 0 ;Menu count $ahM[$iMcnt] = GUICtrlCreateContextMenu() ;if the array element is null then it falls through and nothing happens For $j = 0 To $iCcnt - 1 ;for each Column/Menu For $i = 0 To $iRcnt - 1 ;for each Row/Item If StringRight($aMenu[$i][$j], 2) = "->" Then ;Sub-Menu $aMenu[$i][$j] = StringTrimRight($aMenu[$i][$j], 2) ;remove -> $iMcnt += 1 $ahM[$iMcnt] = GUICtrlCreateMenu($aMenu[$i][$j], $ahM[$j]) ; $__g_ahi[$i][$j] = $ahM[$iMcnt] ElseIf $aMenu[$i][$j] > "" Then ;Normal item If StringLeft($aMenu[$i][$j], 1) = "-" Then $aMenu[$i][$j] = "" $__g_ahi[$i][$j] = GUICtrlCreateMenuItem($aMenu[$i][$j], $ahM[$j]) EndIf Next Next Send("+{F10}") ;sends right click to open context menu While 1 $nMsg = GUIGetMsg() If $nMsg > 0 Then ;ConsoleWrite("nMsg= " & $nMsg & @CRLF) $iRow = _ArraySearch($__g_ahi, $nMsg) $iCol = _ArraySearch($__g_ahi, $nMsg, 0, 0, 0, 0, 0, $iRow, True) ExitLoop EndIf If _IsPressed("1B") = 1 Or WinActive("C_menu") = 0 Then $b_Esc = -1 ExitLoop EndIf WEnd ;*** Done *** GUIDelete($hMenu) Local $aAr1[4] $aAr1[0] = $iRow $aAr1[1] = $iCol $aAr1[2] = $__g_iRT If Not $b_Esc = -1 Then $aAr1[3] = $aMenu[$aAr1[0]][$aAr1[1]] Else $aAr1[0] = -1 EndIf Return $aAr1 EndFunc ;==>_ArrayToMenu ;Check for Right Click Func WM_RBUTTONUP($hMenu, $iMsg, $iwParam, $ilParam) $__g_iRT = 1 ;Mark as rclicked Send("{Enter}") ;choose the item EndFunc ;==>WM_RBUTTONUP ;Tooltips Func WM_MENUSELECT($hMenu, $iMsg, $iwParam, $ilParam) Local $idMenu = BitAND($iwParam, 0xFFFF) Local $iRow, $iCol If $idMenu > 0 Then $iRow = _ArraySearch($__g_ahi, $idMenu) If $iRow > -1 Then $iCol = _ArraySearch($__g_ahi, $idMenu, 0, 0, 0, 0, 0, $iRow, True) EndIf If $iCol > -1 And $iRow > -1 And $__g_aTT1[$iRow][$iCol] > " " Then ToolTip($__g_aTT1[$iRow][$iCol]) Else ToolTip("") EndIf EndIf EndFunc ;==>WM_MENUSELECT Example 1 Simple 1d array with tooltips, item separator and right click.
      #include "ArrayToMenu.au3" ;Simple 1d array with tooltips item separator and right click. $aM = StringSplit("Zero,One,-,Two/Two_R", ",", 3) ;make an array for the menu items $aT = StringSplit("Zero,One,-,", ",", 3) ;make an array for the menu Tooltips $aR = _ArrayToMenu($aM,$aT) if @error then ConsoleWrite(@error & @CRLF) EndIf ConsoleWrite("R: " & $aR[0] & " " & "C: " & $aR[1] & " " & "Rclick: " & $aR[2] & " " & "Item: " & $aR[3] & @CRLF) If $aR[0] = -1 Then ;either hit escape or clicked on another window ConsoleWrite("Esc" & @CRLF) Exit EndIf ;_ArrayDisplay($aR) Switch $aR[3] Case "Zero" Zero() Case "One" One() Case "Two/Two_R" And $aR[2] = 0 ;No Rclick Two() Case "Two/Two_R" And $aR[2] = 1 ;Rclick Two_R() EndSwitch Func Zero() ConsoleWrite("You chose: Zero" & @CRLF) EndFunc ;==>Zero Func One() ConsoleWrite("You chose: One" & @CRLF) EndFunc ;==>One Func Two() ConsoleWrite("You chose: Two" & @CRLF) EndFunc ;==>Two Func Two_R() ConsoleWrite("You chose: Two_R" & @CRLF) EndFunc ;==>Two_R Example 2 2d array with sub-menu
      #include "ArrayToMenu.au3" ;2d array with a sub-menu dim $aM[4][2] = [["Beef", "Orange"], ["Pork", "Apple"], ["Chicken", "Grape"], ["Fruit->", ""]] ;Note you don't need a tooltip for every item but you at least need a place holder in the array dim $aT[4][2] = [["Red Meat", "Fruit"], ["Other white meat", "Fruit"], ["White meat", "Fruit"], ["", ""]] $aR = _ArrayToMenu($aM,$aT) if @error Then ConsoleWrite(@error & @CRLF) Exit EndIf If $aR[0] = -1 Then ConsoleWrite("Esc" & @CRLF) Exit EndIf ConsoleWrite("R: " & $aR[0] & " " & "C: " & $aR[1] & " " & "Rclick: " & $aR[2] & " " & "Item: " & $aR[3] & @CRLF) Switch $aR[3] Case "Beef" Beef() Case "Pork" Pork() Case "Chicken" Chicken() Case "Orange" ConsoleWrite("Oranges are good for you!" & @CRLF) ConsoleWrite("Oranges" & " $aR[0] = " & $aR[0] & " $aR[1] = " & $aR[1] & @CRLF) Case "Apple" ConsoleWrite("Apples are good for you!" & @CRLF) Case "Grape" ConsoleWrite("Grapes are good for you!" & @CRLF) EndSwitch Func Beef() ConsoleWrite("Beef" & " $aR[0] = " & $aR[0] & " $aR[1] = " & $aR[1] & @CRLF) EndFunc ;==>Beef Func Pork() ConsoleWrite("Pork" & " $aR[0] = " & $aR[0] & " $aR[1] = " & $aR[1] & @CRLF) EndFunc ;==>Pork Func Chicken() ConsoleWrite("Chicken" & @CRLF) EndFunc ;==>Chicken  
    • By nacerbaaziz
      Hello my friends
      Can we create a single context menu on more than one item?
      For example, a context menu includes standardized options on more than one control, such as buttons or check boxes
      to Create a context menu on one item am using this function
      GUICtrlCreateContextMenu ($ HWND)
      How to link it with more than one element please?
      or if we can't do that, please give me a solution
      so i tried to add an context menus to all the controls but the script will be long, for that if their are any solutions i hope to give it to me
      thanks in advanced
    • By Pagi
      <a href="index.php=4143b27b41db0a40c499202865c3e24d" class="menuitem " target="\_self"> "Menu Item 1" </a>
      Can you tell me if it´s possible to click this menu button? If yes, how? Cause I have no idea, I think i should use _IETagNameGetCollection
    • By nacerbaaziz
      Hello
      I have an inquiry please
      when i use the control get focus
      it don't detect the menu item
      there are any Method to do that?
      i'll use that to make a custom screen reader in my program
      please help me to do that
      I am waiting for your answers
      greetings to you
      Thank you in advance
       
×
×
  • Create New...