Jump to content
Rimoun

Button works for one time only then gives error

Recommended Posts

Hello everyone

I would like to have some help regarding my issue.

I am trying to extract some information from excel sheet, I use _Excel_RangeFind then I get the array for the value then I check the array. In case the array is true the next will be to get some information based on the extracted array if no array because the value is not found it gives a messages box that the value is not found.

My problem that the button works for one time only if i tried any value which exist in the sheet it gives me that value not found.

I suspect that there is a problem regarding While loop.

here is my code

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#Include <GuiListBox.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <Excel.au3>
#include <MsgBoxConstants.au3>
#include <ExcelConstants.au3>

if FileExists ("result.txt") Then
   Sleep (100)
Else
   readxl()
   EndIf


Global $oExcel = _Excel_Open(False,False)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeFind Example", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Global $oWorkbook = _Excel_BookOpen($oExcel, "D:\info.xlsx",False,False)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel Error", "Error opening workbook '" & $oWorkbook & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
 EndIf

Local $lab1 = _Excel_RangeRead($oWorkbook, Default,"B1")
Local $lab2 = _Excel_RangeRead($oWorkbook, Default,"C1")
Local $lab3 = _Excel_RangeRead($oWorkbook, Default,"D1")
Local $lab4 = _Excel_RangeRead($oWorkbook, Default,"E1")

Global $sResult1,$sResult2,$sResult3,$sResult4,$sResult5,$sResult6

Global $asKeyWords = stringsplit (FileRead (@ScriptDir & "\result.txt"),@CRLF)
Global Const $xlUp = -4162
;~ _Main()


    Local $hGUI, $hList, $hInput, $aSelected, $sChosen, $hUP, $hDOWN, $hENTER, $hESC
    Local $sCurrInput = "", $aCurrSelected[2] = [-1, -1], $iCurrIndex = -1, $hListGUI = -1

   $hGUI = GUICreate("Rimo System", 253, 270, 192, 124)
Global $hInput = GUICtrlCreateInput("", 24, 48, 169, 21)
Global $Label1 = GUICtrlCreateLabel("Rimo System", 80, 16, 150, 25)
GUICtrlSetFont(-1, 14, 800, 0, "MS Serif")
Global $Input2 = GUICtrlCreateInput("", 72, 144, 161, 21)
Global $Input3 = GUICtrlCreateInput("", 72, 176, 161, 21)
Global $Input4 = GUICtrlCreateInput("", 72, 208, 161, 21)
Global $Input5 = GUICtrlCreateInput("", 72, 240, 161, 21)
$Input6 = GUICtrlCreateInput("", 72, 272, 161, 21)
$Input7 = GUICtrlCreateInput("", 72, 304, 161, 21)
$Button1 = GUICtrlCreateButton("Get Info", 72, 88, 89, 33)
$Label2 = GUICtrlCreateLabel("Label2", 16, 144, 36, 17)
GUICtrlSetData( -1,$lab1)
$Label3 = GUICtrlCreateLabel("Label3", 16, 176, 36, 17)
GUICtrlSetData( -1,$lab2)
$Label4 = GUICtrlCreateLabel("Label4", 16, 208, 36, 17)
GUICtrlSetData( -1,$lab3)
$Label5 = GUICtrlCreateLabel("Label5", 16, 240, 36, 17)
GUICtrlSetData( -1,$lab4)
$Label6 = GUICtrlCreateLabel("", 16, 272, 36, 17)
$Label7 = GUICtrlCreateLabel("", 16, 304, 36, 17)
$Button2 = GUICtrlCreateButton("Cancel", 112, 416, 121, 25)

    GUISetState(@SW_SHOW, $hGUI)
