GUI question - call function when I click a button

[dragancla]

Hey guys,

 

I'm trying to create some sort of download speed test in AutoIT, but I'm at a loss on how to call a function ONLY when I press a certain button. My script looks something like this:

 

$SpeedTestButton = GUICtrlCreateButton("Test Download Speed", 10,50,120,35)
$SpeedTestLabel = GUICtrlCreateEdit("Download Speed is:  " & DownloadSpeed(), 170, 57, 190, 20, $ES_READONLY)

Func DownloadSpeed()
    Local $Download = "http://bitdefender.com/tv"
    Local $TempFile = @TempDir & "\Temp.temp"
    $Size = InetGetSize($Download)
    If $Size = 0 Then Return "(Not Connected)"
    $Time = TimerInit()
    $Success = InetGet($Download, $TempFile, 1, 0)
    If $Success = 0 Then Return "(Not Connected)"
    $Time = TimerDiff($Time)
    $Rate = ($Size / $Time)
    FileDelete($TempFile)
    Return Round($Rate) & " KB/Sec"
EndFunc

Currently it calls the function when I run the script, I want it to call the function when I press the button. Any idea?

[dragancla]

And maybe only show the Edit once the button is pressed, that would make sense.

[water]

Welcome to AutoIt and the forum!

When asking for help please post a working reproducer
What you are looking for is described in the help file for GUICtrlCreateButton.
I wouldn't use an Edit control but a Label to display the result of your speed calculation.

[Danyfirex]

Hello welcome to the forum check GUISetOnEvent or GUIGetMsg and use GUICtrlSetData to se the data to the edit control.

 

 

Saludos

[Simpel]

Hi.

Welcome to the forum. You can loop a "while 1 - wend" and wait for pressing the button. If button is pressed run DownloadSpeed() and update the edit:

expandcollapse popup

#include <GuiConstants.au3>

GUICreate("SpeedTest")
GUICtrlCreateDummy()
Local $hSpeedTestButton = GUICtrlCreateButton("Test Download Speed", 10,50,120,35)
Local $hSpeedTestLabel = GUICtrlCreateLabel("", 170, 57, 190, 20)
GUISetState(@SW_SHOW)

Local $msg
Local $iSpeed
While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hSpeedTestButton
            GUICtrlSetData($hSpeedTestLabel, "")
            $iSpeed = DownloadSpeed()
            GUICtrlSetData($hSpeedTestLabel, "Download Speed is:  " & $iSpeed)
    EndSwitch
    Sleep(10)
WEnd

Func DownloadSpeed()
    SplashTextOn("Wait", "Download-Test running...", 300, 50)
    Local $Download = "http://bitdefender.com/tv"
    Local $TempFile = @TempDir & "\Temp.temp"
    Local $Size = InetGetSize($Download)
    If $Size = 0 Then Return "(Not Connected)"
    Local $Time = TimerInit()
    Local $Success = InetGet($Download, $TempFile, 1, 0)
    If $Success = 0 Then Return "(Not Connected)"
    $Time = TimerDiff($Time)
    Local $Rate = ($Size / $Time)
    FileDelete($TempFile)
    SplashOff()
    Return Round($Rate) & " KB/Sec"
EndFunc

I inserted a splash while waiting.

Conrad

Edited September 9, 2017 by Simpel

[dragancla]

6 hours ago, Simpel said:

Hi.

Welcome to the forum. You can loop a "while 1 - wend" and wait for pressing the button. If button is pressed run DownloadSpeed() and update the edit:

expandcollapse popup

#include <GuiConstants.au3>

GUICreate("SpeedTest")
GUICtrlCreateDummy()
Local $hSpeedTestButton = GUICtrlCreateButton("Test Download Speed", 10,50,120,35)
Local $hSpeedTestLabel = GUICtrlCreateLabel("", 170, 57, 190, 20)
GUISetState(@SW_SHOW)

Local $msg
Local $iSpeed
While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hSpeedTestButton
            GUICtrlSetData($hSpeedTestLabel, "")
            $iSpeed = DownloadSpeed()
            GUICtrlSetData($hSpeedTestLabel, "Download Speed is:  " & $iSpeed)
    EndSwitch
    Sleep(10)
WEnd

Func DownloadSpeed()
    SplashTextOn("Wait", "Download-Test running...", 300, 50)
    Local $Download = "http://bitdefender.com/tv"
    Local $TempFile = @TempDir & "\Temp.temp"
    Local $Size = InetGetSize($Download)
    If $Size = 0 Then Return "(Not Connected)"
    Local $Time = TimerInit()
    Local $Success = InetGet($Download, $TempFile, 1, 0)
    If $Success = 0 Then Return "(Not Connected)"
    $Time = TimerDiff($Time)
    Local $Rate = ($Size / $Time)
    FileDelete($TempFile)
    SplashOff()
    Return Round($Rate) & " KB/Sec"
EndFunc

I inserted a splash while waiting.

Conrad

That is awesome! 

Do you have any idea how I would integrate this in my own GUI? I would like to add that to a panel - code would go under _AddControlsToPanel($aPanel[1]) - and, if I just add the 2 Local variables and the while loop to it, it just hangs on Run until I hit CTRL-Break

[Simpel]

Therefor we have to see your code. Could be a lot of reasons. 

[dragancla]

This is it

System Assessment Tool.au3