Resizeable Gui ($WS_SIZEBOX) not responding properly to WinMove()

[corgano]

If I create a window that has $WS_SIZEBOX style, I set up docking on the controls, and I click and drag it the controls stay inside the window correctly.

If I take the SAME window, and I use WinMove() to change it's size, none of the control sizes / positions update. How can I update my window after the WinMove() so autoit sees it changed size and repositions the controls?

SOLUTION: Put the winMove() AFTER you winSetState() to make the window visible!

Edited June 13, 2017 by corgano

[JLogan3o13]

@corgano almost 1000 posts you should know to provide your code, or a reproducer, rather than expect someone to guess at exactly what you're doing in your GUI and then troubleshoot for you. Help us help you.

[corgano]

I thought it'd be simple enough an example wasn't needed, here is the example from the help file, with the winmove added:

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Opt("GUICoordMode", 2)
    $gui = GUICreate("My InputBox", 190, 114, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; start the definition

    GUISetFont(8, -1, "Arial")

    GUICtrlCreateLabel("Prompt", 8, 7) ; add prompt info
    GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP)

    Local $idEdit = GUICtrlCreateInput("Default", -1, 3, 175, 20, $ES_PASSWORD) ; add the input area
    GUICtrlSetState($idEdit, $GUI_FOCUS)
    GUICtrlSetResizing($idEdit, $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)

    Local $idOK = GUICtrlCreateButton("OK", -1, 3, 75, 24) ; add the button that will close the GUI
    GUICtrlSetResizing($idOK, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

    Local $idCancel = GUICtrlCreateButton("Annuler", 25, -1) ; add the button that will close the GUI
    GUICtrlSetResizing($idCancel, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

    WinMove($gui, "", 100, 100, 400, 200)
    GUISetState(@SW_SHOW) ; to display the GUI

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
EndFunc   ;==>Example

However by accIdent, i found the solution:
Put winMove() AFTER the guiSetState()!!!!

Making that change magically makes it work! While you didn't provide a solution, I found the solution while making an example to show the problem so i could get help finding a solution, so...thanks?

Edited June 13, 2017 by corgano

[Melba23]

corgano,

This caught me  out a few years ago - apparently a fix to the code to get the $WS_EX_RTL style to work correctly meant that from 3.3.13.19 onwards, you need to use GUISetState before any WinMove commands or the autoresizing will not work. I was told at the time that the Help file would be modified to reflect this but I cannot find anything so I will look to add something myself.

M23