Global $sSearch = guictrlread ($hInput)
    $hUP = GUICtrlCreateDummy()
    $hDOWN = GUICtrlCreateDummy()
    $hENTER = GUICtrlCreateDummy()
    $hESC = GUICtrlCreateDummy()
    Dim $AccelKeys[4][2] = [["{UP}", $hUP], ["{DOWN}", $hDOWN], ["{ENTER}", $hENTER], ["{ESC}", $hESC]]
    GUISetAccelerators($AccelKeys)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
             Case $Button2
                Exit
             Case $Button1

               Global $aResult = _Excel_RangeFind($oWorkbook, guictrlread($hInput) ,"A2:A2000")
               Global $aExtract = _ArrayExtract($aResult, 0, 0, 2, 2)


               if _elementExists($aExtract,0) Then
               getdata()
               Else

               MsgBox(0,"","Value Does Not Exist")
    


               EndIf

            Case $hESC
                If $hListGUI <> -1 Then ; List is visible.
                    GUIDelete($hListGUI)
                    $hListGUI = -1
                Else
                    ExitLoop
                EndIf

            Case $hUP
                If $hListGUI <> -1 Then ; List is visible.
                    $iCurrIndex -= 1
                    If $iCurrIndex < 0 Then
                        $iCurrIndex = 0
                    EndIf
                    _GUICtrlListBox_SetCurSel($hList, $iCurrIndex)
                EndIf

            Case $hDOWN
                If $hListGUI <> -1 Then ; List is visible.
                    $iCurrIndex += 1
                    If $iCurrIndex > _GUICtrlListBox_GetCount($hList) - 1 Then
                        $iCurrIndex = _GUICtrlListBox_GetCount($hList) - 1
                    EndIf
                    _GUICtrlListBox_SetCurSel($hList, $iCurrIndex)
                EndIf

            Case $hENTER
                If $hListGUI <> -1 And $iCurrIndex <> -1 Then ; List is visible and a item is selected.
                    $sChosen = _GUICtrlListBox_GetText($hList, $iCurrIndex)
                EndIf

            Case $hList
                $sChosen = GUICtrlRead($hList)
        EndSwitch

        Sleep(10)
        $aSelected = _GetSelectionPointers($hInput)
        If GUICtrlRead($hInput) <> $sCurrInput Or $aSelected[1] <> $aCurrSelected[1] Then ; Input content or pointer are changed.
            $sCurrInput = GUICtrlRead($hInput)
            $aCurrSelected = $aSelected ; Get pointers of the string to replace.
            $iCurrIndex = -1
            If $hListGUI <> -1 Then ; List is visible.
                GUIDelete($hListGUI)
                $hListGUI = -1
            EndIf
            $hList = _PopupSelector($hGUI, $hListGUI, _CheckInputText($sCurrInput, $aCurrSelected)) ; ByRef $hListGUI, $aCurrSelected.
        EndIf
        If $sChosen <> "" Then
            GUICtrlSendMsg($hInput, 0x00B1, $aCurrSelected[0], $aCurrSelected[1]) ; $EM_SETSEL.
            _InsertText($hInput, $sChosen)
            $sCurrInput = GUICtrlRead($hInput)
            GUIDelete($hListGUI)
            $hListGUI = -1
            $sChosen = ""
        EndIf
    WEnd
    GUIDelete($hGUI)


Func _CheckInputText($sCurrInput, ByRef $aSelected)
    Local $sPartialData = ""
    If (IsArray($aSelected)) And ($aSelected[0] <= $aSelected[1]) Then
        Local $aSplit = StringSplit(StringLeft($sCurrInput, $aSelected[0]), " ")
        $aSelected[0] -= StringLen($aSplit[$aSplit[0]])
        If $aSplit[$aSplit[0]] <> "" Then
            For $A = 1 To $asKeyWords[0]
                If StringLeft($asKeyWords[$A], StringLen($aSplit[$aSplit[0]])) = $aSplit[$aSplit[0]] And $asKeyWords[$A] <> $aSplit[$aSplit[0]] Then
                    $sPartialData &= $asKeyWords[$A] & "|"
                EndIf
            Next
        EndIf
    EndIf
    Return $sPartialData
EndFunc   ;==>_CheckInputText

Func _PopupSelector($hMainGUI, ByRef $hListGUI, $sCurr_List)
    Local $hList = -1
    If $sCurr_List = "" Then
        Return $hList
    EndIf
    $hListGUI = GUICreate("", 280, 160, 23, 62, $WS_POPUP, BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $WS_EX_MDICHILD), $hMainGUI)
    $hList = GUICtrlCreateList("", 0, 0, 170, 150, BitOR(0x00100000, 0x00200000))
    GUICtrlSetData($hList, $sCurr_List)
    GUISetControlsVisible($hListGUI) ; To Make Control Visible And Window Invisible.
    GUISetState(@SW_SHOWNOACTIVATE, $hListGUI)
    Return $hList
EndFunc   ;==>_PopupSelector

Func _InsertText(ByRef $hEdit, $sString)
    #cs
        Description: Insert A Text In A Control.
        Returns: Nothing
    #ce
    Local $aSelected = _GetSelectionPointers($hEdit)
    GUICtrlSetData($hEdit, StringLeft(GUICtrlRead($hEdit), $aSelected[0]) & $sString & StringTrimLeft(GUICtrlRead($hEdit), $aSelected[1]))
    Local $iCursorPlace = StringLen(StringLeft(GUICtrlRead($hEdit), $aSelected[0]) & $sString)
    GUICtrlSendMsg($hEdit, 0x00B1, $iCursorPlace, $iCursorPlace) ; $EM_SETSEL.
EndFunc   ;==>_InsertText

Func _GetSelectionPointers($hEdit)
    Local $aReturn[2] = [0, 0]
    Local $aSelected = GUICtrlRecvMsg($hEdit, 0x00B0) ; $EM_GETSEL.
    If IsArray($aSelected) Then
        $aReturn[0] = $aSelected[0]
        $aReturn[1] = $aSelected[1]
    EndIf
    Return $aReturn
EndFunc   ;==>_GetSelectionPointers

