"File" menu is highlighted when switching tab

[wuruoyu]

When switching tab, the "File" menu is highlighted just like when pressing the "ALT" key on keyboard (especially when I keep holding down the left click on the tab). Is there anyway to avoid the "File" menu being highlighted when switching tab and retain the accelerator "ALT" when press "ALT" key on keyboard. Thanks in advance!

I know this is not the standard way to setup tab control, but have to use this method to fix other issues I have had:

*Seems like ALT is being triggered when GUISetState(@SW_HIDE) or GUISetState(@SW_SHOW) is used in my case

expandcollapse popup

#NoTrayIcon
#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>
#include <EditConstants.au3>
#include <GUIToolbar.au3>
#include <GUIImageList.au3>
#include <WinAPITheme.au3>

Opt("GUIOnEventMode", 1)

Global $tab, $currentTab, $pageOneGUI, $pageTwoGUI
Global $idInput1P2, $idInput2P2, $idInput3P2

_main()

Func _main()
    $main = GUICreate("main", 368, 363, -1, -1, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")
    GUISetState()
    
    Local $idFilemenu = GUICtrlCreateMenu("&File")
    Local $idFileitem = GUICtrlCreateMenuItem("Open", $idFilemenu)
    GUICtrlSetState(-1, $GUI_DEFBUTTON)
    Local $idHelpmenu = GUICtrlCreateMenu("?")
    GUICtrlCreateMenuItem("Save", $idFilemenu)
    GUICtrlSetState(-1, $GUI_DISABLE)
    Local $idInfoitem = GUICtrlCreateMenuItem("Info", $idHelpmenu)
    Local $idExititem = GUICtrlCreateMenuItem("Exit", $idFilemenu)
    Local $idRecentfilesmenu = GUICtrlCreateMenu("Recent Files", $idFilemenu, 1)

    $ToolbarGUI = GUICreate('', 350, 62, 1, 1, $WS_CHILD, 0, $main)
    $Toolbar = _GUICtrlToolbar_Create($ToolbarGUI, BitOR($BTNS_BUTTON, $BTNS_SHOWTEXT, $TBSTYLE_FLAT, $TBSTYLE_TOOLTIPS), $TBSTYLE_EX_DOUBLEBUFFER)
    $ToolbarImageList = _GUIImageList_Create(32, 32, 5, 1)
    _GUIImageList_AddIcon($ToolbarImageList, "C:\Windows\System32\mmc.exe", 0, 1)
    _GUIImageList_AddIcon($ToolbarImageList, "C:\Windows\System32\cmd.exe", 0, 1)
    _GUICtrlToolbar_SetImageList($Toolbar, $ToolbarImageList)
    _GUICtrlToolbar_AddString($Toolbar, 'MMC')
    _GUICtrlToolbar_AddString($Toolbar, 'CMD')
    _GUICtrlToolbar_AddButton($Toolbar, 10000, 0, 0)
    _GUICtrlToolbar_AddButton($Toolbar, 10001, 1, 1)
    _GUICtrlToolbar_SetButtonSize($Toolbar, 62, 50)
    _GUICtrlToolbar_SetMetrics($Toolbar, 0, 0, 1, 0)
    _GUICtrlToolbar_SetIndent($Toolbar, 1)
    _SendMessage($Toolbar, $TB_AUTOSIZE)

    GUISwitch($main)

    GUICtrlCreateLabel('', 0, 63, 368, 2, $SS_ETCHEDHORZ)
    GUICtrlCreateButton("button", 248, 313, 100, 20, -1, -1)

    $pageOneGUI = GUICreate("", 352, 198, 9, 93, $WS_CHILD,-1, $main)
    ;GUISetBkColor(0xCCFFCC)
    GUICtrlCreateGroup("Group", 6, 3, 341, 180, -1, -1)
    GUICtrlCreateEdit("this is an edit control", 15, 40, 325, 67, BitOR($ES_READONLY, $WS_VSCROLL), $WS_EX_CLIENTEDGE)
    GUICtrlCreateInput("This is an inputbox", 15, 130, 325, 20, -1, $WS_EX_CLIENTEDGE)

    $pageTwoGUI = GUICreate("", 352, 198, 9, 93, $WS_CHILD,-1, $main)
    ;GUISetBkColor(0xCCFFCC)
    $idInput1P2 = GUICtrlCreateInput("This is an inputbox", 15, 070, 325, 20, -1, $WS_EX_CLIENTEDGE)
    $idInput2P2 = GUICtrlCreateInput("This is an inputbox", 15, 100, 325, 20, -1, $WS_EX_CLIENTEDGE)
    $idInput3P2 = GUICtrlCreateInput("This is an inputbox", 15, 130, 325, 20, -1, $WS_EX_CLIENTEDGE)

    GUISwitch($main)
    $tab = GUICtrlCreateTab(4, 70, 363, 226, -1, -1)
    GUICtrlSetOnEvent($Tab, "_tabChangeDetected")
    GUICtrlCreateTabItem("Page 1")
    GUICtrlCreateTabItem("Page 2")
    GUICtrlCreateTabItem("")
    _WinAPI_SetWindowTheme(GUICtrlGetHandle( $tab ), "", "")

    $currentTab = _GUICtrlTab_GetCurFocus($tab)

    $idTabKeyP2 = GUICtrlCreateDummy()
    GUICtrlSetOnEvent( $idTabKeyP2, "TabKeyP2" )
    Local $aAccelKeys[1][2] = [["{Tab}", $idTabKeyP2]]
    GUISetAccelerators($aAccelKeys)

    GUISetState(@SW_SHOWNOACTIVATE, $ToolbarGUI)
    GUISetState(@SW_SHOW, $main)

    _GUICtrlTab_SetCurFocus($tab, 0)

    While 1
        Sleep(100)
    WEnd
EndFunc   ;==>_main

Func TabKeyP2()
  Switch _WinAPI_GetDlgCtrlID( ControlGetHandle( $pageTwoGUI, "", ControlGetFocus( $pageTwoGUI ) ) )
    Case $idInput1P2
      ControlFocus( $pageTwoGUI, "", $idInput2P2 )
    Case $idInput2P2
      ControlFocus( $pageTwoGUI, "", $idInput3P2 )
    Case $idInput3P2
      ControlFocus( $pageTwoGUI, "", $idInput1P2 )
    Case Else
  EndSwitch
EndFunc

Func _exit()
    Exit
EndFunc   ;==>_exit

Func _tabChangeDetected()
    If _GUICtrlTab_GetCurFocus($tab) <> $currentTab Then
        $currentTab = _GUICtrlTab_GetCurFocus($tab)
        ;MsgBox(0, "", $currentTab)
        Switch $currentTab
            Case 0
                GUISetState(@SW_HIDE,$pageTwoGUI)
                GUISetState(@SW_SHOW,$pageOneGUI)
            Case 1
                GUISetState(@SW_HIDE,$pageOneGUI)
                GUISetState(@SW_SHOW,$pageTwoGUI)
        EndSwitch
    EndIf
EndFunc   ;==>_tabChangeDetected

 

 

Edited October 13, 2017 by wuruoyu

[wuruoyu]

Bump

[SmOke_N]

I can see this happening when you're using hide method because you're not focusing on that GUI any longer, now it's shifted back to the main gui before focus is again giving to the alternate page GUI.

I'm curious, if you put say Sleep(100) between the hide and show in the tab changed detected function... do you still get the same result?

[wuruoyu]

Thank you for your reply, SmOke_N.

I tried adding Sleep(100) between the hide and show, it's the same result.

[mLipok]

Offtopic:  Nice to see you again @SmOke_N 

[SmOke_N]

Have you tried using controlhide/show instead?  I can't replicate it, on mine,  it highlights as expected then when the new GUI is given show state the highlight goes away as expected.

 

eg..

Func _tabChangeDetected()
    If _GUICtrlTab_GetCurFocus($tab) <> $currentTab Then
        $currentTab = _GUICtrlTab_GetCurFocus($tab)
        ;MsgBox(0, "", $currentTab)
        Switch $currentTab
            Case 0
                ControlHide($main, "", $pageTwoGUI)
                ControlShow($main, "", $pageOneGUI)
;~                 GUISetState(@SW_HIDE,$pageTwoGUI)
;~                 GUISetState(@SW_SHOW,$pageOneGUI)
            Case 1
                ControlHide($main, "", $pageOneGUI)
                ControlShow($main, "", $pageTwoGUI)
;~                 GUISetState(@SW_HIDE,$pageOneGUI)
;~                 GUISetState(@SW_SHOW,$pageTwoGUI)
        EndSwitch
    EndIf
EndFunc   ;==>_tabChangeDetected

 

Edit:

@mLipok hope you're doing well!

Edited October 14, 2017 by SmOke_N

[mLipok]

1 hour ago, SmOke_N said:

@mLipok hope you're doing well!

Thanks, apart from lack of sleep and money I do not complain

 

[wuruoyu]

@SmOke_N Thank you so much for the fix, it works!