How do you convert date dd/mm/yyyy

[Valnurat]

Hi experts.

I'm sorry if this has been explained before.

I have a list of dates. Some are like this: YYYY/MM/DD and that is ok. But then I have some like this: DD/MM/YYYY and that is not ok.

I want to go through the list in convert it to YYYY/MM/DD.

How do you convert DD/MM/YYYY to YYYY/MM/DD?

Edited March 17, 2017 by Valnurat

[rootx]

StringSplit

[Valnurat]

ok. Will look into it.

I have another thought.

If you have a mixed list of date like YYYY/MM/DD, DD/MM/YYYY and MM/YYYY/DD or any kind of mixed dates.

How do you convert it to YYYY/MM/DD?

[rootx]

mmm, 4the YYYY is easy with StringLen, but the limit is when MM <= 12 and DD <= 12... because you don't have a way to understand if is a MM or DD, the first 12 is the limit after 12 is DD because the MM limit is 12. At the moment I don't have any idea.

 

 

Edited March 17, 2017 by rootx

[FrancescoDiMuro]

@Valnurat
Something like this
 

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

Local $aDateTimes[3] = ["17/03/2017", "2017/03/17", "03/2017/17"]
Local $aDateTimesSplitted
For $i = 0 To UBound($aDateTimes) - 1
    $aDateTimesSplitted = StringSplit($aDateTimes[$i], "/", $STR_NOCOUNT)
    If($aDateTimesSplitted[0] > 12 And $aDateTimesSplitted[0] <= 31 And $aDateTimesSplitted[1] <= 12) Then ; DD/MM/YYYY
        MsgBox($MB_ICONINFORMATION, "Date format:", "Old date format: " & $aDateTimes[$i] & @CRLF & "New date format: " & $aDateTimesSplitted[2] & "/" & _
                                                                                                                          $aDateTimesSplitted[1] & "/" & _
                                                                                                                          $aDateTimesSplitted[0])
    ElseIf($aDateTimesSplitted[0] <= 12 And $aDateTimesSplitted[1] > 31) Then ; MM/YYYY/DD
        MsgBox($MB_ICONINFORMATION, "Date format:", "Old date format: " & $aDateTimes[$i] & @CRLF & "New date format: " & $aDateTimesSplitted[1] & "/" & _
                                                                                                                          $aDateTimesSplitted[0] & "/" & _
                                                                                                                          $aDateTimesSplitted[2])
    Else
        MsgBox($MB_ICONINFORMATION, "Date format:", "Date format: " & $aDateTimes[$i])
    EndIf
Next

Where you find $aDateTimes, you could find a function that read lines and then, paste the new line as I do in the MsgBox...
This is just an example...
Tell me if this script works correctly in your specific case
 

Edited March 17, 2017 by FrancescoDiMuro

[jchd]

Making that simpler:

Local $aDateTimes[3] = ["17/03/2017", "2017/03/17", "03/2017/17"]

For $i = 0 To UBound($aDateTimes) - 1
    $aDateTimes[$i] = StringRegExpReplace($aDateTimes[$i], "(\d\d)/(\d\d)/(\d\d\d\d)", "$3/$2/$1")  ; deals with DD/MM/YYYY
    $aDateTimes[$i] = StringRegExpReplace($aDateTimes[$i], "(\d\d)/(\d\d\d\d)/(\d\d)", "$2/$1/$3")  ; deals with MM/YYYY/DD
    ; there is NO way to deal with [unmanageable] US-style dates MM/DD/YYYY for DD < 13
Next
_ArrayDisplay($aDateTimes)

 

[mLipok]

Look also here:

https://www.autoitscript.com/wiki/User_Defined_Functions#Misc

 

[rootx]

A way that can be valid is to parameterize the position of the year in the position within it stringsplit

DD MM YYYY     YYYY MM DD      MM YYYY DD
["11/11/2017",  "2017/11/11",   "11/2017/11"]

postion YYYY[2] postion YYYY[0] postion YYYY[1]

firts target is find the 4char value in the result of StringSplit then isolate the YYYY

in the loop you can tell if the position YYYY = 2 ... then DD MM YYYY etc...

Edited March 17, 2017 by rootx