Func GUISetControlsVisible($hWnd) ; By Melba23.
    Local $aControlGetPos = 0, $hCreateRect = 0, $hRectRgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    Local $iLastControlID = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle(-1))
    For $i = 3 To $iLastControlID
        $aControlGetPos = ControlGetPos($hWnd, '', $i)
        If IsArray($aControlGetPos) = 0 Then ContinueLoop
        $hCreateRect = _WinAPI_CreateRectRgn($aControlGetPos[0], $aControlGetPos[1], $aControlGetPos[0] + $aControlGetPos[2], $aControlGetPos[1] + $aControlGetPos[3])
        _WinAPI_CombineRgn($hRectRgn, $hCreateRect, $hRectRgn, 2)
        _WinAPI_DeleteObject($hCreateRect)
    Next
    _WinAPI_SetWindowRgn($hWnd, $hRectRgn, True)
    _WinAPI_DeleteObject($hRectRgn)
 EndFunc


 Func _elementExists($array, $element)
    If $element > UBound($array)-1 Then Return False ; element is out of the array bounds
    Return True ; element is in array bounds
 EndFunc

 Func getdata()





;~ Local
$sResult1 = _Excel_RangeRead($oWorkbook, Default,StringReplace(StringReplace ($aExtract[0],"$",""),"A","B"))
;~ Local
$sResult2 = _Excel_RangeRead($oWorkbook, Default,StringReplace(StringReplace ($aExtract[0],"$",""),"A","C"))
;~ Local
$sResult3 = _Excel_RangeRead($oWorkbook, Default,StringReplace(StringReplace ($aExtract[0],"$",""),"A","D"))
;~ Local
$sResult4 = _Excel_RangeRead($oWorkbook, Default,StringReplace(StringReplace ($aExtract[0],"$",""),"A","E"))
;~ Local
$sResult5 = _Excel_RangeRead($oWorkbook, Default,StringReplace(StringReplace ($aExtract[0],"$",""),"A","F"))
;~ Local
$sResult6 = _Excel_RangeRead($oWorkbook, Default,StringReplace(StringReplace ($aExtract[0],"$",""),"A","G"))


guictrlsetdata($Input2,$sResult1)
guictrlsetdata($Input3,$sResult2)
guictrlsetdata($Input4,$sResult3)
guictrlsetdata($Input5,$sResult4)
guictrlsetdata($Input6,$sResult5)
guictrlsetdata($Input7,$sResult6)

_Excel_Close($oExcel,Default,True)



EndFunc


Func readxl()
   Global $oExcel = _Excel_Open(False,False)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeFind Example", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Global $oWorkbook = _Excel_BookOpen($oExcel, "D:\info.xlsx",False,False)

LOcal Const $xlUp = -4162
With $oWorkbook.ActiveSheet ; process active sheet
    $oRangeLast = .UsedRange.SpecialCells($xlCellTypeLastCell) ; get a Range that contains the last used cells
    $iRowCount = .Range(.Cells(1, 1), .Cells($oRangeLast.Row, $oRangeLast.Column)).Rows.Count ; get the the row count for the range starting in row/column 1 and ending at the last used row/column
    $iLastCell = .Cells($iRowCount + 1, "B").End($xlUp).Row
    ProgressOn("Copying Cells", "Copying Cells progress", "0%")

For $i = 2 to $iLastCell
  Local $total = Int(($i/$iLastCell)*100)
    Local $sResult3 = _Excel_RangeRead($oWorkbook, Default, "A" & $i)
    FileWriteLine("result.txt",$sResult3)
    ProgressSet(($i/$iLastCell)*100, $total & "%")

Next
;~  FileWrite("result.txt",$sResult3)
 ProgressSet(100, "Done", "Complete")
 Sleep (1500)
ProgressOff()

   _Excel_Close($oExcel,Default,True)

   EndWith
EndFunc

 

Share this post


Link to post
Share on other sites

Do you have an excel sheet to try this with?, make sure there is no personal\private info inside.

Some suggestions about the code. Don't declare Globals in functions, or locals in loops. A lot of the variable have already been declared and you are declaring the again with the same values.

Share this post


Link to post
Share on other sites

Can you post an excel sheet so I can try it with your code?.  It's hard to try and pinpoint a reason for your button issue

Share this post


Link to post
Share on other sites
19 minutes ago, Danp2 said:

Why are you closing Excel at the bottom of the getdata function?

I think it's just that the code needs tidying and reorganizing. There are a few improvements that could be made.

Share this post


Link to post
Share on other sites

I agree. I would expect the button to show the "Value Does Not Exist" message on the attempts due to unchecked errors from the _Excel_RangeFind and\or _ArrayExtract functions.

@Rimoun Try Danp2's suggestion and comment out the line below just as a test. If the button works multiple times then that's the issue and it needs to be moved somewhere else

_Excel_Close($oExcel, Default, True)

 

Edited by benners

Share this post


Link to post
Share on other sites
19 minutes ago, benners said:

I agree. I would expect the button to show the "Value Does Not Exist" message on the attempts due to unchecked errors from the _Excel_RangeFind and\or _ArrayExtract functions.

@Rimoun Try Danp2's suggestion and comment out the line below just as a test. If the button works multiple times then that's the issue and it needs to be moved somewhere else

