javascript unescape Question

[youtuber]

How can I make html codes the same?
and how can i solve

<script type="text/javascript">
document.write(unescape('%41%75%74%6F%69%74%54%65%73%74'));
</script>

Is it possible to do this with Autoit and solve it?

[Danp2]

Have you tried this UDF?

 

[youtuber]

What I'm talking about is different from your thread

http://www.tareeinternet.com/scripts/unescape.html

 

[Melba23]

youtuber,

It is a simple ASCII conversion:

#include <MsgBoxConstants.au3>

$sString = "AutoIt"

$sCoded = StringTrimLeft(StringToBinary($sString), 2)

MsgBox($MB_SYSTEMMODAL, "Encoded", $sCoded)

$sDecoded = BinaryToString("0x" & $sCoded)

MsgBox($MB_SYSTEMMODAL, "Decoded", $sDecoded)

M23

[Danp2]

How so? It appears to decode your string just fine.

Perhaps you should provide a more details response indicating what you are trying to accomplish and how this UDF doesn't meet your needs.

[youtuber]

@Melba23 Thanks

I could not do the same

$Form1 = GUICreate("Unescape Decoder and Encoder", 876, 422, 192, 124)
$Edit1 = GUICtrlCreateEdit("AutoitTest", 48, 48, 337, 305)
$Edit2 = GUICtrlCreateEdit("", 412, 49, 425, 305)
$Label1 = GUICtrlCreateLabel("String", 56, 24, 50, 17)
$Label2 = GUICtrlCreateLabel("Unescape", 416, 24, 50, 17)

$ButtonEncoder = GUICtrlCreateButton("Encoder", 150, 376, 147, 25)
$ButtonDecoder = GUICtrlCreateButton("Decoder", 550, 376, 147, 25)

GUISetState(@SW_SHOW)
While 1
  $nMsg = GUIGetMsg()
  Switch $nMsg
     Case -3
        Exit
     Case $ButtonEncoder
        GUICtrlSetData($Edit2, "%" & StringTrimLeft("%" & StringToBinary(GUICtrlRead($Edit1)), 2))

     Case $ButtonDecoder
        GUICtrlSetData($Edit1,BinaryToString("0x" & GUICtrlRead($Edit2)),2)
  EndSwitch
WEnd

 

[youtuber]

Can you help me please

expandcollapse popup

#include <Array.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1_1 = GUICreate("Unescape Decoder and Encoder", 877, 669)
$Edit1 = GUICtrlCreateEdit("", 48, 48, 337, 249)
GUICtrlSetData(-1, "AutoitTest")
$Edit2 = GUICtrlCreateEdit("", 412, 49, 425, 249)
$Label1 = GUICtrlCreateLabel("String", 56, 24, 50, 17)
$Label2 = GUICtrlCreateLabel("Unescape", 416, 24, 50, 17)
$ButtonEncoder = GUICtrlCreateButton("Encoder", 150, 312, 147, 25)
$ButtonDecoder = GUICtrlCreateButton("Decoder", 550, 312, 147, 25)
$Edit3 = GUICtrlCreateEdit("", 40, 408, 801, 233)
$Label3 = GUICtrlCreateLabel("Decode", 40, 384, 122, 17)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $ButtonEncoder
            $aData = StringTrimLeft(StringToBinary(GUICtrlRead($Edit1)), 2)
            $aArray = _StringEqualSplit($aData, 2)
            GUICtrlSetData($Edit2, "%" & _ArrayToString($aArray, "%"))

        Case $ButtonDecoder
            GUICtrlSetData($Edit3,GUICtrlRead($Edit2)

  EndSwitch
WEnd

Func _StringEqualSplit($sString, $iNumChars)
    If (Not IsString($sString)) Or $sString = "" Then Return SetError(1, 0, 0)
    If (Not IsInt($iNumChars)) Or $iNumChars < 1 Then Return SetError(2, 0, 0)
    Return StringRegExp($sString, "(?s).{1," & $iNumChars & "}", 3)
EndFunc

 

[Melba23]

youtuber,

Do not be so impatient - some of us have more important things to do.

This works for me:

#include <GUIConstantsEx.au3>

$Form1 = GUICreate("Unescape Decoder and Encoder", 876, 422, 192, 124)
$Edit1 = GUICtrlCreateEdit("AutoitTest", 48, 48, 337, 305)
$Edit2 = GUICtrlCreateEdit("", 412, 49, 425, 305)
$Label1 = GUICtrlCreateLabel("String", 56, 24, 50, 17)
$Label2 = GUICtrlCreateLabel("Unescape", 416, 24, 50, 17)

$ButtonEncoder = GUICtrlCreateButton("Encoder", 150, 376, 147, 25)
$ButtonDecoder = GUICtrlCreateButton("Decoder", 550, 376, 147, 25)

GUISetState(@SW_SHOW)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $ButtonEncoder
            $sBinary = StringTrimLeft(StringToBinary(GUICtrlRead($Edit1)), 2)
            $sEscaped = StringRegExpReplace($sBinary, "(.{2})", "%$1")
            GUICtrlSetData($Edit2, $sEscaped)
            GUICtrlSetData($Edit1, "")

        Case $ButtonDecoder
            $sEncoded = GUICtrlRead($Edit2)
            $sStripped = StringReplace($sEncoded, "%", "")
            ConsoleWrite($sStripped & @CRLF)
            $sDecoded = BinaryToString("0x" & $sStripped)
            ConsoleWrite($sDecoded & @CRLF)
            GUICtrlSetData($Edit1, $sDecoded)
    EndSwitch
WEnd

M23