Include a function as an element in array

[VeryGut]

Hello,

I am a begginer when it comes down to scripting and programming. I have not been able to find a thread covering a problem i encountered, nor a working solution.

Is it possible to include a function, as an array element?

I imagine it working like this:

#include <MsgBoxConstants.au3>
#inlude <Array.au3>

Global $Array [5] = ["5", "4", _Function2(), "2", "1" ]

While 1
_Function1()
WEnd

Func _Function1()
For $i=1 to 5
MsgBox ($MB_OK, "", $Array[$i])
Next
EndFunc

Func _Function2()
MsgBox ($MB_OK, "", "Function was executed")
EndFunc

 

Thanks
 

 

 

[Melba23]

VeryGut,

Welcome to the AutoIt forums.

You can indeed use a function in an array - like this:

#include <MsgBoxConstants.au3>

HotKeySet("{ESC}", "_Exit")

Global $Array[5] = ["5", "4", _Function2, "2", "1"]

While 1
    _Function1()
WEnd

Func _Function1()
    For $i = 0 To 4
        MsgBox($MB_OK, "", ( (IsFunc($Array[$i])) ? ($Array[$i]()) : ($Array[$i]) ))
    Next
EndFunc   ;==>_Function1

Func _Function2()
    Return "Function was executed"
EndFunc   ;==>_Function2

Func _Exit()
    Exit
EndFunc

You need to check that the array element is a function and then add the trailing () to execute it.

Out of interest, why do you need to do this?

M23

[VeryGut]

Thanks for the help!

I needed it to automate filling my pdf forms from an excel source file - my script is very primitive (based on ctrl c + ctrl v method with controlclick/controlsend). The problem was that the clipboard was filling up rather quick and I needed to clear it every now and then to keep the script running.

Using an array inside for..next makes it much easier to make a compact script, rather than having to write a line after line of commands in my main function.

[junkew]

We should start a contest like http://www.ioccc.org/  for AutoIt

I agree its powerfull but when used a comment would be nice in your coding for some maintenance understanding in the future.

 

[kylomas]

VeryGut,

An alternate and more readable technique...

#include <MsgBoxConstants.au3>
#include <Array.au3>

; define 50 element array anf fill with sequential integers
Global $Array[50]
For $1 = 0 To UBound($Array) - 1
    $Array[$1] = $1
Next

_Function1()

Func _Function1()
    For $i = 0 To UBound($Array) - 1
        ConsoleWrite(StringFormat('$i = %02i\tmod value = %02i', $i, Mod($i, 10)) & @CRLF)
        ;every 10th entry run the cleanup routine
        If Mod($i, 10) = 0 And $i <> 0 Then _Function2()
    Next
EndFunc   ;==>_Function1

Func _Function2()
    ConsoleWrite('Ran cleanup' & @CRLF)
EndFunc   ;==>_Function2

kylomas

[VeryGut]

Thank you guys for the help. I was unable to get my sript working using the method described in replies. Fortunately i found a workaround, using some of the techniques. Below is my method:

#include <MsgBoxConstants.au3>
#include <Array.au3>

HotKeySet("{ESC}", "_Exit")

Global $Array[5] = ["5", "4", _Function2, "2", "1"]

While 1
    _Function1()
WEnd

Func _Function1 ()
   For $i=1 to 5
      $element = IsFunc($Array[$i])
      If $element = 0 Then
         MsgBox ($MB_OK, "", $Array[$i])
      Else
         Call($Array[$i])
      EndIf
   Next
EndFunc   ;==>_Function1

Func _Function2()
    MsgBox ($MB_OK, "", "Function was executed")
EndFunc

Func _Exit()
    Exit
EndFunc

 

Edited May 18, 2017 by VeryGut