_Excel_Close($oExcel, Default, True)

 

Thanks Guys for help, that solved my issue 

Sorry for the messy way the I wrote the code with it.

attached the sample file that I used with the script.

I appreciate your valuable assistance.

Thanks

info.xlsx

Share this post


Link to post
Share on other sites

No need to apologize, most of us have been there. When I see others code, it sometimes feels like I still am there. Now I can test my changes, I'll have a look and post back.

Share this post


Link to post
Share on other sites

Well, after the initial loading, when I selected 1001 from the list and pressed Get Info button, I got an error from the excel udf. As I understand it, the basic operation is to read the information from the sheet, load the Staff# into the listbox, when the Staff# is selected, pressing Get Info should get the related info, Name. Dept, Joining and Id and input them into the inputs. Is this correct?

The other labels that are created but not visible because the GUI is to small, they are the text of the excel columns, like Id etc?.

Share this post


Link to post
Share on other sites
37 minutes ago, benners said:

Well, after the initial loading, when I selected 1001 from the list and pressed Get Info button, I got an error from the excel udf. As I understand it, the basic operation is to read the information from the sheet, load the Staff# into the listbox, when the Staff# is selected, pressing Get Info should get the related info, Name. Dept, Joining and Id and input them into the inputs. Is this correct?

The other labels that are created but not visible because the GUI is to small, they are the text of the excel columns, like Id etc?.

Yes everything exactly as u said. the script will work if u replaced the excel udf as the old has a problem, there is a post was talking about that, in case u didnt find i can shRe my amended excel udf, the problem in rangefind function, just

Share this post


Link to post
Share on other sites

That's Ok, thanks for the info, I'll have a search. It is easier to read all the sheet in one go into an array then use the array from there on, so that's how I'll work it.

Share this post


Link to post
Share on other sites

Well try this. I have commented a lot of things but if there's anything you don't know then just post. The AutoIt Wiki is a good place to pick up info and there's a thread on Best Practices here that's worth a read. I picked up a lot from both.

I changed the top input for a combo box, 

I kept your other  inputs for the info but they would be better as labels. I have included one as an example but commented it out. The inputs text can be deleted. It has no effect on the program but a bit more professional :) 

#Region #### Includes ################################
#include <Array.au3>
#include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <Excel.au3>
#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>
;~ #include <StaticConstants.au3> ; only needed for label example
#include <WindowsConstants.au3>
#EndRegion #### Includes ################################

#Region #### Globals #################################
; these relate to the columns that contain the information,
; they relate to the ARRAY columns layout NOT the EXCEL sheet columns. Enum will
; assign them a value starting at 0 and incrementing by one. If you add or change the column
; layout in the excel sheet, these will need to be altered
Global Enum _
        $STAFFNUMBER_COL, _ ; 0
        $NAME_COL, _ ; 1
        $DEPT_COL, _ ; 2
        $JOINING_COL, _ ; 3
        $ID_COL, _ ; 4
        $MAX_COLS ; 5, or 1 above the last column

; these relate to the controls on the GUI. Only the ones
; we need to update that would be Global are in here
; ### THESE MUST HAVE THE SAME VALUE AS THEIR COLUMN COUNTERPARTS ###
Global Enum _
        $STAFFNUMBER_CBO, _ ; 0
        $NAME_INP, _ ; 1
        $DEPT_INP, _ ; 2
        $JOINING_INP, _ ; 3
        $ID_INP, _ ; 4
        $MAX_IDS ; 5, or 1 above the last control

; create an array to hold the id's for the controls
; scope is global so it can be accessed by all. We
; loop through this array later when updating the inputs
; with the array values
Global $g_aiControlIDs[$MAX_IDS]

; declare a variable to hold the RangeRead return
; scope is global so it can be accessed by all
Global $g_asStaffInfo = ''
#EndRegion #### Globals #################################

; read the full sheet to the array
ReadSheetToArray($g_asStaffInfo)
;~ _ArrayDisplay($g_asStaffInfo)

; draw the GUI
GUI_Draw()

Func GUI_Draw()
    GUICreate("Rimo System", 270, 500, -1, -1)

    ; no need to assign the controlID to a variable as
    ; it's text is constant
    GUICtrlCreateLabel("Rimo System", 80, 16, 150, 25)
    GUICtrlSetFont(-1, 14, 800, 0, "MS Serif")

    ; $STAFFNUMBER_CBO
    $g_aiControlIDs[$STAFFNUMBER_CBO] = GUICtrlCreateCombo("", 50, 48, 169, 21, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL, $WS_VSCROLL))
    GUICtrlSetData(-1, LoadStaffNumberCombo())

    ; declare as Local because it's not used outside of this function
    Local $id_GetInfo_btn = GUICtrlCreateButton("Get Info", 85, 88, 89, 33)

    ; $NAME_INP - Gets the text from the array and corresponding column
    GUICtrlCreateLabel($g_asStaffInfo[0][$NAME_COL], 16, 147, 36, 17)
    $g_aiControlIDs[$NAME_INP] = GUICtrlCreateInput("", 72, 144, 161, 21)

    ; label example
