How to get text from Webpage in IE ?

[iamtech]

Hello guys i want to know how to grab text from a website page ? like this:

i want to get that "C Number" 6020199903988288, anyone can help me ?

[JLogan3o13]

@iamtech the help file is your friend. Look under IE Management for a whole slew of functions related to IE.

[iamtech]

25 minutes ago, JLogan3o13 said:

@iamtech the help file is your friend. Look under IE Management for a whole slew of functions related to IE.

@JLogan3o13 i am trying with this : 

#include <IE.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>

Local $oIE = _IECreate("https://www.url.com", 1)
Local $readtitle =  _StringBetween(_IEDocReadHTML($oIE), '<td style="font-weight: bold;">', '</td>')

    MsgBox(64, "Finished", $readtitle)

But, Not working

[kaz]

you can try this code to obtain html page

 

get_url(insert url here)

Func get_url($url)

    $RequestURL = $url;
    Global $oHTTP = ObjCreate("winhttp.winhttprequest.5.1") ;
    $oHTTP.Open("GET", $RequestURL, False)
    $oHTTP.Send()
     if  $oHTTP.status == 200 Then
           ConsoleWrite($oHTTP.ResponseText)
     Else
            ConsoleWrite("Other status: " & $oHTTP.status)
     EndIf

 EndFunc

the function _INetGetSource exist to, but sometime don't do the job...

[mLipok]

46 minutes ago, iamtech said:

But, Not working

Did you try:

_IEBodyReadText()

?

[Subz]

Untested, but try:

#include <IE.au3>

Local $sCNumber = "C Number", $iCNumber = "0"
Local $oIE = _IECreate("https://www.w3schools.com/html/html_tables.asp", 1)
_IELoadWait($oIE)
Local $oTds = _IETagNameGetCollection($oIE, "td")
For $oTd In $oTds
    If $oTd.InnerText = $sCNumber Then
        $iCNumber = $oTd.NextElementSibling.InnerText
        ExitLoop
    EndIf
Next
MsgBox(32, $sCNumber, $sCNumber & " : " & $iCNumber)

 

Edited March 24, 2018 by Subz

[iamtech]

16 hours ago, Subz said:

Untested, but try:

#include <IE.au3>

Local $sCNumber = "C Number", $iCNumber = "0"
Local $oIE = _IECreate("https://www.w3schools.com/html/html_tables.asp", 1)
_IELoadWait($oIE)
Local $oTds = _IETagNameGetCollection($oIE, "td")
For $oTd In $oTds
    If $oTd.InnerText = $sSearch Then
        $iCNumber = $oTd.NextElementSibling.InnerText
        ExitLoop
    EndIf
Next
MsgBox(32, $sCNumber, $sCNumber & " : " & $iCNumber)

 

@Subz What is you used $sSearch = ?

[Subz]

Sorry it was meant to be $sCNumber (updated post above)

[iamtech]

4 minutes ago, Subz said:

Sorry it was meant to be $sCNumber (updated post above)

Thanks Its working, But i want to only display C Number Value, without showing C Number :

[iamtech]

@Subz It working without loop ?

 

[Subz]

Yes thats the $iCNumber variable!  I just placed in a string in the MsgBox (see last line) to show you what the value is.

 

[iamtech]

2 minutes ago, Subz said:

Yes thats the $iCNumber variable!  I just placed in a string in the MsgBox (see last line) to show you what the value is.

 

@Subz and its working without loop statement ?

[Subz]

No it requires a loop to go through each of the "td" and identify the innertext "C Number", once this is found it grabs the next sibling element, then exits the loop and you have your variable.

[iamtech]

2 minutes ago, Subz said:

No it requires a loop to go through each of the "td" and identify the innertext "C Number", once this is found it grabs the next sibling element, then exits the loop and you have your variable.

@Subz Okay

[iamtech]

@Subz

How to use multiple statement in this function?

i am tried with this code : 

#include <IE.au3>

Local $sCNumber = "C Number" & "G Number", $iCNumber = "0"
Local $oIE = _IECreate("https://www.w3schools.com/html/html_tables.asp", 1)
_IELoadWait($oIE)
Local $oTds = _IETagNameGetCollection($oIE, "td")
For $oTd In $oTds
    If $oTd.InnerText = $sCNumber Then
        $iCNumber = $oTd.NextElementSibling.InnerText
        ExitLoop
    EndIf
Next
MsgBox(32, $sCNumber, $sCNumber & " : " & $iCNumber)

But not woeking, i want to also get G Number's Value

Edited March 25, 2018 by iamtech

[Subz]

#include <IE.au3>

Local $sCNumber = "C Number", $sGNumber = "G Number", $iCNumber = "0", $iGNumber = "0"
Local $oIE = _IECreate("<Enter URL Here>", 1)
_IELoadWait($oIE)
Local $oTds = _IETagNameGetCollection($oIE, "td")
For $oTd In $oTds
    If $oTd.InnerText = $sCNumber Then
        $iCNumber = $oTd.NextElementSibling.InnerText
    ElseIf $oTd.InnerText = $sGNumber Then
        $iGNumber = $oTd.NextElementSibling.InnerText
    EndIf
Next
MsgBox(32, $sCNumber, $sCNumber & " : " & $iCNumber & @CRLF & $sGNumber & " : " & $iGNumber)

 

Edited March 25, 2018 by Subz

[iamtech]

2 hours ago, Subz said:

#include <IE.au3>

Local $sCNumber = "C Number", $sGNumber = "G Number", $iCNumber = "0", $iGNumber = "0"
Local $oIE = _IECreate("<Enter URL Here>", 1)
_IELoadWait($oIE)
Local $oTds = _IETagNameGetCollection($oIE, "td")
For $oTd In $oTds
    If $oTd.InnerText = $sCNumber Then
        $iCNumber = $oTd.NextElementSibling.InnerText
    ElseIf $oTd.InnerText = $sGNumber Then
        $iGNumber = $oTd.NextElementSibling.InnerText
    EndIf
Next
MsgBox(32, $sCNumber, $sCNumber & " : " & $iCNumber & @CRLF & $sGNumber & " : " & $iGNumber)

 

@SubzThanks , You are my god

Edited March 25, 2018 by iamtech