[SOLVED]Remove specific combo value.

[pintas]

The combo content below are the files from a network folder.

I also have a button that moves the combo selected entry (file) to another place, and then i need to update the combo to remove that particular entry.

I've tried updating the combo values, and even deleting the combo and creating it again, but it picks up the same values as before, no matter what i do...

The entries (file names) are not always the same, so i can't know the index of the file in the combo to properly remove it. So _GUICtrlComboBox_DeleteString doesn't help.

Any ideas on how i can do this?

$Pasta = GUICtrlCreateCombo("Selecionar", 8, 16, 153, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
Global $arquivo = _FileListToArray('\\192.168.10.1\Dir\')
Func PopularPasta()
    For $i = 1 To UBound($arquivo) - 1
        GUICtrlSetData($Pasta, $arquivo[$i])
    Next
EndFunc

 

Edited June 12, 2017 by pintas

[Melba23]

pintas,

This simple example works for me:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3>

Global $aList[5] = [1, 2, 3, 4, 5]

$hGUI = GUICreate("Test", 500, 500)

$cCombo = GUICtrlCreateCombo("", 8, 16, 153, 25) ; The required styles are included by default

_FillCombo()

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo
            _ActionCombo(GUICtrlRead($cCombo))
    EndSwitch

WEnd

Func _ActionCombo($sChoice)

    ; Get index of choice in array
    $iIndex = _ArraySearch($aList, $sChoice)
    ; And delete it
    _ArrayDelete($aList, $iIndex)
    ; Refill combo
    _FillCombo()

    MsgBox($MB_SYSTEMMODAL, "Combo reloaded", "You selected " & $sChoice & @CRLF & " which has now been removed from the combo")

EndFunc

Func _FillCombo()

    $sData = ""
    For $i = 0 To UBound($aList) - 1
        $sData &= "|" & $aList[$i]
    Next
    GUICtrlSetData($cCombo, $sData)

EndFunc

Much easier to work with the original array rather than the combo.

M23

[pintas]

On 2017-6-11 at 4:32 AM, Melba23 said:

pintas,

This simple example works for me:

Much easier to work with the original array rather than the combo.

M23

Fantastic, Thank you.

However, if i replace the:

Global $aList[5] = [1, 2, 3, 4, 5]

with:

Global $aList = _FileListToArray('\\192.168.10.1\Dir\')

I get the item count in the first combo position.

I can use _ArrayDelete($aList, 0) and it will work the first time i run the gui, but after it deletes the selected combo value and refreshes, some items are missing from the combo. I'm not sure why this happens.

Edited June 12, 2017 by pintas
Nevermind. Got it working... :)