;~  $g_aiControlIDs[$NAME_INP] = GUICtrlCreateLabel("", 72, 144, 161, 21, $SS_CENTERIMAGE, $WS_EX_STATICEDGE)
;~  GUICtrlSetBkColor(-1, 0xFFFFFF)

    ; $DEPT_INP - Gets the text from the array and corresponding column
    GUICtrlCreateLabel($g_asStaffInfo[0][$DEPT_COL], 16, 177, 36, 17)
    $g_aiControlIDs[$DEPT_INP] = GUICtrlCreateInput("", 72, 176, 161, 21)

    ; $JOINING_INP - Gets the text from the array and corresponding column
    GUICtrlCreateLabel($g_asStaffInfo[0][$JOINING_COL], 16, 211, 36, 17)
    $g_aiControlIDs[$JOINING_INP] = GUICtrlCreateInput("", 72, 208, 161, 21)

    ; $ID_INP - Gets the text from the array and corresponding column
    GUICtrlCreateLabel($g_asStaffInfo[0][$ID_COL], 16, 243, 36, 17)
    $g_aiControlIDs[$ID_INP] = GUICtrlCreateInput("", 72, 240, 161, 21)

    ; unknown1 - These two will need to be added when you expand the spreadsheet
    ; you will need to create them in the same way as the others above
;~  GUICtrlCreateLabel("", 16, 272, 36, 17)
;~  Global $id_unknown2_inp = GUICtrlCreateInput("", 72, 272, 161, 21)

    ; unknown2
;~  GUICtrlCreateLabel("", 16, 304, 36, 17)
;~  Global $id_unknown2_inp = GUICtrlCreateInput("", 72, 304, 161, 21)

    ; declare as Local because it's not used outside of this function
    Local $id_Cancel_btn = GUICtrlCreateButton("Cancel", 75, 416, 121, 25)

    ; show the gui
    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $id_Cancel_btn
                ExitLoop
            Case $id_GetInfo_btn
                LoadStaffInfoInputs() ; retreive the info from the array
        EndSwitch
    WEnd

    GUIDelete()
EndFunc   ;==>GUI_Draw

Func LoadStaffNumberCombo()
    ; set a starting string
    Local $s_Input = '|'

    ; loop through the Staff# column of the array
    For $i = 1 To UBound($g_asStaffInfo) - 1
        ; add the values from the rows ($i)
        $s_Input &= '|' & $g_asStaffInfo[$i][$STAFFNUMBER_COL]
    Next

    ; trim the first pipe symbol
    Return StringTrimLeft($s_Input, 1)
EndFunc   ;==>LoadStaffNumberCombo

Func LoadStaffInfoInputs()
    ; get the index of the currently selected item in the combo
    Local $i_ComboIndex = _GUICtrlComboBox_GetCurSel($g_aiControlIDs[$STAFFNUMBER_CBO])
    If $i_ComboIndex = -1 Then Return ; nothing selected

    ; _GUICtrlComboBox_GetCurSel returns a zero based index so
    ; we need to increase by one to tally with $g_asStaffInfo rows
    $i_ComboIndex += 1

    ; loop through the inputs and add the values. If the number of columns in the excel
    ; sheet increases and the number of inputs increases, as long as they are added to the global
    ; enums at the top of the script in the correct order, this should not need adjusting
    For $i = $NAME_COL To $MAX_COLS - 1
        GUICtrlSetData($g_aiControlIDs[$i], $g_asStaffInfo[$i_ComboIndex][$i])
    Next
EndFunc   ;==>LoadStaffInfoInputs

Func ReadSheetToArray(ByRef $as_RangeRead)
    Local $s_ErrorMsg = "Error creating the Excel application object"

    ; create an instance of excel. Declare as local scope
    ; as it is only needed in this function
    Local $o_Excel = _Excel_Open(False)

    If Not @error Then
        $s_ErrorMsg = "Error opening workbook"

        ; open the workbook. Scope as above
        Local $o_WorkBook = _Excel_BookOpen($o_Excel, 'D:\info.xlsx', False, False)

        If Not @error Then
            $s_ErrorMsg = "Error reading excel range"
            $as_RangeRead = _Excel_RangeRead($o_WorkBook)
        EndIf
    EndIf

    If @error Then Exit MsgBox($MB_SYSTEMMODAL, _
            "Excel Error", _
            $s_ErrorMsg & $o_WorkBook & @CRLF & _
            "@error = " & @error & ", @extended = " & @extended)

    ; we're are finished with excel now as all the info
    ; is in the array so it can be closed
    _Excel_Close($o_Excel)
EndFunc   ;==>ReadSheetToArray

 

Share this post


Link to post
Share on other sites
12 hours ago, benners said:

Well try this. I have commented a lot of things but if there's anything you don't know then just post. The AutoIt Wiki is a good place to pick up info and there's a thread on Best Practices here that's worth a read. I picked up a lot from both.

