How to set the correct encoding for STDERR and STDOUT?

[g52]

Hi,

How to set the correct encoding for STDERR_CHILD and STDOUT_CHILD in this code? Output messages are not OK

Will anyone advise? Thank you.

Example()

Func Example()
    Local $iPID = Run(@ComSpec & " /c " & 'net start Apache' , "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
    Local $sOutput = ""
    While 1
        $sOutput = StdoutRead($iPID)
        If @error Then ; Exit the loop if the process closes or StdoutRead returns an error.
            ExitLoop
        EndIf
         MsgBox($MB_SYSTEMMODAL, "Stdout Read:", $sOutput)
    WEnd

    While 1
        $sOutput = StderrRead($iPID)
        If @error Then ; Exit the loop if the process closes or StderrRead returns an error.
            ExitLoop
        EndIf
        MsgBox($MB_SYSTEMMODAL, "Stderr Read:",  $sOutput)
    WEnd
EndFunc   ;==>Example

 

Edited April 27, 2017 by g52

[BrewManNH]

Try using the Binary mode of the StdErr/StdOutRead functions, then convert to text using BinaryToString using one of the Unicode format flags.

[kylomas]

g52,

Try concatenating the output stream to $sOutput.  I don't think you need the 2nd loop...

Kylomas

[Gianni]

@g52,  run directly the "net" command instead of with the @ComSpec in the middle,

Using @ComSpec you will bind the i/o streams of CMD while you will lose the control of "net" command that is fired by CMD but when started it runs away from your stream's control

try with something like this:

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sOutput = ""

    ; Local $iPID = Run(@ComSpec & " /c " & 'net start Apache' , "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
    Local $iPID = Run('net start Apache', "", @SW_HIDE, $STDERR_MERGED)

    Do
        $sOutput = StdoutRead($iPID)

        If $sOutput <> "" Then MsgBox($MB_SYSTEMMODAL, "Stdout Read:", $sOutput)

    Until @error ; Exit the loop if the process closes or StdoutRead returns an error.

EndFunc   ;==>Example

 

[kylomas]

Chimp,

The OP is over writing the output variable with every line streamed ($sOutput = StdoutRead($iPID)).  He/she probably wants "$sOutput &= stdoutread($IPID)". 

Quote

Using @ComSpec you will bind the i/o streams of CMD while you will lose the control of "net" command

This is a new one on me, if true, thanks for teaching me something!

kylomas

[g52]

Thank you very much for your help

I tried

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

Example()

Func Example()
          Local $sOutput = ""
          Local $iPID = Run('net start Apache', "", @SW_HIDE, $STDERR_MERGED)
          Do
                    $sOutput = StdoutRead($iPID, "", True)

                    If $sOutput <> "" Then
                              MsgBox($MB_SYSTEMMODAL, "Stdout Read:", BinaryToString($sOutput, $SB_UTF8))
                    EndIf
          Until @error ; Exit the loop if the process closes or StdoutRead returns an error.
EndFunc

The result is still not right :(

[Gianni]

@g52, can you try this script?, it should encode the stdoutread data in different ways to see if there is one correct encoding.

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sOutput = ""

    ; Local $iPID = Run(@ComSpec & " /c " & 'net start Apache' , "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
    Local $iPID = Run('net start Apache', "", @SW_HIDE, $STDERR_MERGED)

    Do
        $sOutput = StdoutRead($iPID, False, True) ; reads the data as binary instead of text

        If $sOutput <> "" Then MsgBox($MB_SYSTEMMODAL, "Stdout Read:", _
                "1 ANSI " & BinaryToString($sOutput, 1) & @CRLF & _
                "2 UTF16LE " & BinaryToString($sOutput, 2) & @CRLF & _
                "3 UTF16BE " & BinaryToString($sOutput, 3) & @CRLF & _
                "4 UTF8 " & BinaryToString($sOutput, 4))

    Until @error ; Exit the loop if the process closes or StdoutRead returns an error.

EndFunc   ;==>Example

 

[g52]

@Chimp

Yes, here is the result. I am sad from this

 

[Nikolas92]

_WinAPI_MultiByteToWideChar?

[g52]

I do not understand how to paste it into the code. Do you advise?