How do I remove the Horizontal Scroll Bar from an Edit Control

[Skysnake 85]

My code.

Does not work

;~ [optional] Control styles:
;~     $ES_AUTOHSCROLL - Automatically scrolls text to the right by 10 characters when the user types a character at the end of the line.
;~     $ES_AUTOVSCROLL - Automatically scrolls text up one page when the user presses the ENTER key on the last line.

    Local $hEditNewText = _GUICtrlEdit_Create($hGUI, "This is a test" & @CRLF & "Another Line", 8, 500, 715, 100)
    Local $iStyle = _WinAPI_GetWindowLong(GUICtrlGetHandle($hEditNewText), $GWL_STYLE) ; get style
    Local $iExStyle = _WinAPI_GetWindowLong(GUICtrlGetHandle($hEditNewText), $GWL_EXSTYLE) ; get extended style
    ;GUICtrlSetStyle($hEditNewText, BitXOR($iStyle, $ES_AUTOHSCROLL)) ; remove hscroll left to right (force wrap)
    GUICtrlSetStyle($hEditNewText, BitAND($iStyle, BitNOT($ES_AUTOHSCROLL)))

https://www.autoitscript.com/wiki/Setting_Styles

Also tried this

;~ https://www.autoitscript.com/forum/topic/113598-solved-scrolling-read-only-text-display-using-edit-not-input-control/
    Local $hEditNewText = GUICtrlCreateEdit("This is a test" & @CRLF & "Another Line", 8, 500, 715, 100)
    Local $iStyle = _WinAPI_GetWindowLong(GUICtrlGetHandle($hEditNewText), $GWL_STYLE) ; get style
    Local $iExStyle = _WinAPI_GetWindowLong(GUICtrlGetHandle($hEditNewText), $GWL_EXSTYLE) ; get extended style
    GUICtrlSetStyle($hEditNewText, BitAND($iStyle, BitNOT($ES_AUTOHSCROLL)))

 

However, this works:

Local $hEditNewText = GUICtrlCreateEdit("This is a test" & @CRLF & "Another Line", 8, 500, 715, 100, $ES_WANTRETURN + $WS_VSCROLL + $ES_AUTOVSCROLL + $ES_MULTILINE + $WS_TABSTOP)

My question stands. How to change the STYLE of an EDIT control?

Skysnake

Edited September 19, 2017 by Skysnake

[Melba23 3,706]

Skysnake,

You need to remove the $WS_HSCROLL style from the control styles - the $ES_AUTOHSCROLL merely allows the control to automatically scroll as you type. This is why the final snippet works and the others do not, as you only remove the correct style in that final one - in the first 2 the edit control is created with the $WS_HSCROLL as a default style as explained in the Help file.

This works for me:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

; Create edit without the $WS_HSCROLL style
$cEdit = GUICtrlCreateEdit("", 10, 10, 200, 200, Bitor($ES_WANTRETURN, $WS_VSCROLL, $ES_AUTOVSCROLL))

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

M23

[Skysnake 85]

Aha, On it.  As always the devil is in the detail...

Thanks

 

[mLipok 1,301]

@Melba23 Thanks for yours example, I wanted to use them and then I found that GUICtrlSetStyle() behaves in a strage way.

Here is my repro script:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

_Example(True)
_Example(False)

Func _Example($b_Presetting_at_start)
    GUICreate("Test", 500, 500)
    Local $sText = _
            ' first line ............................................ ....... ...... xyz' & @CRLF & _
            '' & @CRLF & _
            ''
    Local $i_Edit_Style = 0
    $i_Edit_Style = BitOR($ES_WANTRETURN, $WS_VSCROLL, $ES_AUTOVSCROLL)

    If $b_Presetting_at_start Then $i_Edit_Style = BitOR($i_Edit_Style, $WS_HSCROLL, $ES_AUTOHSCROLL)

    Local $cEdit = GUICtrlCreateEdit($sText, 10, 10, 200, 200, $i_Edit_Style)

    If Not $b_Presetting_at_start Then
        $i_Edit_Style = BitOR($i_Edit_Style, $WS_HSCROLL, $ES_AUTOHSCROLL)
        GUICtrlSetStyle($cEdit, $i_Edit_Style)
    EndIf

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Return
        EndSwitch
    WEnd
EndFunc   ;==>_Example

The strange for me is the fact that when I use $b_Presetting_at_start = false then the line is wrapped, is there a way to disable wrapping when I use $b_Presetting_at_start = false ?

Edited November 12, 2021 by mLipok

[mLipok 1,301]

Hah.... I found solution....

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

_Example(True)
_Example(False)

Func _Example($b_Presetting_at_start)
    GUICreate("Test", 500, 500)
    Local $sText = _
            ' first line ............................................ ....... ...... xyz' & @CRLF & _
            '' & @CRLF & _
            ''
    Local $i_Edit_Style = $WS_HSCROLL, $ES_AUTOHSCROLL
    $i_Edit_Style = BitOR($i_Edit_Style, $ES_WANTRETURN, $WS_VSCROLL, $ES_AUTOVSCROLL)

    If $b_Presetting_at_start Then $i_Edit_Style = BitOR($i_Edit_Style, $WS_HSCROLL, $ES_AUTOHSCROLL)

    Local $cEdit = GUICtrlCreateEdit($sText, 10, 10, 200, 200, $i_Edit_Style)

    If Not $b_Presetting_at_start Then
        $i_Edit_Style = BitAND($i_Edit_Style, BitNOT($WS_HSCROLL), BitNOT($ES_AUTOHSCROLL))
        GUICtrlSetStyle($cEdit, $i_Edit_Style)
    EndIf

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Return
        EndSwitch
    WEnd
EndFunc   ;==>_Example

 

Edited November 12, 2021 by mLipok