I changed the top input for a combo box, 

I kept your other  inputs for the info but they would be better as labels. I have included one as an example but commented it out. The inputs text can be deleted. It has no effect on the program but a bit more professional :) 

#Region #### Includes ################################
#include <Array.au3>
#include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <Excel.au3>
#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>
;~ #include <StaticConstants.au3> ; only needed for label example
#include <WindowsConstants.au3>
#EndRegion #### Includes ################################

#Region #### Globals #################################
; these relate to the columns that contain the information,
; they relate to the ARRAY columns layout NOT the EXCEL sheet columns. Enum will
; assign them a value starting at 0 and incrementing by one. If you add or change the column
; layout in the excel sheet, these will need to be altered
Global Enum _
        $STAFFNUMBER_COL, _ ; 0
        $NAME_COL, _ ; 1
        $DEPT_COL, _ ; 2
        $JOINING_COL, _ ; 3
        $ID_COL, _ ; 4
        $MAX_COLS ; 5, or 1 above the last column

; these relate to the controls on the GUI. Only the ones
; we need to update that would be Global are in here
; ### THESE MUST HAVE THE SAME VALUE AS THEIR COLUMN COUNTERPARTS ###
Global Enum _
        $STAFFNUMBER_CBO, _ ; 0
        $NAME_INP, _ ; 1
        $DEPT_INP, _ ; 2
        $JOINING_INP, _ ; 3
        $ID_INP, _ ; 4
        $MAX_IDS ; 5, or 1 above the last control

; create an array to hold the id's for the controls
; scope is global so it can be accessed by all. We
; loop through this array later when updating the inputs
; with the array values
Global $g_aiControlIDs[$MAX_IDS]

; declare a variable to hold the RangeRead return
; scope is global so it can be accessed by all
Global $g_asStaffInfo = ''
#EndRegion #### Globals #################################

; read the full sheet to the array
ReadSheetToArray($g_asStaffInfo)
;~ _ArrayDisplay($g_asStaffInfo)

; draw the GUI
GUI_Draw()

Func GUI_Draw()
    GUICreate("Rimo System", 270, 500, -1, -1)

    ; no need to assign the controlID to a variable as
    ; it's text is constant
    GUICtrlCreateLabel("Rimo System", 80, 16, 150, 25)
    GUICtrlSetFont(-1, 14, 800, 0, "MS Serif")

    ; $STAFFNUMBER_CBO
    $g_aiControlIDs[$STAFFNUMBER_CBO] = GUICtrlCreateCombo("", 50, 48, 169, 21, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL, $WS_VSCROLL))
    GUICtrlSetData(-1, LoadStaffNumberCombo())

    ; declare as Local because it's not used outside of this function
    Local $id_GetInfo_btn = GUICtrlCreateButton("Get Info", 85, 88, 89, 33)

    ; $NAME_INP - Gets the text from the array and corresponding column
    GUICtrlCreateLabel($g_asStaffInfo[0][$NAME_COL], 16, 147, 36, 17)
    $g_aiControlIDs[$NAME_INP] = GUICtrlCreateInput("", 72, 144, 161, 21)

    ; label example
;~  $g_aiControlIDs[$NAME_INP] = GUICtrlCreateLabel("", 72, 144, 161, 21, $SS_CENTERIMAGE, $WS_EX_STATICEDGE)
;~  GUICtrlSetBkColor(-1, 0xFFFFFF)

    ; $DEPT_INP - Gets the text from the array and corresponding column
    GUICtrlCreateLabel($g_asStaffInfo[0][$DEPT_COL], 16, 177, 36, 17)
    $g_aiControlIDs[$DEPT_INP] = GUICtrlCreateInput("", 72, 176, 161, 21)

    ; $JOINING_INP - Gets the text from the array and corresponding column
    GUICtrlCreateLabel($g_asStaffInfo[0][$JOINING_COL], 16, 211, 36, 17)
    $g_aiControlIDs[$JOINING_INP] = GUICtrlCreateInput("", 72, 208, 161, 21)

    ; $ID_INP - Gets the text from the array and corresponding column
    GUICtrlCreateLabel($g_asStaffInfo[0][$ID_COL], 16, 243, 36, 17)
    $g_aiControlIDs[$ID_INP] = GUICtrlCreateInput("", 72, 240, 161, 21)

    ; unknown1 - These two will need to be added when you expand the spreadsheet
    ; you will need to create them in the same way as the others above
;~  GUICtrlCreateLabel("", 16, 272, 36, 17)
;~  Global $id_unknown2_inp = GUICtrlCreateInput("", 72, 272, 161, 21)

    ; unknown2
;~  GUICtrlCreateLabel("", 16, 304, 36, 17)
;~  Global $id_unknown2_inp = GUICtrlCreateInput("", 72, 304, 161, 21)

    ; declare as Local because it's not used outside of this function
    Local $id_Cancel_btn = GUICtrlCreateButton("Cancel", 75, 416, 121, 25)

    ; show the gui
    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $id_Cancel_btn
                ExitLoop
            Case $id_GetInfo_btn
                LoadStaffInfoInputs() ; retreive the info from the array
        EndSwitch
    WEnd

    GUIDelete()
