IE button with Autoit action (event onclick)

[maniootek]

In this example I want have just one function (not three) but how to determinate which button was pressed? Is it possible to pass parameter to event funcion?

#include <IE.au3>

$oIE = _IECreate()
_IEDocWriteHTML($oIE, '' & _
'<button id="button1">Click me 1</button>' & _
'<button id="button2">Click me 2</button>' & _
'<button id="button3">Click me 3</button>')
$oButton1 = _IEGetObjById($oIE, "button1")
$oButton2 = _IEGetObjById($oIE, "button2")
$oButton3 = _IEGetObjById($oIE, "button3")
Local $oEventHandler1 = ObjEvent($oButton1, "_Evt1_")
Local $oEventHandler2 = ObjEvent($oButton2, "_Evt2_")
Local $oEventHandler3 = ObjEvent($oButton3, "_Evt3_")

Func _Evt1_onclick()
    msgbox(0,0,1)
EndFunc

Func _Evt2_onclick()
    msgbox(0,0,2)
EndFunc

Func _Evt3_onclick()
    msgbox(0,0,3)
EndFunc

while 1
    sleep(100)
WEnd

Quote

Func _Evt_onclick($parameter?)

MsgBox(0,0,$parameter?)

EndFunc

 

Edited October 26, 2017 by maniootek

[mLipok]

Small hint from HelpFile:

; Custom sink object
    Local $oIEEvents = ObjEvent($oIE, "_IEEvent_", "DWebBrowserEvents2")

 

EDIT: and look here:
https://msdn.microsoft.com/en-us/library/aa768283(v=vs.85).aspx

 

EDIT2: I remember somewhere on the forum was solution to your question but do not know where

 

Edited October 26, 2017 by mLipok

[maniootek]

I think you didn't get my problem well. Try to convert my code from 3 functions to only 1 with parameter (to know what button was clicked).

45 minutes ago, mLipok said:

EDIT2: I remember somewhere on the forum was solution to your question but do not know where

Do you mean this?

 

[mLipok]

Quite possible this is what you need.
Check this and back with feedback.

Pozdrawiam
mLipok

 

[maniootek]

12 minutes ago, maniootek said:

Do you mean this?

I read that post before but only now I noticed this line:

    Local $o_object = @COM_EventObj

which is answer for my question.

#include <IE.au3>

$oIE = _IECreate()
_IEDocWriteHTML($oIE, '' & _
        '<button id="button1">Click me 1</button>' & _
        '<button id="button2">Click me 2</button>' & _
        '<button id="button3">Click me 3</button>')
$oButton1 = _IEGetObjById($oIE, "button1")
$oButton2 = _IEGetObjById($oIE, "button2")
$oButton3 = _IEGetObjById($oIE, "button3")
ObjEvent($oButton1, "_IEEvent_")
ObjEvent($oButton2, "_IEEvent_")
ObjEvent($oButton3, "_IEEvent_")

Func _IEEvent_onclick()
    $obj = @COM_EventObj
    MsgBox(0, 0, $obj.id)
EndFunc   ;==>_IEEvent_onclick

While 1
    Sleep(100)
WEnd

Thanks anyway

Edited October 26, 2017 by maniootek

[mLipok]

Exactly.

Here is better example:
 

expandcollapse popup

#include <IE.au3>

Global $g_bExitTester = False

_Example()

Func _Example()
    Local $oIE = _IECreate()
;~  _IEDocWriteHTML($oIE, '' & _
    _IEDocWriteHTML($oIE, _
            '<button id="button1">Click me 1</button>' & _
            '<button id="button2">Click me 2</button>' & _
            '<button id="button3">Exit</button>' _
            )

    Local $oIE_Button1 = _IEGetObjById($oIE, "button1")
    Local $oIE_Button2 = _IEGetObjById($oIE, "button2")
    Local $oIE_Button3 = _IEGetObjById($oIE, "button3")

    Local $oEventHandler1 = ObjEvent($oIE_Button1, "_Evt_")
    Local $oEventHandler1 = ObjEvent($oIE_Button2, "_Evt_")
    Local $oEventHandler1 = ObjEvent($oIE_Button3, "_Evt_")

    While 1
        Sleep(10)
        If $g_bExitTester Then ExitLoop
    WEnd

    _IEQuit($oIE)

EndFunc   ;==>_Example

Func _Evt_onclick()
    Local $o_object = @COM_EventObj
    Switch $o_object.Innertext
        Case 'Exit'
            $g_bExitTester = True
        Case Else
            MsgBox(0, 0, $o_object.Innertext)
    EndSwitch
EndFunc   ;==>_Evt_onclick

 

[mLipok]

Final example:

expandcollapse popup

#include <IE.au3>
#include <MsgBoxConstants.au3>

Global $g_bExitTester = False

_IEErrorHandlerRegister(_ErrFunc)

_Example()

Func _Example()
    ; create new IE
    Local $oIE = _IECreate()

    ; write example HTML content to IE
    _IEDocWriteHTML($oIE, _
            '<button id="button1">Click me 1</button>' & _
            '<button id="button2">Click me 2</button>' & _
            '<button id="button3">Exit</button>' _
            )

    ; get object for each button
    Local $oIE_Button1 = _IEGetObjById($oIE, "button1")
    Local $oIE_Button2 = _IEGetObjById($oIE, "button2")
    Local $oIE_Button3 = _IEGetObjById($oIE, "button3")

    ; registering event handler for each button
    ObjEvent($oIE_Button1, "_IEEvent_")
    ObjEvent($oIE_Button2, "_IEEvent_")
    ObjEvent($oIE_Button3, "_IEEvent_")

    ; main loop
    While 1
        Sleep(10)
        If $g_bExitTester Then ExitLoop
    WEnd

    _IEQuit($oIE)

EndFunc   ;==>_Example

Func _IEEvent_onclick()
    ; catch object fireing Event
    Local $o_object = @COM_EventObj

    ; manage captured Event
    Switch $o_object.Innertext
        Case 'Exit'
            $g_bExitTester = True
        Case Else
            MsgBox($MB_OK, 'Information', 'Button "' & $o_object.Innertext & '" was clicked in Internet Explorer')
    EndSwitch

EndFunc   ;==>_IEEvent_onclick

; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc