search with start and end of a line

[Rskm]

I have a text file with lot of lines (of the order of 30000 - thats to get an idea about the size of file). i wish to replace  particular texts , and wish to do the search based on the 'start' and 'end' of such lines , because the 'in between' portions are variables and they vary.
 
the texts in the file looks like below
CAD 100     101       102  E  NEW  REPLACE 
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
CAD 200     201       202  R  CHK  REPLACE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
CAD 300     301       302  E  FEW  REPLACE 
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
CAD 400     401       402  G  COK  REPLACE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE

What i want to replace is only the lines which start with 'CAD' and end with 'REPLACE' in the text,

the replacements are respectively
CAD 600     111       112  E  NEW  REPLACE
CAD 700     222       223  E  NEW  REPLACE
CAD 800     333       334  E  NEW  REPLACE
CAD 900     444       445  E  NEW  REPLACE

my replace should look something like

replace ("CAD 100    $var1   $var2  $var3  $var 4 "REPLACE") with

("CAD 100    $newvar1   $newvar2  $newvar3  $newvar 4 "REPLACE")

where $var1,2,3,4 represents 100,102,E and NEW and $newvars are the replacements.

thanks.

[Subz]

What are the delimiters? spaces or tabs?

[Rskm]

hi, they are spaces.. 

[Subz]

Maybe something like:

#include <Array.au3>
#include <File.au3>
#include <String.au3>

Local $aArray, $sStart, $sEnd, $x = 0
Local $aVar[4] = [111, 112, "E", "NEW"]
_FileReadToArray(@ScriptDir & "\Test.txt", $aArray)
    If @error Then Exit

For $i = 1 To $aArray[0]
    $sStart = StringLeft(StringStripWS($aArray[$i], 3), 3)
    $sEnd = StringRight(StringStripWS($aArray[$i], 3), 7)
    If $sStart = "CAD" And $sEnd = "REPLACE" Then
        $aArray[$i] = $sStart & " " & $aVar[0] & "       " & $aVar[1] & "  " & $aVar[2] & "  " & $aVar[3] & "  " & $sEnd
        $aVar[0] += 111
        $aVar[1] += 11
    EndIf
Next
_ArrayDisplay($aArray)

 

[jchd]

You can use a regex for that.

[Malkey]

Here is an example of a regex for that.

expandcollapse popup

#cs
CAD 100     101       102  E  NEW  REPLACE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
CAD 200     201       202  R  CHK  REPLACE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
CAD 300     301       302  E  FEW  REPLACE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
CAD 400     401       402  G  COK  REPLACE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
SOME TEXT HERE
#ce

Local $newvar3 = "E", $newvar4 = "New"
Local $TextFile = StringRegExpReplace(FileRead(@ScriptName), "(?is)^.*#cs\v+|\v+#ce.*", "") ; Get test data from the block comment.
ConsoleWrite("Original Text:" & @CRLF & $TextFile & @CRLF & @CRLF)

Local $s = "'" & StringRegExpReplace($TextFile, "(?im)^CAD(\s*)(\d+)(\s*)(\d+)(\s*)(\d+)(\s*)(\w+)(\s*)(\w+)(\s*)REPLACE\s*$", _
        "' & 'CAD' & '${1}'& (${2} + 500) & '${3}' & (${2}/100 * 111) & '${5}' & (${2}/100 * 111 +1) & '${7}' & $newvar3 & '${9}' & $newvar4 & '${11}REPLACE' & '") & "'"
; Note: Backreferences ${1}, ${3}, ${5}, ${7}, ${9}, and ${11} are the spacings of the original text.
;ConsoleWrite($s & @CRLF) ; <---Execute() function parameter

ConsoleWrite("------------------------------------" & @CRLF)
ConsoleWrite("Replaced Text:" & @CRLF & Execute($s) & @CRLF)