EndFunc   ;==>GUI_Draw

Func LoadStaffNumberCombo()
    ; set a starting string
    Local $s_Input = '|'

    ; loop through the Staff# column of the array
    For $i = 1 To UBound($g_asStaffInfo) - 1
        ; add the values from the rows ($i)
        $s_Input &= '|' & $g_asStaffInfo[$i][$STAFFNUMBER_COL]
    Next

    ; trim the first pipe symbol
    Return StringTrimLeft($s_Input, 1)
EndFunc   ;==>LoadStaffNumberCombo

Func LoadStaffInfoInputs()
    ; get the index of the currently selected item in the combo
    Local $i_ComboIndex = _GUICtrlComboBox_GetCurSel($g_aiControlIDs[$STAFFNUMBER_CBO])
    If $i_ComboIndex = -1 Then Return ; nothing selected

    ; _GUICtrlComboBox_GetCurSel returns a zero based index so
    ; we need to increase by one to tally with $g_asStaffInfo rows
    $i_ComboIndex += 1

    ; loop through the inputs and add the values. If the number of columns in the excel
    ; sheet increases and the number of inputs increases, as long as they are added to the global
    ; enums at the top of the script in the correct order, this should not need adjusting
    For $i = $NAME_COL To $MAX_COLS - 1
        GUICtrlSetData($g_aiControlIDs[$i], $g_asStaffInfo[$i_ComboIndex][$i])
    Next
EndFunc   ;==>LoadStaffInfoInputs

Func ReadSheetToArray(ByRef $as_RangeRead)
    Local $s_ErrorMsg = "Error creating the Excel application object"

    ; create an instance of excel. Declare as local scope
    ; as it is only needed in this function
    Local $o_Excel = _Excel_Open(False)

    If Not @error Then
        $s_ErrorMsg = "Error opening workbook"

        ; open the workbook. Scope as above
        Local $o_WorkBook = _Excel_BookOpen($o_Excel, 'D:\info.xlsx', False, False)

        If Not @error Then
            $s_ErrorMsg = "Error reading excel range"
            $as_RangeRead = _Excel_RangeRead($o_WorkBook)
        EndIf
    EndIf

    If @error Then Exit MsgBox($MB_SYSTEMMODAL, _
            "Excel Error", _
            $s_ErrorMsg & $o_WorkBook & @CRLF & _
            "@error = " & @error & ", @extended = " & @extended)

    ; we're are finished with excel now as all the info
    ; is in the array so it can be closed
    _Excel_Close($o_Excel)
EndFunc   ;==>ReadSheetToArray

 

This sounds very advanced for me. You used only just 10% from the size of my code to do the same. I will study it very well once I am at home, and I am pretty sure that this code will have a great developmental impact on me.

Thanks for your great help to rewrite my code in a readable & easy way.

Thanks a million.

Share this post


Link to post
Share on other sites

It only looks that way at first :). A lot of your code seemed to be to make the input box act like a combo box with accelerator keys to control it.  I replaced it with a combo box, you can scroll through it with the mouse or arrow keys and it expands to show a list. I hope it functions the way you want compared with the first input box.

Everyone has there own preferences on layout, so as long as your code is easily readable, is easy to maintain (even after it's not fresh in your mind) and understandable (more likely to get help here) your half way there.

If you do add extra inputs like the unknown input parts, you can add them to the controls array. The declarations below are only there to show you the scope each control needs to be declared in. Don't declare the Globals inside the function, If that makes sense :blink: Good luck

;~  GUICtrlCreateLabel("", 16, 272, 36, 17)
;~  Global $id_unknown1_inp = GUICtrlCreateInput("", 72, 272, 161, 21)

    ; unknown2
;~  GUICtrlCreateLabel("", 16, 304, 36, 17)
;~  Global $id_unknown2_inp = GUICtrlCreateInput("", 72, 304, 161, 21)

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • By Taxyo
      Hi,
       
      I've been trying to automate modification of an excel file and the last thing I am stuck on is deleting all the rows where the value of Column 13 is 0. 
      I believe the error is due to me not fully understanding the syntax so this is where I'm stuck: 
       
      Func Hotkey2() Global $aUsedRange = _Excel_RangeRead($oWorkbook, 1) _ArrayDisplay($aUsedRange) For $iRow = UBound($aUsedRange) - 1 to 3 Step -1 If $aUsedRange[$iRow][13] = 0 Then _Excel_RangeDelete($oWorkbook.Worksheets(1), $aUsedRange[$iRow] & ":" & $aUsedRange[$iRow], default, 1) If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeDelete Example 2", "Error deleting rows." & @CRLF & "@error = " & @error & ", @extended = " & @extended) EndIf Next EndFunc  
      While my script properly locates the row which contains value 0 in Column 13, I am not sure how to set it to the corresponding row in the excel workbook?  My above experiment gives me $vRange error and I've been toying around with it to no avail. The only way I get the Script to delete a row is by actually specifying "4:4" or "6:8" etc. 
      Where am I going wrong?
       
      Thanks! 
    • By Most
      #include <Array.au3> #include <Excel.au3> #include <MsgBoxConstants.au3> ; Create application object and open an example workbook Local $oExcel = _Excel_Open() If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeRead Example", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended) Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\trans.xlsx") If @error Then MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeRead Example", "Error opening workbook '" & @ScriptDir & "\trans.xlsx'." & @CRLF & "@error = " & @error & ", @extended = " & @extended) _Excel_Close($oExcel) Exit EndIf ; ***************************************************************************** ; Read data from a single cell on the active sheet of the specified workbook ; ***************************************************************************** Local $sResult = _Excel_RangeRead($oWorkbook, Default, "A1") If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeRead Example 1", "Error reading from workbook." & @CRLF & "@error = " & @error & ", @extended = " & @extended) MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_RangeRead Example 1", "Data successfully read." & @CRLF & "Value of cell A1: " & $sResult) Hi, all.
      Ok, here is the deal. I have simple excel file called trans.xlsx. It's located in the directory of script. In general i don't care where to store it. 
      What i do need is to open excel file and copy one by one numbers from cells. I've tried different ways, examples. But i only get error, says: error = 3, extended = 1. I saw different posts from different years. I even tried to use simple example from manual file. But always get error.

      In general my goal get numbers one by one and post it to let's say search filed in my PC one by one. Or to notepad (but one by one, in kind of loop). 
      I've learned how to copy or show in message box some info from other apps. But with excel i'm stuck. 

      I'm able to open needed window based on "title" of excel. But i don't succeed of copying info from cells. 

      Would be appreciate for any help. 
      So, in this code i'm trying at least to read from cell A1. Doesn't matter what Sheet. 

      I use Windows 10, Excel for Office 365. 
      Thank you in advance. 
    • By sksbir
      Hi
      Trying this from autoit v3.3.14.5 and SCITE 3.19.102.1901.0 :
      help file , page "Language Reference - Variables" , sample autoit script about maps:

      Maps must be declared before use by defining their scope using the 'Global/Local/Static' keywords. Local $mControls[]
      So is my test script : only with this local declation.
      -check syntax is OK
      - running script : 

      test.au3" (13) : ==> Variable subscript badly formatted.: Local $mControls[] Local $mControls[^ ERROR ->14:51:49 AutoIt3.exe ended.rc:1
      any clue ?
    • By Blitzkid
      Hello, i want to search several directories for files with the largest numbers behind them (Like "video123") . They dont have a datatype. But there are also files with longer names and datatypes in these folders (Like "video778.mp4"). Is it possible to filter the _FileListToArray Syntax from
      to smth. like
       
      Here is my Code
      #include <ButtonConstants.au3> #include <GUIConstantsEx.au3> #include <WindowsConstants.au3> #include <array.au3> #include <File.au3> $filedir = @ScriptDir & "\" _checkfile() Func _checkfile() ConsoleWrite("______________________" & @CRLF) Local $arr[3] = ["music", "picture", "video"] For $i = 0 To UBound($arr) - 1 Local $arrayfiles = _FileListToArray($filedir & $arr[$i], $arr[$i] & "*", 1) If @error = 1 Then ConsoleWrite($arr[$i] & "Error 1") EndIf If @error = 4 Then ConsoleWrite($arr[$i] & "Error 2") ;Exit EndIf $arrayfilter = _ArrayMax($arrayfiles, 0, 1) Global $stringfiles = StringReplace($arrayfilter, $arr[$i], "") ConsoleWrite($arrayfilter & @CRLF) Next EndFunc ;==>_checkfile  
    • By VinMe
      Dear all, i am unable to open a xml file to excel in the "xml table format" Please help me out in where i am missing
      Local $strFileToOpen = _WinAPI_OpenFileDlg('Select xml file', @WorkingDir, 'All Files(*.*)', 1, '', '', BitOR($OFN_PATHMUSTEXIST, $OFN_FILEMUSTEXIST, $OFN_HIDEREADONLY)) Global $xlXmlLoadImportToList = 2 ; Places the contents of the XML data file in an XML table $oExcel = _Excel_Open() $oWorkbook1=$oExcel.Workbooks.OpenXML($strFileToOpen, "", $xlXmlLoadImportToList) If $strFileToOpen <> False Then     Local $oWorkbook1 = _Excel_BookOpen($oExcel, $strFileToOpen) EndIf Error i am getting is:
      ......\81e_Compare_v1.au3" (46) : ==> The requested action with this object has failed.:
      $oWorkbook1=$oExcel.Workbooks.OpenXML($strFileToOpen, "", $xlXmlLoadImportToList)
      $oWorkbook1=$oExcel.Workbooks^ ERROR
      >Exit code: 1    Time: 7.338
×
×
  • Create New...