Translate batch to AutoIt?

[HotPocky]

I use a batch file to toggle showing/hiding hidden files, folders, etc, and I have recently begun using AutoIt for more flexibility. The idea was to use a .lnk to keybind the process, but I read that getting a batch file to press F5 isn't exactly 'easy'. Currently I use AutoIt to run the batch file and then press F5 after a short period. I have an issue; I have gotten the compiled script to work via a .lnk with a keyboard shortcut, however the focus is on the CMD that pops up for a fraction of a second. My question is how do I express the commands in batch file in AutoIt?

show_hide_files.txt

[JLogan3o13]

@HotPocky welcome to the forum. You will find that batch files translate very easily to AutoIt, no need to run both. Below is the beginning of translating your batch file to an AutoIt script. The help file will help you easily create the If statement to RegWrite the appropriate values.

Local $sRegPath = "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced"
Local $sValue = "Hidden"
Local $iDate = 2

$sResult = RegRead($sRegPath, $sValue)

;look at regwrite in the help file

 

[orbs]

@HotPocky, you may find this useful:

you can see the registry implementation in there, as well as a function to refresh all Windows Explorer windows, instead of sending F5.

[Subz]

Another method:

Local $sRegPath = "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced"
Local $iRegValue = RegRead($sRegPath, "Hidden")
Switch $iRegValue
    Case 1
    ;~ Hidden = 1 - Show hidden files and folders
        RegWrite($sRegPath, "Hidden", "REG_DWORD", 2)
        RegWrite($sRegPath, "HideFileExt", "REG_DWORD", 1)
        RegWrite($sRegPath, "ShowSuperHidden", "REG_DWORD", 0)
    Case Else
    ;~ Hidden = 2 - Don't show hidden files and folders
        RegWrite($sRegPath, "Hidden", "REG_DWORD", 1)
        RegWrite($sRegPath, "HideFileExt", "REG_DWORD", 0)
        RegWrite($sRegPath, "ShowSuperHidden", "REG_DWORD", 1)
EndSwitch

 

[JLogan3o13]

And when you get a bit more comfortable with the language you can cut your script in half:

Local $sRegPath = "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced"
Local $iRegValue = RegRead($sRegPath, "Hidden")
    RegWrite($sRegPath, "Hidden", "REG_DWORD", (($iRegValue = 1) ? 2 : 1))
    RegWrite($sRegPath, "HideFileExt", "REG_DWORD", (($iRegValue = 1) ? 1 : 0))
    RegWrite($sRegPath, "ShowSuperHidden", "REG_DWORD", (($iRegValue = 1) ? 0 : 1))