General Question: How do controls without GUIGetMsg() capture mouse clicks and events?

[arlight1]

i've been working a lot with listview recently, and found out that groups can be created to expand/collapse the items that belong to them. While a state does exist to collapse it a will, a state does not exist to expand a group within a listview at will. 

 

So that got me thinking, how do message boxes, treeview, listviews and other controls that don't use GUIGetMsg() to capture mouse clicks work? If I click "ok" on a message box, how does it automatically know to close it out? Same with a list/treeview, if I click on the "+" sign, how does it know to expand or collapse a group? Where is all that defined?

[arlight1]

Bump

[Danyfirex]

Hello. It's a complex question But a start point is GUIRegisterMsg. But You need go to deep Windows Information. Check MSDN.

 

 

Saludos

[arlight1]

On 11/23/2017 at 11:16 AM, Danyfirex said:

Hello. It's a complex question But a start point is GUIRegisterMsg. But You need go to deep Windows Information. Check MSDN.

 

 

Saludos

Thanks for the response! Would that be the way to go then if I wanted to automate the expanding/collapsing of a listview group, for example?

[Melba23]

arlight1,

_GUICtrlListView_SetGroupInfo would seem a good place to start - this is based on the Help file example for that function:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aInfo, $hImage, $idListview

    GUICreate("ListView Set Group Info", 400, 300)

    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Load images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Build groups
    _GUICtrlListView_EnableGroupView($idListview)
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1", 1)
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    ; Change group information
    Sleep(1000)
    _GUICtrlListView_SetGroupInfo($idListview, 2, "Collapsed Group 2", 0, $LVGS_COLLAPSED)
    Sleep(1000)
    _GUICtrlListView_SetGroupInfo($idListview, 2, "Expanded Group 2")

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example

M23